【练习-004】批处理重命名特殊文件名

batman

---------------------------------------------------------------------------------------------------------------------------------------------

文件夹下有三个由字母、数字、汉字、特殊字符组成文件名的文件同时批处理自身也在其中：
一b!a!1235@_ s%#8i  三 c.rar
h^e12 0~%l%!p!@. s321-的文件.txt
%o%%% !O!ffi9~  ce$- Wor8d29 文档.docx
重命名.bat
图1：

---------------------------------------------------------------------------------------------------------------------------------------------
要求运行批处理将这三个文件文件名中的数字、汉字、特殊字符全部(含空格)去掉，而重命名为只含字母的文件，但
后缀名不能更改，同时批处理自身名字不能更改，重命名后：
basic.rar
helps.txt
oOfficeWor.docx
重命名.bat
图2：

---------------------------------------------------------------------------------------------------------------------------------------------
要求：代码简洁、通用、效率不至于太低。
---------------------------------------------------------------------------------------------------------------------------------------------

qixiaobin0715

考虑的还不是太完善：

@echo off
for %%a in (*) do (
    if "%%~nxa" neq "%~nx0" (
        set "filename=%%~na"
        set "str=%%a"
        setlocal enabledelayedexpansion
        set "filename=!filename: =!
        for /l %%b in (0,1,50) do (
            set "str1=!filename:~%%b,1!"
            echo,!str1!|findstr [a-z]>nul 2>nul&&set str2=!str2!!str1!
        )
        ren "!str!" "!str2!%%~xa"
        set str2=
        endlocal
    )
)
pause
复制代码

ai20110304

回复 2# pusofalse


    在你思路上进行严格地判断改进了下：

@echo off
cd /d %~dp0
::思路：通过字母字符范围大小，逐个字符比较，保留英文字母。
for /f "delims=" %%i in ('dir /b /a-d') do (
	::排除批处理自身
	if "%%~nxi" neq "%~nx0" (	
		
		::截取文件名，不含扩展名
		set "name=%%~ni" & set "old=%%~nxi"
		::避免文件名中有感叹号，动态感知变量值的变化
		setlocal enabledelayedexpansion
		
		set "name1=!name!" & call :loop
		echo;!nam!		
		ren "!old!" "!nam!%%~xi"
		
		::用完一次清除该变量。避免下次使用还有残留值。
		set "nam="	
		
		endlocal
	)
)

pause>nul & goto :eof

:loop
if defined name1 (
	::逐个截取字符作判断
	set "var=!name1:~0,1!"
	::忽略大小写，保证值在字母头尾之间
	if /i "!var!" leq "Z" (
		if /i "!var!" geq "A" (
			::满足上面两个条件下作字符串拼接，即有效文件名拼接。
			set "nam=!nam!!var!"
		)
	)
	::每次循环后，从左往右依次截断字符串。直至把字符串截取完成空。
	set "name1=!name1:~1!"
	goto loop
)
复制代码

ai20110304

回复 5# batman

for /f "tokens=%n% delims=%str% " %%a in ("%var%") 
复制代码

变量引用有误，原文件名字符串中含感叹号包裹，会造成感叹号之间的字母当作变量是为空值不存在。如：一b!a!1235@_ s%#8i  三 c.rar    ----> !a!    最后处理出来是 : bsic.rar
应防止变量值中含感叹号，该这样写：

for /f "tokens=%n% delims=%str% " %%a in ("!var!")
复制代码

测试成功。
感谢5楼提供的处理思路。

无忧

能不能直接用通配符呢………………
比如*.doc 然后改成你想要的就可以了…………反正也只有唯一的三种文件，不用担心改错……

尘丶

@echo off
set "z=a b c d e f g h i j k l m n o p q r s t u v w x y z"
for /f "delims=" %%a in ('dir /b *^|findstr /vc:"%~nx0"') do (
set k=
set wenben=%%~na
set wenjian=%%a
setlocal enabledelayedexpansion
	for /l %%b in (0,1,50) do (
	    set zimu=!wenben:~%%b,1!
		for %%c in (!z!) do (
	  	    if /i "!zimu!"=="%%c" set k=!k!!zimu!
	  	)
	)
ren "!wenjian!" "!k!%%~xa"
endlocal
)
pause
复制代码

dishuo

原帖由 pusofalse 于 2008-8-5 23:34 发表
看到terse前辈的代码，忽然闪现了一个思路，但立刻消失了，觉得这题肯定有更简单的方法。
只需思考一个问题，如何把字母从这一堆特殊字符中提取出来即可。

根据 pusofalse斑竹的思路，提取字符最方便的工具肯定是正则表达式，批处理命令唯一一个支持正则的就是findstr，能不能用它来提取呢？
测试成功！
满足要求：简洁、通用、效率不至于太低。
特点：通用性很强，只需要修改 findstr 的正则参数就能实现各种功能，举几个例子。
　　　"[^-!-~0-9a-z]"  保留全角字符（中文、全角标点等）
　　　"[a-z0-9]"　　 保留英文字母和数字

@echo off&cls
for /f "tokens=*" %%i in ('dir /b/a-d "*.*"') do (
    if "%%~nxsi" neq "%~nxs0" (
        set "旧文件名=%%~nxsi"&set "文件名串=%%~ni"&set "新文件名="&set "counter=0"
        del ~filenamechar.lst /q>nul 2>&1
        setlocal enabledelayedexpansion
        call :split
        for /f "tokens=*" %%n in ('findstr "[a-z]" ~filenamechar.lst') do set "新文件名=!新文件名!%%n"
        if "!新文件名!" neq "" (
            echo ren !旧文件名! !新文件名!%%~xi
        ) else (
            echo  ^(文件"!旧文件名!"不含字母,不能重命名.^)
        )
        endlocal
    )
)
del ~filenamechar.lst /q>nul 2>&1
pause&goto :eof

:split
if "!文件名串:~%counter%,1!" neq "" (
    if "!文件名串:~%counter%,1!" neq " " echo !文件名串:~%counter%,1!>>~filenamechar.lst
    set /a counter+=1
    goto split
)
goto :eof

pusofalse

我可是测试了好多遍的，特殊字符无非就是那么几个而已。

愚无尽

很有意思的说。。。。

tjtchly

楼上的没用。不用达到目的。

pusofalse

写了将近一个小时，做是做出来了，但并不简洁。

@echo off
for %%a in (*.*) do (
 if "%%~nxa" neq "%~nx0" (
 set "name=%%~na"
 call,set name=%%name: =%%
 call,set name=%%name:!=%%
 setlocal enabledelayedexpansion
 for /l %%s in (0 1 9) do set name=!name:%%s=!
 set name=!name:%%=!
 for %%s in (@ _ # . $ - ^&) do set name=!name:%%s=!
 call :lp !name!
 echo !nam!%%~xa&set "nam="
 endlocal
))
pause&exit/b
:lp
for /f "tokens=1* delims=~" %%l in ("%1") do (
 set "n=!n!%%l
 if "%%m" neq "" (
 call :lp %%m
 ) else (
 for %%a in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do set n=!n:%%a= %%a !
 for %%a in (!n!) do if "%%a" geq "a" if "%%a" leq "Z" set nam=!nam!%%a
))
复制代码

pusofalse

看到terse前辈的代码，忽然闪现了一个思路，但立刻消失了，觉得这题肯定有更简单的方法。
只需思考一个问题，如何把字母从这一堆特殊字符中提取出来即可。

terse

@echo off
for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do set %%i=a
for %%i in (*.*) do (
    if not "%%~nxi"=="%~nx0" (
        set "name=%%~ni"
        setlocal enabledelayedexpansion
        set name1=!name!
        call :lp
        ren "!name!%%~xi" "!nam!%%~xi"
        set "nam="
        endlocal
     )
  )
pause&goto :eof
:lp
if defined name1 (
   set "var=!name1:~,1!"
   if defined !var! set "nam=!nam!!var!"
   set name1=!name1:~1!
   goto lp
)
复制代码

more

原帖由 batman 于 2008-7-28 01:16 发表

我都测试了N次了，怎么会不成功

昨天晚上测试的时候不行,今天早上却可以,怪...

batman

原帖由 more 于 2008-7-28 00:53 发表
5楼的代码运行不成功

我都测试了N次了，怎么会不成功