[文本处理] 怎样用批处理修改或删除文本文件中指定的内容？

xbee

有一个软件会修改C:\WINDOWS\win.ini文件，卸载后这些内容并不被删除。
比如下面的两行：

[aspeeder]
count=?

？是不确定的，是0到50之间任意数
要求删除上面两行，或改为
[aspeeder]
count=1

Batcher

删除：

@echo off
sed -i ":nt; $!{N; s/\[aspeeder\]\ncount=[1-50]//; tnt}" C:\WINDOWS\win.ini
复制代码

第三方命令行工具sed.exe下载地址：
http://bbs.bathome.net/thread-1114-1-1.html

Batcher

删除：

@echo off
setlocal enabledelayedexpansion
set SrcFile=C:\WINDOWS\win.ini
set DstRow=[aspeeder]
set NextRow=
set flag=0
>C:\WINDOWS\win_tmp.ini echo ; for 16-bit app support
(for /f "usebackq tokens=*" %%a in ("%SrcFile%") do (
  if !flag! equ 0 (
    if "%%a" neq "%DstRow%" (
      echo.%%a
    )
  )
  if "%%a" equ "%DstRow%" (
    set flag=1
  ) else (
    set flag=0
  )
))>>C:\WINDOWS\win_tmp.ini
move /y C:\WINDOWS\win_tmp.ini C:\WINDOWS\win.ini
复制代码

Batcher

修改：

@echo off
setlocal enabledelayedexpansion
set SrcFile=C:\WINDOWS\win.ini
set DstRow=[aspeeder]
set flag=0
>C:\WINDOWS\win_tmp.ini echo ; for 16-bit app support
(for /f "usebackq tokens=*" %%a in ("%SrcFile%") do (
  if !flag! equ 0 (
    echo.%%a
  ) else (
    echo count=1
  )
  if "%%a" equ "%DstRow%" (
    set flag=1
  ) else (
    set flag=0
  )
))>>C:\WINDOWS\win_tmp.ini
move /y C:\WINDOWS\win_tmp.ini C:\WINDOWS\win.ini
复制代码

xbee

怎样删除

[aspeeder]
count=?

随风

未测试。。。
:

@echo off
>tem echo [aspeeder]
>>tem echo count=1
for /f "delims=" %%a in (c:\windows\win.ini) do >>tem echo %%a
move /y tem c:\windows\win.ini
复制代码