[其他] [已解决]批处理怎样获取文件夹路径并根据结果生成文件夹？

001011

比如文件夹路径是：G:\文件\九\0501\06.21\2010-10套-目的地-1-10
首先获取文件夹路径 然后根据最后面的1-10（有可能是其他数字，但是“-”的左右最多不超过3位）生成对应的文件夹：1、2、3、4、5、6、7、8、9、10
如果路径是：G:\文件\九\0501\06.21\2010-10套-目的地-102-108，生成对应的文件夹为：102、103、104、105、106、107、108
谢谢指教！

mstsc

学习中   不是很懂

001011

@echo off
cd /d G:\
for /r /d %%i in (*-*-*) do (
    set _path=%%i
    setlocal enabledelayedexpansion
    for /f "tokens=1,2 delims=?" %%i in ("!_path:-=\!\..?!_path:-=\!") do (
        for /l ...
tmplinshi 发表于 2011-6-26 17:48

非常好用  非常好的论坛  谢谢啦

lvsehuaxue

@echo off
for /f "tokens=1-5 delims=-" %%i in ('dir /s /ad /b G:\文件\九\0501\06.21') do (
    for /l %%a in (%%l 1 %%m) do (
        md %%i-%%j-%%k-%%l-%%m\%%a
    )
)
pause
复制代码

tmplinshi

@echo off
cd /d G:\
for /r /d %%i in (*-*-*) do (
    set _path=%%i
    setlocal enabledelayedexpansion
    for /f "tokens=1,2 delims=?" %%i in ("!_path:-=\!\..?!_path:-=\!") do (
        for /l %%a in (%%~ni 1 %%~nj) do md "!_path!\%%a"
    )
    endlocal
)
pause
复制代码

001011

文件夹生成到哪里？
tmplinshi 发表于 2011-6-26 17:33

谢谢您的回复  生成在获取文件夹路径的文件夹

001011

@echo off&setlocal enabledelayedexpansion
set "paths=G:\文件\九\0501\06.21\2010-10套-目的地-1-10"
for %%a in (%paths%) do (
  set "str=%%~na"&set "str=!str:-=.!"
  for %%a in (!str!) do (
    s ...
batman 发表于 2011-6-26 17:33

谢谢您  但是我要获取的的路径是有变化的 生成的文件夹也是根据路径而变化的

001011

生成在获取文件夹路径的文件夹

batman

@echo off&setlocal enabledelayedexpansion
set "paths=G:\文件\九\0501\06.21\2010-10套-目的地-1-10"
for %%a in (%paths%) do (
  set "str=%%~na"&set "str=!str:-=.!"
  for %%a in (!str!) do (
    set "max=%%~xa"
    for %%b in (%%~na) do set "min=%%~xb"
  )
)
for /l %%a in (%min:~1%,1,%max:~1%) do md "%paths%\%%a"
复制代码

tmplinshi

文件夹生成到哪里？

001011

这个可以获取路径：
@ECHO OFF
set AAA=%0
FOR %%i in (%AAA%) do (echo %%~dpi>a.txt)
type a.txt
pause

001011

“-”的左右,不会出现左大 右小的现象