[文本处理] [已解决]BAT如何批量提取多个文本内的共有数？

思想之翼

D:/数据1/内有若干txt文本：
001_1.txt
001_2.txt

002_1.txt
002_2.txt
...
210_1.txt
210_2.txt
欲
提取001_1.txt  001_2.txt共有的数据，写入D:/数据2/001.txt
提取002_1.txt  002_2.txt共有的数据，写入D:/数据2/002.txt
...
提取210_1.txt  210_2.txt共有的数据，写入D:/数据2/210.txt

比如：
001_1.txt内有数据：
01
02
03
001_2.txt内有数据：
02
03
04
05
001_1.txt  001_2.txt共有的数据为：02 03
则将02 03写入D:/数据2/001.txt，数据格式为横排：02 03

思想之翼

回复 8# pcl_test

感谢！问题解决。

pcl_test

回复 7# 思想之翼
添加一行代码，而不是修改原有代码

思想之翼

回复 6# pcl_test

(for /f "delims=" %%b in ('findstr /G:"!n!_1.txt" "!n!_2.txt"') do set /p=%%b )<nul>echo;>>D:\数据2\!n!.txt

这样？问题没有解决，望指教。

pcl_test

回复 5# 思想之翼
此处添加
echo;>>D:\数据2\!n!.txt
)
pause

思想之翼

回复 4# pcl_test

感谢！
发现一个问题：提取出的数据，最后需要添加回车键，能否烦请再帮下忙。

pcl_test

回复 3# 思想之翼

@echo off&setlocal enabledelayedexpansion
cd /d D:\数据1\
for /l %%a in (1001 1 1002) do (
set n=%%a
set n=!n:~1!
(for /f "delims=" %%b in ('findstr /G:"!n!_1.txt" "!n!_2.txt"') do for /f "delims=" %%c in ('findstr "%%b" "!n!_3.txt"') do set /p=%%c )<nul>D:\数据2\!n!.txt
echo;>>D:\数据2\!n!.txt
)
pause
复制代码

思想之翼

回复 2# pcl_test

感谢帮助！
经测试，运行正确、快速。
再请教个问题：若提取001_1.txt  001_2.txt  001_3.txt  三个文本的共有数，上述代码如何扩展？

pcl_test

@echo off & setlocal enabledelayedexpansion
cd /d D:\数据1\
for /l %%a in (1001 1 1210) do (
set n=%%a
set n=!n:~1!
(for /f "delims=" %%b in ('findstr /G:"!n!_1.txt" "!n!_2.txt"') do set /p=%%b )<nul>D:\数据2\!n!.txt
)
pause
复制代码