[已解决]批处理配置mysql5.5.22问题

wangrz421

在网上找到个解决方法，调试后启动mysql报错1067，最后发现是路径问题，
例如：
方法中获得路径是：
D:\test\mysql-5.5.20-win32
但是实际要的是D:/test/mysql-5.5.20-win32
第一次接触批处理，望大家帮忙解决下。

批处理配置mysql方法：
红色部分是获取当前mysql路径

（1）建立三个文件，分别是：service install.bat，temp.txt，update.sql。
（2）在temp.txt文件中写入如下内容：
set PathTemp=
（3）在update.sql文件中写入如下内容：
use mysql
update user set host='%' where user='root' and host='127.0.0.1';
update user set password=password('root') where user='root' and host='%';
quit
（4）在service install.bat文件中写入如下内容：
@echo off
rem @echo off的作用是关闭回显功能

rem 找到当前路径
rem 将temp.txt文件中内容拷贝到temp.bat文件中
rem temp.txt文件中的内容是“set PathTemp=”
rem 特别注意：“=”后面不能加回车
copy temp.txt temp.bat>nul

rem 将路径添加到temp.bat文件中
cd>>temp.bat

rem 执行temp.bat文件中命令
rem temp.bat文件执行后，路径已经保存在PathTemp变量中
call temp.bat

rem 删除temp.bat文件
del temp.bat

rem 设置my-huge.ini的标记位
set tag=[mysqld]

rem 设置添加到my.ini文件中的数据库路径和数据路径
rem set datadir=datadir=%PathTemp%\data的意思是：
rem 将字符串“datadir=”、变量PathTemp对应的字符串以及字符串“\data”赋值给datadir变量
[color=Red]set basedir=basedir=%PathTemp%
set datadir=datadir=%PathTemp%\data[/color]

rem 设置运行环境变量homedir
set homedir=%PathTemp%\bin

rem 设置变量延迟
rem 注意：使用变量延迟后，相关变量用！！包围，这样程序才能正确识别
setlocal enabledelayedexpansion

rem 循环查找my-huge.ini文件中的内容
for /f "tokens=*" %%i in (my-huge.ini) do (

rem 将从my-huge.ini文件中读到的字符串，赋值给变量p
set p=%%i

rem 如果变量p的内容和my-huge.ini的标记位相同
rem 将变量p的内容写入my.ini文件中，同时在其后面加入两行内容：
rem basedir的内容和datadir的内容；
rem 如果不同，只将变量p的内容写入my.ini文件中
if "!p!"== "%tag%" (
echo !p!>>my.ini
echo !basedir!>>my.ini
echo !datadir!>>my.ini
)
if not "!p!"== "%tag%" echo !p!>>my.ini
)

rem 设置安装mysql服务的命令
set installcmd=.\bin\mysqld.exe -install

rem 调用安装命令
call !installcmd!

rem 启动mysql服务
net start mysql

rem 调用update.sql文件中的sql语句，将mysql的远程访问方式打开，以备远程访问服务器；
rem 同时，将mysql的密码更改，本批处理命令将mysql密码更改为root
.\bin\mysql -u root <.\update.sql

rem 重启mysql服务
net stop mysql
net start mysql
复制代码

wangrz421

回复 3# Batcher


  非常感谢，已经解决了。

Batcher

set basedir=basedir=%PathTemp%
set basedir=%basedir:\=/%
复制代码

wangrz421

第一次发帖不太会，第35,36行为获取路径