【练习-020】批处理根据输入列出组合

terse

如输入a b a


输入 a b c d e a b

写了一个效率很不高到7位的话 就要近50秒
难度是要能处理相同字符组合
贴出就加分
2天后来加分

CrLf

建议把临时文件名改为纯数字，这样每次循环还可以省去两个set

wankoilz

32楼的代码来自20楼...
楼上分析的在理，但就32楼代码而言for/f读取算不上频繁吧，8个字符执行7次for/f

CrLf

32楼用偏移的办法确实更好，如果是8个排列项，那这种方法就避开了!7次的set和for /l，从而弥补了for /f频繁读写对效率的影响，这种用for /f从文件读取的思路真是太妙了

plp626

32# wankoilz


没测试，
真如你说的话，看来有更快的算法，先收藏。。

wankoilz

6楼并非最快吧...
把6楼代码构造成求8个字符40320个组合，且去掉set/a flag+=1，耗时8秒。

@echo off&setlocal enabledelayedexpansion
set var=a b c d e f g h
echo %time%
(for %%i in (!var!) do (
    set var1=!var:%%i=!
    for %%j in (!var1!) do (
    set var2=!var1:%%j=!
    for %%k in (!var2!) do (
    set var3=!var2:%%k=!
    for %%l in (!var3!) do (
    set var4=!var3:%%l=!
    for %%m in (!var4!) do (
    set var5=!var4:%%m=!
    for %%n in (!var5!) do (
    set var6=!var5:%%n=!
    for %%o in (!var6!) do (
    set var7=!var6:%%o=!
    for %%p in (!var7!) do (
    echo %%i %%j %%k %%l %%m %%n %%o %%p
    )))))))))>c.txt
echo %time%
pause
复制代码

同样的求8个字符40320个组合，下面的耗时不到4秒：

@echo off&setlocal enabledelayedexpansion
set/p s=请输入，用一个空格分开:
echo %time%
set f1=a.txt
set f2=b.txt
>!f1! echo !s:~,1!&set s=!s:~1!
set len=1
for %%a in (%s%) do (
    (for /f %%b in (!f1!) do (
        set tmp=%%b
        for /l %%c in (0,1,!len!) do echo !tmp:~,%%c!%%a!tmp:~%%c!
    ))>!f2!
    set t=!f1!
    set f1=!f2!
    set f2=!t!
    set/a len+=1
)
echo %time%
start %f1%&del/f %f2%
pause
复制代码

我在想for嵌套得太深了是不是会影响效率...

powerbat

最老老实实的枚举法没人关注。。。
怎样对字符串进行可重复组合？
http://www.bathome.net/viewthrea ... muid=29086#pid78176
从一组数字中取任意个数字之和在一个数值范围内
http://www.bathome.net/viewthrea ... muid=29086#pid77555

plp626

要速度就不能call，那么6楼的思路是最快的，

为了短小，我们可以构造一个“制造函数的函数”来制造6楼那个代码，从而支持可变字符个数的排列

16楼和21楼的思路就是如此。。。

wankoilz

我是用的字符插入法，呵呵。
楼上构造for嵌套虽然不错，但效率还是不及20楼。
把21楼代码的%for%改成(%for%)>a.txt，且去掉for中的set/a z+=1 之后效率有所提升，测试8个字符40320个组合耗时近8秒。

CrLf

噢，发现27楼代码就是6楼代码，只是21楼代码是对这种思路的改进

CrLf

那个%for%运行起来就是这个效果：

@echo off&setlocal enabledelayedexpansion&set tmp5=a b c de f 
for %%5 in (!tmp5!) do (
	set tmp4=!tmp5:%%5 =!
	for %%4 in (!tmp4!) do (
		set tmp3=!tmp4:%%4 =!
		for %%3 in (!tmp3!) do (
			set tmp2=!tmp3:%%3 =!
			for %%2 in (!tmp2!) do (
				set tmp1=!tmp2:%%2 =!
				for /f "delims=" %%1 in ("!tmp1:%%2=!") do (
					echo %%5 %%4 %%3 %%2 %%1
				)
			)
		)
	)
)
pause
复制代码

很明显是最土的办法...只是我改进思路后，在执行之前可以自动定义层数，然后用一个变量存储了整个for嵌套，实际运行的代码就是这样子：

@echo off&setlocal enabledelayedexpansion&set tmp5=a b c de f 
for %%5 in (!tmp5!) do ((set tmp4=!tmp5:%%5 =!)&for %%4 in (!tmp4!) do ((set tmp3=!tmp4:%%4 =!)&for %%3 in (!tmp3!) do ((set tmp2=!tmp3:%%3 =!)&for %%2 in (!tmp2!) do ((set tmp1=!tmp2:%%2 =!)&for /f "delims=" %%1 in ("!tmp1:%%2=!") do echo %%5 %%4 %%3 %%2 %%1 ))))
pause
复制代码

CrLf

你们怎么会认为是字符插入呢？这段代码和我所理解的字符插入的概念一点关系都没有呀，看来原有的注释太少，弄详细点：

@echo off&setlocal enabledelayedexpansion
set str= a b c d e f g
set t=%time%
for %%a in (%str%) do (
        set /a n+=1,"tmp+=^!tmp"
        set "echo=%%!n! !echo!"
)
::初始化
set "for=for /f %%1 in ("^^!tmp1:%%2 =^^!") do (set /a z+=1)&echo %echo%"
::定义最里层的for
for /l %%a in (2 1 %n%) do (
        set /a last=%%a-1
        set "for=for %%%%a in (^!tmp%%a^!) do ((set tmp!last!=^!tmp%%a: %%%%a = ^!)&!for!)"
rem 定义for嵌套，一层包一层...
)
::为str构建相应层数的for嵌套
set tmp%n%=%str% 
%for%
::执行组装而成的for嵌套，改成echo !for!就明白了
echo 共有%z%种组合 开始于%t% 结束于%time%
pause
复制代码

wankoilz

楼上是字符插入的方法啊。
caruko 发表于 2011-5-21 19:13

是字符插入法。

CrLf

反正5040种组合耗时3秒，应该算不错的成绩了

CrLf

22# caruko


？？
不懂...