[文本处理] [已解决]BAT批处理怎样在一行中，提取多个变量？

lky216

需要操作的文件1.txt内容是
192.168.1.1,192.168.1.2,192.168.1.3,192.168.1.4,192.168.1.5,192.168.1.6,192.168.1.7,
只有一行，这样子的循环下去的，可能有200多个，鄙人用for i到z只能提取几个而已，
求教如何提取呢


解决方法：
1.gawk "gsub(/,/,\"\n\")" a.txt
2.sed "s/,/\n/g" a.txt
3.

@echo off
set /p str=<a.txt
for %%i in (%str%) do (
    echo %%i
)
复制代码

4.

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do set "str=%%i"
echo !str:,=^

!
pause
复制代码

感谢DAIC，感谢PowerShell，感谢terse

tom1

这个系列语句好像可以在《for语句入门到精通》中找到

apang

回复 28# zhanglei1371


    如果要从字串 ab 中间换行，分成两行显示，可以这样：

@echo off
echo,a^

b
pause
复制代码

如果把它用变量表示，就是这样：

@echo off
set NLM=^


echo,a^%NLM%%NLM%b
pause
复制代码

其中的 ^%NLM%%NLM% 代表的是换行，这是第一次转义。
如果再把^%NLM%%NLM%用一个变量表示，还需要再次转义，就成这样子了：

@echo off
set NLM=^


set NL=^^^%NLM%%NLM%^%NLM%%NLM%
echo,a%NL%b
pause
复制代码

zhanglei1371

回复 27# apang


    谢谢，可否解释下含义，看了长时间没看明白

apang

回复 24# zhanglei1371


    如果不开启变量延迟，有一种办法：
http://bathome.l3.wuyou.com/thread-20262-1-1.html

terse

回复 16# lky216
我这里测试可以的 确定 “,”和“，” 的区别

terse

回复 24# zhanglei1371
开启延迟变量  setlocal enabledelayedexpansion
用

echo !str:,=^

!
复制代码

zhanglei1371

回复 13# terse


    这里用
echo %str:,=^

%
为何不行?

522235677

回复 21# DAIC


    是哦，没想起，从来不用逗号来分割

522235677

回复 20# lky216


    在我这都可以，找找你自己的问题

DAIC

回复 18# 522235677


逗号本身也可以作为分隔符，那个字符串替换是多余的。

@echo off
for %%i in (192.168.1.1,192.168.1.12) do (
    echo %%i
)
复制代码

lky216

回复 18# 522235677


    空的，只有按任意键继续。DAIC的，sed和gawk不错，用第三方的也可以拉，

zhanglei1371

回复 15# terse


    是的。为何使用这句会有85个的限制？

522235677

@echo off & setlocal enabledelayedexpansion
for /f "delims=" %%a in (1.txt) do (
	set a=%%a
	set a=!a:,= !
	for %%b in (!a!) do (
		echo %%b
	)
)
pause
复制代码

你看这样行不行呢

lky216

回复 12# DAIC


    哈哈，原来下载的sed是没有i选项的，我从论坛下载一个[new]sed-4.2.1-bin.zip，可以了，不好意思啊，谢谢了。