[文本处理] 【已解决】批处理命令For /F 取随机空格问题

327025010

@echo off
FOR /F "skip=5" %%i in (Exelist.txt) do call :Cmpexe %%i
Echo.清理完毕
Pause

:Cmpexe
FOR /F %%i IN (Server.ini) DO IF %*==%%i Goto :END
Echo.%*
:END
复制代码

==================================================
%*无法获取含空格全名求解决方案


打包
Exelist.txt 内容

映像名称                       PID 会话名              会话#       内存使用
========================= ======== ================ =========== ============
System Idle Process              0 Services                   0         24 K
System                           4 Services                   0        300 K
含空格 无法获取.exe                      432 Console                    1     25,056 K
wget.exe                      3628 Console                    1      5,192 K

Server.ini内容
wget.exe

Batcher

回复 4# 327025010


明白你的问题了，那个跟%*没有任何关系，是因为第二个for循环需要写成这样：
@echo off
wmic process get name /value > exelist.txt
for /f "tokens=2 delims==" %%i in ('type exelist.txt ^| findstr "="') do call :cmpexe "%%i"
echo 清理完毕
pause
goto :eof

:cmpexe
for /f "delims=" %%i in (server.ini) do if %*=="%%i" goto :eof
echo,%*

327025010

回复 6# apang


    完美解决感谢！

apang

举例：

@echo off
(for /f "delims=" %%a in ('more +7 "%~0"') do echo,^^\"%%a\")>$
echo,Is_Not_System_Process_List:
for /f delims^=^" %%a in ('tasklist /nh /fo csv^|findstr /ivg:$') do (
        echo,%%a
)
pause & Exit/b

;;;System_Process_List;;;
System Idle Process
System
smss.exe
csrss.exe
wininit.exe
csrss.exe
services.exe
lsass.exe
lsm.exe
svchost.exe
winlogon.exe
taskhost.exe
dwm.exe
explorer.exe
taskeng.exe
conhost.exe
dllhost.exe
cmd.exe
tasklist.exe
复制代码

Batcher

回复 4# 327025010


    请举例说明一下我这个代码的执行结果和你希望的结果有什么差异

327025010

回复 3# Batcher


    这样和我加个*号一样啊 无法排除含空格的进程。

Batcher

@echo off
wmic process get name /value > exelist.txt
for /f "tokens=2 delims==" %%i in ('type exelist.txt ^| findstr "="') do call :cmpexe "%%i"
echo 清理完毕
pause
goto :eof

:cmpexe
for /f %%i in (server.ini) do if %*=="%%i" goto :eof
echo,%*
复制代码

Batcher

我不是告诉你用wmic获取进程列表嘛