[日期时间] 批处理怎么取上一个小时的yyyymmddhhmiss格式的时间字符串？

xd502djj

怎么取上一个小时的yyyymmddhhmiss格式的时间字符串

xd502djj

谢谢啊 非常好用 就是下面的两个函数看不明白呀 本人批处理技术实在太差
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
这个是什么意思啊  还有后面的算法就更不明白了

HAT

@echo off
set TimeBegin=%date:~0,10% %time:~0,8%
set SecondInter=3600
call :DateToSecs %TimeBegin:~0,4% %TimeBegin:~5,2% %TimeBegin:~8,2% %TimeBegin:~11,2% %TimeBegin:~14,2% %TimeBegin:~17,2% SecondsBegin
set /a SecondsEnd=SecondsBegin-SecondInter
call :SecsToDate %SecondsEnd% YearEnd MonthEnd DayEnd HourEnd MinuteEnd SecondEnd
set TimeEnd=%YearEnd%%MonthEnd%%DayEnd%%HourEnd%%MinuteEnd%%SecondEnd%
echo,%TimeEnd%
pause
goto :eof

:DateToSecs %yy% %mm% %dd% %hh% %nn% %ss% secs
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3&set hh=%4&set nn=%5&set ss=%6
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
if 1%hh% LSS 20 set hh=0%hh%
if {%nn:~2,1%} EQU {p} if "%hh%" NEQ "12" set hh=1%hh%&set/a hh-=88
if {%nn:~2,1%} EQU {a} if "%hh%" EQU "12" set hh=00
if {%nn:~2,1%} GEQ {a} set nn=%nn:~0,2%
set /a hh=100%hh%%%100,nn=100%nn%%%100,ss=100%ss%%%100
set /a j=j*86400+hh*3600+nn*60+ss
endlocal&set %7=%j%&goto :EOF

:SecsToDate %secs% yy mm dd hh nn ss
setlocal ENABLEEXTENSIONS
set /a i=%1,ss=i%%60,i/=60,nn=i%%60,i/=60,hh=i%%24,dd=i/24,i/=24
set /a a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
(if %hh% LSS 10 set hh=0%hh%)&(if %nn% LSS 10 set nn=0%nn%)
if %ss% LSS 10 set ss=0%ss% 
endlocal&set %7=%ss%&set %6=%nn%&set %5=%hh%&^
set %4=%dd%&set %3=%mm%&set %2=%yy%&goto :EOF
复制代码