[系统相关] 能否解释一下中文显示ping处理结果这个批处理

基拉freedom

批处理内容：

@echo off
color f2
echo.
set for=于
set of=的
set with=用
set in=(以
set data:=数据
set milli-seconds:=毫秒为单位)
set Approximate=大约
set times=时间:
set round=来回
set trip=行程
set Reply=应答
set from=来自
set bytes=字节
set time=时间:
set timed=时间
set out=超过
set statistics=统计
set Packets:=包:
set Sent=已发送=
set Received=已收到=
set Lost=已丢失=
set loss)=丢失)
set Minimum=最小值=
set Maximum=最大值=
set Average=平均值=
set TTL=TTL=
setlocal enabledelayedexpansion
set a=
set/p a=请输入要ping的网址或IP   
for /f "delims=" %%i in ('ping %a%') do (
    set ret=
    for %%a in (%%i) do if defined %%a (set ret=!ret!!%%a!) else set ret=!ret! %%a 
    if not "!ret!"=="" (set ret=!ret:time=时间! && echo !ret!) else echo.
)
pause>nul
复制代码

那段for语句能不懂
它是怎么实现set中的替换的？
希望能详细讲解 谢了

batman

@echo off&setlocal enabledelayedexpansion
set "code=for#于 of#的 with#用 in#^(以 data:#数据 milli-seconds:#毫秒为单位^)  Approximate#大约 times#时间: round#来回 trip#行程 Reply#应答 from#来自 bytes#字节: time#时间: timed#接 out.#超时 statistics#统计 Packets:#包: Sent#已发送: Received#已收到: Lost#已丢失: loss^)#丢失^) Minimum#最小值: Maximum#最大值: Average#平均值: TTL#TTL值: Request#连"
for %%a in (%code%) do (
    for /f "tokens=1* delims=#" %%i in ("%%a") do set "%%i=%%j"
)
set /p ip=请输入要ping的网址或IP: 
echo.&set "num=4"
set /p num=请输入ping的次数，默认为4次:
for /f "delims=" %%a in ('ping /n %num% %ip%') do (
    for %%i in (%%a) do (
        if defined %%i (
           set /p=!%%i!<nul
           ) else (
           set /p=%%i <nul
        )
    )
    echo.
)
pause>nul
复制代码

[ 本帖最后由 batman 于 2008-10-2 11:17 编辑 ]