[文本处理] 批处理如何实现给文本内容添加行号？

wh1234567

文本内容比较多，但每行内容的前面没有序号，想用批处理自动给文本内容每行前面加个行号，请问如何写呢？
例如文本内容如下：
11.txt
需v师德师风
bdbdfbd-dfvd=dfd
231231323223123123232312323[fff]
sddfsfsfsd3231方便更方便
自动处理后格式为：
1-bdbdfbd-dfvd=dfd
2-231231323223123123232312323[fff]
3-sddfsfsfsd3231方便更方便
并输出到另外一个文本22.txt里

elec

回复 3# DAIC


    来一个perl

perl -ne 'print "$.-$_"'     1.txt>2.txt
复制代码

wh1234567

回复 20# terse

不行

terse

编码问题吗 但也不对
如是编码问题的话 10楼代码也不能处理
下面能正确显示不

@echo off
for /f "tokens=1*delims=[]" %%i in ('find /v /n "" ^<11.txt')do echo,%%i-%%j
pause
复制代码

wh1234567

回复 18# DAIC


     是XP的

DAIC

回复 7# wh1234567


    XP还是Win7?

CrLf

回复 14# wh1234567


    我这测试没问题

CrLf

@set @a=0;/*&echo off
cscript /nologo /e:jscript %0 <11.txt >22.txt
pause&exit
*/
str = WScript.StdIn.ReadAll()
str = str.replace(/\r?\n/g,'");WScript.Echo(++i + "-')
str = 'WScript.Echo((i=1)+"-'+str+'")'
eval(str)
复制代码

CrLf

@set @a=0;/*&echo off
findstr /n .* 11.txt |cscript /nologo /e:jscript %0 >22.txt
pause&exit
*/
str = WScript.StdIn.ReadAll()
str = str.replace(/^(\d+):/gm,'$1-')
WScript.Echo(str)
复制代码

wh1234567

回复 11# CrLf


    这个不行，输不出

CrLf

@echo off
((for /f "delims=" %%a in ('findstr /n .* 11.txt') do (
   set "str=%%a"
   set /a n+=1
   setlocal enabledelayedexpansion
   set "str=!str:*:=!"
   echo !n!-!str!
   endlocal
))>22.txt
复制代码

wh1234567

回复 10# CrLf


    哦，这个正常，感谢您了

CrLf

@echo off
for /f %%a in ('find /c /v "" ^<11.txt') do set count=%%a
(for /l %%a in (1 1 %count%) do (
  setlocal enabledelayedexpansion
  set /p "str="&echo;%%a-!str!
  endlocal
))<11.txt >22.txt
复制代码

CrLf

@echo off
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* 11.txt') do echo %%a-%%b)>22.txt
复制代码

CrLf

hash /printf:"%d-%s",number,string /file 11.txt >22.txt
复制代码