[文件操作] 根据指定文本中列出的字符串全盘查找文件名中含有某个字符串的图片并复制到指定目录里

sohoxs

请教一个批量查找图片并复制到指定文件夹的BAT
我现在想从我的电脑中将符合“查找.txt”（全是人名），查询出来并复制到F盘“查找到图片”文件夹中，以下这代码只能查询f盘“数据”文件夹，不能全盘查找，注：图片名字可能是图片文件名包含有名字，查找.txt文件中只是名字，比如：图片的文件名是"广东_张三（1).JPG"，请教各位老师帮忙写个批处理，谢谢！

@echo off
for /f "delims=" %%a in (查找.txt) do (
    copy /y "F:\数据\*%%a*.jpg" "F:\查找到图片"
)
复制代码

sohoxs

回复 3# pcl_test


  不好意思，前几天有事外出了，没能及时回复，试了下非常好用，非常感谢！

pcl_test

不知道你说的全盘是什么意思，F整个分区还是所有分区？

@echo off&setlocal enabledelayedexpansion
set "fd=F:\查找到图片\"
md "%fd%" 2>nul
for /f "delims=" %%a in ('type "查找.txt"') do set "#%%a=%%a"
for %%a in (c d e f g h i j k l m n) do (
    if exist %%a:\ (
        for /f "delims=" %%a in ('dir /a-d/b/s %%a:\*.jpg') do (
            set "fn=%%~nxa"
            if /i "%%~dpa" neq "%fd%" (
                for /f "tokens=2 delims==" %%c in ('set #') do (
                    if "!fn:%%c=!" neq "%%~nxa" (
                        if exist "%fd%%%~nxa" (
                            rem 处理可能的同名文件
                            set /a n+=1
                            copy "%%a" "%fd%!n!_%%~nxa"
                        ) else copy "%%a" "%fd%"
                    )
                )
            )
        )
    )
)
pause
复制代码

sohoxs

回复 1# sohoxs


    版主你好，我没找着，都是查找txt文本内容的，谢谢！