[系统相关] [已解决]循环1秒，检测到当前打开IE浏览器，自动按F11键全屏。

ygqiang

[已解决]循环1秒，检测到当前打开IE浏览器，自动按F11键全屏。
用啥语言/或者脚本，可以实现？谢谢了。

zhangop9

监测ie 最大化

ygqiang

最终代码如下：

On Error Resume Next
Set objShell = CreateObject("Shell.Application")
Do
  For Each i In objShell.Windows()
    If InStr(1, i.FullName, "\IEXPLORE.EXE", 1) > 0 Then
      If i.TheaterMode = False Then i.TheaterMode = True
    End If
  Next
  WScript.Sleep 1000
Loop
复制代码

(echo On Error Resume Next
echo Set objShell = CreateObject^("Shell.Application"^)

echo Do
echo   For Each i In objShell.Windows^(^)
echo     If InStr^(^1, i.FullName, "\IEXPLORE.EXE", ^1^) ^> ^0 Then
echo       If i.TheaterMode = False Then i.TheaterMode = True
echo     End If
echo   Next
echo   WScript.Sleep 1000
echo Loop
)>"c:\iefull.vbs"
复制代码

ygqiang

最终代码如下：

' VBS 调用API设置IE显示模式（只允许最小化、最大化） by Yu2n
On Error Resume Next
Dim wso
set wso = CreateObject("WScript.Shell")
wso.RegWrite "HKCU\Software\Microsoft\Office\11.0\Excel\Security\AccessVBOM",1,"REG_DWORD"
wso.RegWrite "HKCU\Software\Microsoft\Office\12.0\Excel\Security\AccessVBOM",1,"REG_DWORD"
wso.RegWrite "HKCU\Software\Microsoft\Office\14.0\Excel\Security\AccessVBOM",1,"REG_DWORD"
Dim oExcel, oBook, oModule
Set oExcel = CreateObject("Excel.Application")
Set oBook = oExcel.Workbooks.Add
Set oModule = oBook.VBProject.VBComponents.Add(1)
strCode = _
  "Private Declare Function FindWindow Lib ""user32"" Alias ""FindWindowA"" ( _" & vbCr &_
  "  ByVal lpClassName As String, ByVal lpWindowName As String) As Long" & vbCr &_
  "Private Declare Function GetDesktopWindow Lib ""user32"" () As Long" & vbCr &_
  "Private Declare Function GetWindow Lib ""user32"" ( _" & vbCr &_
  "  ByVal hwnd As Long, ByVal wCmd As Long) As Long" & vbCr &_
  "Private Declare Function GetClassName Lib ""user32"" Alias ""GetClassNameA"" ( _" & vbCr &_
  "  ByVal hwnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long" & vbCr &_
  "Private Declare Function SendMessage Lib ""user32"" Alias ""SendMessageA"" ( _" & vbCr &_
  "  ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long" & vbCr &_
  "Private Declare Function IsZoomed Lib ""user32"" (ByVal hwnd As Long) As Long" & vbCr &_
  "Private Declare Function IsIconic Lib ""user32"" (ByVal hwnd As Long) As Long" & vbCr &_
  "Private Const GW_HWNDFIRST = 0" & vbCr &_
  "Private Const GW_HWNDNEXT = 2" & vbCr &_
  "Private Const GW_CHILD = 5" & vbCr &_
  "Private Const WM_SYSCOMMAND = &H112" & vbCr &_
  "Private Const SC_MAXIMIZE = &HF030&" & vbCr &_
  "Public Sub IE_Maximize()" & vbCr &_
  "  Dim nHWnd As Long" & vbCr &_
  "  Dim s As String * 260" & vbCr &_
  "  nHWnd = GetDesktopWindow()" & vbCr &_
  "  nHWnd = GetWindow(nHWnd, GW_CHILD Or GW_HWNDFIRST)" & vbCr &_
  "  While nHWnd <> 0" & vbCr &_
  "    nHWnd = GetWindow(nHWnd, GW_HWNDNEXT)" & vbCr &_
  "    s = String(256, Chr(0)): GetClassName nHWnd, s, 255: s = Replace(s, Chr(0), """")" & vbCr &_
  "    If InStr(1, s, ""IEFRAME"", vbTextCompare) > 0 Then If nHWnd <> 0 Then WindowMaximize nHWnd" & vbCr &_
  "  Wend" & vbCr &_
  "End Sub" & vbCr &_
  "Private Sub WindowMaximize(ByVal nHWnd As Long)" & vbCr &_
  "  If IsZoomed(nHWnd) = 0 And IsIconic(nHWnd) = 0 Then SendMessage nHWnd, WM_SYSCOMMAND, SC_MAXIMIZE, ByVal 0" & vbCr &_
  "End Sub"
oModule.CodeModule.AddFromString strCode
oExcel.DisplayAlerts = False
Do
  oExcel.Run "IE_Maximize"
  WScript.Sleep 1000
Loop
oBook.Close False
oExcel.Quit
复制代码

ygqiang

IE_Maximize.exe 设置IE显示模式（只允许最小化、最大化）

VB6源码：


使用与结果：
yu2n 发表于 2015-1-11 01:02

   
这个也测试过，确实也好用。。。win7 64+ie9浏览器环境。

CrLf

来段比较暴力的 AutoHotKey：

#SingleInstance force
#Persistent

GroupAdd, IE, ahk_class IEFrame
SetTimer WinMaximizeIE,1000

WinMaximizeIE:
WinMaximize, ahk_group IE
Return
复制代码

CrLf

回复 5# ygqiang


    两个一起用倒是可以全屏并设置 ToolBar=1：

SHWin.FullScreen=True
SHWin.TheaterMode=True
复制代码

不过试了一下好像和 F11 的效果是不太一样，找不到在哪退出全屏

yu2n

IE_Maximize.exe 设置IE显示模式（只允许最小化、最大化）

VB6源码：

使用与结果：

C:\Documents and Settings\Yu2n>IE_Maximize.exe
2015-01-11 00:59:22     Initd.
2015-01-11 00:59:31     Maximize(2230858)
2015-01-11 00:59:41     Maximize(198696)
复制代码

ygqiang

Set SH = CreateObject("Shell.Application")
do
For Each SHWin In SH.Windows
        If  LCase(Right(SHWin.FullName, 12)) = "iexplore.exe" Then
                SHWin.FullScreen=True
        End If
Next
WScript.Sleep 20000

loop
复制代码

CrLf给出的这个代码。win7 64+IE9环境下测试了。
有个问题。F11全屏以后，ie浏览器右上角的最小化和关闭按钮，都找不到了。如果手动按F11键，是没有这个问题的。

CrLf

回复 11# ygqiang


    那个帖子用的是 TheaterMode，我用的是 FullScreen，实测好像没有问题

ygqiang

回复 10# CrLf


    http://www.bathome.net/thread-33661-1-1.html

按f11的话，xp+ie环境好用。
win7 64+ie9环境，就不好用了。

CrLf

来个 F11 的效果

Set SH = CreateObject("Shell.Application")
For Each SHWin In SH.Windows
	If  LCase(Right(SHWin.FullName, 12)) = "iexplore.exe" Then
		SHWin.FullScreen=True
	End If
Next
复制代码

ygqiang

多谢。。。。

yu2n

回复 7# ygqiang
设置 EXCEL 不显示提示即可：

' VBS 调用API设置IE显示模式（只允许最小化、最大化） by Yu2n
On Error Resume Next
Dim wso
set wso = CreateObject("WScript.Shell")
wso.RegWrite "HKCU\Software\Microsoft\Office\11.0\Excel\Security\AccessVBOM",1,"REG_DWORD"
wso.RegWrite "HKCU\Software\Microsoft\Office\12.0\Excel\Security\AccessVBOM",1,"REG_DWORD"
wso.RegWrite "HKCU\Software\Microsoft\Office\14.0\Excel\Security\AccessVBOM",1,"REG_DWORD"
Dim oExcel, oBook, oModule
Set oExcel = CreateObject("Excel.Application")
Set oBook = oExcel.Workbooks.Add
Set oModule = oBook.VBProject.VBComponents.Add(1)
strCode = _
  "Private Declare Function FindWindow Lib ""user32"" Alias ""FindWindowA"" ( _" & vbCr &_
  "  ByVal lpClassName As String, ByVal lpWindowName As String) As Long" & vbCr &_
  "Private Declare Function GetDesktopWindow Lib ""user32"" () As Long" & vbCr &_
  "Private Declare Function GetWindow Lib ""user32"" ( _" & vbCr &_
  "  ByVal hwnd As Long, ByVal wCmd As Long) As Long" & vbCr &_
  "Private Declare Function GetClassName Lib ""user32"" Alias ""GetClassNameA"" ( _" & vbCr &_
  "  ByVal hwnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long" & vbCr &_
  "Private Declare Function SendMessage Lib ""user32"" Alias ""SendMessageA"" ( _" & vbCr &_
  "  ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long" & vbCr &_
  "Private Declare Function IsZoomed Lib ""user32"" (ByVal hwnd As Long) As Long" & vbCr &_
  "Private Declare Function IsIconic Lib ""user32"" (ByVal hwnd As Long) As Long" & vbCr &_
  "Private Const GW_HWNDFIRST = 0" & vbCr &_
  "Private Const GW_HWNDNEXT = 2" & vbCr &_
  "Private Const GW_CHILD = 5" & vbCr &_
  "Private Const WM_SYSCOMMAND = &H112" & vbCr &_
  "Private Const SC_MAXIMIZE = &HF030&" & vbCr &_
  "Public Sub IE_Maximize()" & vbCr &_
  "  Dim nHWnd As Long" & vbCr &_
  "  Dim s As String * 260" & vbCr &_
  "  nHWnd = GetDesktopWindow()" & vbCr &_
  "  nHWnd = GetWindow(nHWnd, GW_CHILD Or GW_HWNDFIRST)" & vbCr &_
  "  While nHWnd <> 0" & vbCr &_
  "    nHWnd = GetWindow(nHWnd, GW_HWNDNEXT)" & vbCr &_
  "    s = String(256, Chr(0)): GetClassName nHWnd, s, 255: s = Replace(s, Chr(0), """")" & vbCr &_
  "    If InStr(1, s, ""IEFRAME"", vbTextCompare) > 0 Then If nHWnd <> 0 Then WindowMaximize nHWnd" & vbCr &_
  "  Wend" & vbCr &_
  "End Sub" & vbCr &_
  "Private Sub WindowMaximize(ByVal nHWnd As Long)" & vbCr &_
  "  If IsZoomed(nHWnd) = 0 And IsIconic(nHWnd) = 0 Then SendMessage nHWnd, WM_SYSCOMMAND, SC_MAXIMIZE, ByVal 0" & vbCr &_
  "End Sub"
oModule.CodeModule.AddFromString strCode
oExcel.DisplayAlerts = False
Do
  oExcel.Run "IE_Maximize"
  WScript.Sleep 1000
Loop
oBook.Close False
oExcel.Quit
复制代码

ygqiang

回复  ygqiang
VBS 调用API设置IE显示模式（只允许最小化、最大化） by Yu2n
yu2n 发表于 2015-1-6 12:24

    关机-弹出的2个窗口提示-能否不提示？