[文件操作] 【已解决】怎样把一个标签的内容复制成一个新的批处理?

nnszuo

在论坛找了下复制自身某段内容到新的批处理文件时都要计算行数的,感觉这样比较麻烦,能不能把一个标签的下的所有内容复制成一个新的批处理
比如把下面标签的内容生成新的批处理

:xin
@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /a-d /b c:\aaa') do (
     set str=%%i
     for /f "tokens=2 delims=. " %%a in ("%%i") do ren "c:\aaa\!str!" !str: %%a=!
)
pause
复制代码

nnszuo

嗯.我那看起来太乱

DAIC

回复 6# nnszuo


建议合理的使用缩进，比如：

@echo off
setlocal enabledelayedexpansion
set "ming="序号1-文本 1" "序号2-文本2" "序号3-文本3"  "序号4-文本4""
set "lu="序号1-%~dp0" "序号2-c:\" "序号3-d:\"  "序号4-e:\"" 
for /f "skip=1 tokens=*" %%i in ('type "%~f0"') do (
    set ii=%%i
    if "%%i" == "::tingzhi" goto yun
    for %%a in (%ming%) do (
        set w=%%~a
        for %%b in (%lu%) do (
            set l=%%~b
            if "%%i%%i" == "::!w:~0,3!::!l:~0,3!" (
                set "s=!l:~4!!w:~4!.vbs"
                cd.>"!s!"
            )
        )
    )
    if not "!ii:~2,2!" == "序号" (
        echo %%i>>!s!
    )
)
复制代码

nnszuo

回复 5# Batcher
感谢讲解,现正学习中,回去看看帮助

nnszuo

回复 2# cjiabing
多谢提示,只要做个特定的标记就行
这是我刚做批处理有需要简化的地方没.或者其他类似的批处理,现在学习中需要更多实例

goto :kaishi
::序号1
str="将文字复制到剪贴板 我是文本1"
Set ws = wscript.createobject("wscript.shell")
ws.run "mshta vbscript:clipboardData.SetData("+""""+"text"+""""+","+""""&str&""""+")(close)",0,true
createobject("scripting.filesystemobject").getfile(wscript.scriptfullname).delete

::序号2
str="将文字复制到剪贴板 我是文本2"
Set ws = wscript.createobject("wscript.shell")
ws.run "mshta vbscript:clipboardData.SetData("+""""+"text"+""""+","+""""&str&""""+")(close)",0,true
createobject("scripting.filesystemobject").getfile(wscript.scriptfullname).delete

::序号3
str="将文字复制到剪贴板 我是文本3"
Set ws = wscript.createobject("wscript.shell")
ws.run "mshta vbscript:clipboardData.SetData("+""""+"text"+""""+","+""""&str&""""+")(close)",0,true
createobject("scripting.filesystemobject").getfile(wscript.scriptfullname).delete

::序号4
str="将文字复制到剪贴板 我是文本4"
Set ws = wscript.createobject("wscript.shell")
ws.run "mshta vbscript:clipboardData.SetData("+""""+"text"+""""+","+""""&str&""""+")(close)",0,true
createobject("scripting.filesystemobject").getfile(wscript.scriptfullname).delete
::tingzhi



:kaishi
@echo off&setlocal enabledelayedexpansion
set "ming="序号1-文本 1" "序号2-文本2" "序号3-文本3"  "序号4-文本4""
set "lu="序号1-%~dp0" "序号2-c:\" "序号3-d:\"  "序号4-e:\"" 
for /f "skip=1 tokens=*" %%i in ('type "%~f0"') do (
set ii=%%i
if "%%i" == "::tingzhi" goto yun
for %%a in (%ming%) do (
set w=%%~a
for %%b in (%lu%) do (
set l=%%~b
if "%%i%%i" == "::!w:~0,3!::!l:~0,3!" (
set "s=!l:~4!!w:~4!.vbs"&&cd.>"!s!"
)
)
)
if not "!ii:~2,2!" == "序号" (@echo %%i>>!s!)
)
:yun
pause>nul
复制代码

Batcher

回复 4# nnszuo


系统自带的帮助文档里面有讲解
more /?
    +n      从第 n 行开始显示第一个文件

%~f0 是指批处理自身这个文件

nnszuo

回复 3# Batcher


我是新手不明白  more +%%i "%~f0" 的意思,可以解释一下么

Batcher

@echo off
for /f "delims=:" %%i in ('findstr /n "^:DynamicScript$" "%~f0"') do (
    more +%%i "%~f0" > new.bat
)
goto :eof

:DynamicScript
@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /a-d /b c:\aaa') do (
     set str=%%i
     for /f "tokens=2 delims=. " %%a in ("%%i") do ren "c:\aaa\!str!" !str: %%a=!
)
pause
复制代码

cjiabing

回复 1# nnszuo


    首先你要区分这段内容与其他代码的区别，找到具体的特征标记，找到开始点和结束点，这样批处理才能认识。
    笼统地说，只要字符前面有一个冒号都算标签了。
    但标签后面的内容从哪里结束？一般标签的结束用的比较多的是goto :eof、pause、exit等，但不是绝对，具体问题具体分析。
所以，答案很简单：
1、直接find到这个标签名“:”——more和for就可以了。
2、将此标签名后面的内容全部写入新建的批处理。FOR处理就可以。
3、根据这段代码的特征判断结束点。比如，以“goto :eof”结束的直接if  /i   "%%a"=="goto :eof"  跳出写入。