[其他] [已解决]请教文件压缩批处理

qq370135415

@echo off
::如果E盘没有Output\1文件夹，创建Output\1。
if not exist "E:\Output\1" mkdir "E:\Output\1"
::将C:\OutFolder\1里面的所有文件和文件夹压缩成单独的压缩文件，并放到E:\Output\1。
for /f "usebackq tokens=1* delims=\" %%a in (`dir /b "C:\OutFolder\1"`) do (rar.exe a -ep1 -r0 -exit -- "E:\Output\1\%%a.rar" "C:\OutFolder\1\%%a")

::如果E盘没有Output\test文件夹，创建Output\test。
if not exist "E:\Output\test" mkdir "E:\Output\test"
::将C:\OutFolder\test里面的所有文件和文件夹压缩成单独的压缩文件，并放到E:\Output\test。
for /f "usebackq tokens=1* delims=\" %%a in (`dir /b "C:\OutFolder\test"`) do (rar.exe a -ep1 -r0 -exit -- "E:\Output\test\%%a.rar" "C:\OutFolder\test\%%a")

::如果E盘没有Output\asd文件夹，创建Output\asd。
if not exist "E:\Output\asd" mkdir "E:\Output\asd"
::将C:\OutFolder\asd里面的所有文件和文件夹压缩成单独的压缩文件，并放到E:\Output\asd。
for /f "usebackq tokens=1* delims=\" %%a in (`dir /b "C:\OutFolder\asd"`) do (rar.exe a -ep1 -r0 -exit -- "E:\Output\asd\%%a.rar" "C:\OutFolder\asd\%%a")

pause
复制代码

首先这是一个用来批量压缩文件的批处理

目的是将C:\OutFolder目录下的所有文件夹里的文件压缩备份到E:\Output目录下 并把每个文件压缩成单独的文件



最后完成的效果是 C:\OutFolder\1\456.txt  变成 E:\Output\1\456.rar

                              C:\OutFolder\test\1.txt           E:\Output\test\1.rar

                              C:\OutFolder\asd\abc.txt        E:\Output\asd\abc.rar

也就是只把盘符和后缀名变了一下

或者说把C:\OutFolder下的所有文件单独压缩一下然后将C:\OutFolder复制到E盘下





请教 如果C:\OutFolder目录下有很多文件夹怎样来实现

lanni654321

看来懂得东西  还是很少呢……

qq370135415

非常感谢版主！谢谢！

hanyeguxing

如果要改变路径:

@echo off&setlocal enabledelayedexpansion
set "r=C:\OutFolder"
set "s=E:\Output"
for /r "%r%" %%a in (*) do (
        set "d=%%~dpa"
        md "!d:%r%=%s%!" 2>nul
        rar.exe a -inul -m5 "!d:%r%=%s%!%%~na.rar" "%%a"
)
复制代码

hanyeguxing

@echo off
for /r "C:\OutFolder" %%a in (*) do (
	md "e:%%~pa" 2>nul
	rar.exe a -inul -m5 "e:%%~pna.rar" "%%a"
)
复制代码