naiveboy520

我要看答案   没办法了

vsbat

**********************************************************************************
【程序37】
题目：对10个数进行排序
1.程序分析：可以利用选择法，即从后9个比较过程中，选择一个最小的与第一个元素交换，
　　　　　　下次类推，即用第二个元素与后8个进行比较，并进行交换。
**********************************************************************************

@echo off
setlocal enabledelayedexpansion
for /l %%l in (1 1 10) do set /p a%%l=请输入第%%l个数: 
for /l %%k in (1 1 9) do (
set max=%%k
for /l %%i in (%%k 1 10) do (call,set mm=%%a!max!%%&if !a%%i! gtr !mm! (set max=%%i))
call,set t=%%a!max!%%&set a!max!=!a%%k!&set a%%k=!t!)
echo\
echo 从大到小排序后如下：
for /l %%j in (1 1 10) do echo !a%%j!
pause>nul
复制代码

::选择法排序
：：原理是设序号max它代表最大数的序数，先假设max为1----然后把他与其他一一比较---比它大就把那个数的序号赋给max--这样从1到9比较下来最大的数的序数就确定下开了--然后把它与a1交换==
使其为首位----然后利用循环 对 从2开始的数重复此过程---把第二大的数挑出来--
一直到第9大的数，即外循环是9次
从而实现从大到小排序----------
代码中注意--变量嵌套==

[ 本帖最后由 vsbat 于 2009-11-1 21:03 编辑 ]

vsbat

set/a res=%%a*%%b
                set "res=!res!  " %======此处用来对齐=========%
                set/p=%%ax%%b=!res:~0,2!  <nul   

7 楼的这个 对齐 真是让人学习啦------------每次 res  都是两个字符----
这样在 3x3=9  4x3=12 处就都对得齐了---------

loveyuto

不好意思，刚才打错了一个数字

@echo off&setlocal EnableDelayedExpansion
set a=1
for /l %%i in (1,1,10) do (
echo 倒数第%%i天时有!a!个桃子
set /a a=a+1
set /a a=a*2
)
pause
复制代码

loveyuto

@echo off&setlocal EnableDelayedExpansion
set a=1
for /l %%i in (2,1,10) do (
echo 倒数第%%i天时有!a!个桃子
set /a a=a+1
set /a a=a*2
)
pause
复制代码

loveyuto

楼主的好像不太对哟。

@echo off&setlocal EnableDelayedExpansion
echo 倒数第1天时有1个桃子
set a=1
for /l %%i in (2,1,10) do (
set /a a=a+1
set /a a=a*2
echo 倒数第%%i天时有!a!个桃子)
pause
复制代码

ghostwar

感觉好难咯！
   继续努力！
  楼主你等我的答案哈！

tuifei

tuifei  来学习·····

vsbat

程序1:
题目：有1、2、3、4个数字，能组成多少个互不相同且无重复数字的三位数？都是多少？
1.程序分析：可填在百位、十位、个位的数字都是1、2、3、4。组成所有的排列后再去
　　　　　　掉不满足条件的排列。

@echo off
set a=0
for /l %%i in (1 1 4) do ( 
      for /l %%j in (1 1 4) do ( if %%i neq %%j (
            for /l %%k in (1 1 4) do if %%i neq %%k (
                     set/a a=a+1&if %%k neq %%j   echo %%i  %%j  %%k))))
echo       共 %a% 个
pause
                                                  
                                                  
复制代码

先做一个题----^-^

[ 本帖最后由 vsbat 于 2009-10-17 19:27 编辑 ]

基拉freedom

好久没来了
稍微做几题：
第一题 记得用递归可以做...但这里就用for了

@echo off
for /l %%i in (1 1 4) do (
for /l %%k in (1 1 4) do (
if %%i neq %%k (
	for /l %%j in (1 1 4) do (
	if %%j neq %%i if %%j neq %%k (
    for /l %%x in (1 1 4) do (
    if %%x neq %%j if %%x neq %%i if %%x neq %%k echo %%i%%k%%j%%x
    )
	)
	)
)
)
)
pause
复制代码

乘法表是什么东西？？看看对不对

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 9) do (
for /l %%k in (1 1 %%i) do (
set /a a=%%k *%%i
set a= !a!
set a=!a:~-2!  
set g=!g!"%%k*%%i=!a!"
)
echo !g:"=!
set a=
set g=
)
pause
复制代码

水仙花树
9*10*10=900 效率差不多吧？？

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 9) do (
for /l %%k in (0 1 9) do (
for /l %%j in (0 1 9) do (
set /a a=%%i*100+%%k*10+%%j
set /a b=%%i*%%i*%%i+%%k*%%k*%%k+%%j*%%j*%%j
if !a! equ !b! echo 百位 %%i  十位 %%k  各位 %%j
)
)
)
复制代码

就只做这么多了 用其他语言都做过了 呵呵 回味一下
不错

starjaymy

这好像不适合新手做吧。。

dominater

好帖子 用来练习for再好不过 对我学习c++也有极大帮助啊

wangshuping42

**********************************************************************************
【程序1】
有1、2、3、4个数字，能组成多少个互不相同且无重复数字的三位数？都是多少？
**********************************************************************************

@echo off
for %%i in (1 2 3 4) do (
   for %%j in (1 2 3 4) do (
      if %%j neq %%i (
         for %%k in (1 2 3 4) do (
   if %%k neq %%i (
      if %%k neq %%j (echo %%i%%j%%k)
)
                     )
               )
        )
)
pause>nul
复制代码

**********************************************************************************
【程序2】
输入某年某月某日，判断这一天是这一年的第几天？  
**********************************************************************************

@echo off
set days=0&setlocal enabledelayedexpansion
set /p date=请输入日期（日期格式 xxxx.xx.xx）：
for /f "tokens=1,2,3 delims=./ " %%i in ("%date%") do (
     set "year=%%i"&set "month=%%j"&set "day=%%k"
     set "run=%%j"
  )
for %%l in (0 31 28 31 30 31 30 31 31 30 31 30 31) do (
    set /a days=days+%%l
    set /a month=month-1
    if !month! equ 0 (goto a)
)
:a
set /a days=%day%+!days!
if %run% equ 1 (goto b)
set /a b=year%%400
set /a c=year%%4
set /a d=year%%100
if %b% equ 0 (set /a days=1+days&goto b)
if %c% equ 0 (
   if %d% neq 0 (
      set /a days=1+days
    )
)
:b
echo %date% 是 %year% 年的第 %days% 天
pause>nul
复制代码

**********************************************************************************
【程序3】
输出9*9口诀。
**********************************************************************************

@echo off&set n=0
for /l %%i in (1 1 9) do (
    set a=%%i
for /l %%j in (1 1 9) do (
    set b=%%j
    call :a
   )
    echo.
)
pause>nul
:a
if %b% gtr %a% (goto :eof)
set /a num=a*b
set /p "=%a%x%b% = %num% " <nul
set /a n=n+1
goto :eof
复制代码

**********************************************************************************
【程序4】
输出101-200之间所有的素数。
**********************************************************************************

@echo off
for /l %%i in (101 1 200) do (
    set a=%%i &set n=0
    call :calc
)
pause>nul
:calc
for /l %%j in (2 1 15) do (
    set b=%%j
    call :op
   )
if %n% equ 0 (echo %a%)
goto :eof
:op
set /a yu=a%%b
if %yu% equ 0 (set n=1)
goto :eof
复制代码

**********************************************************************************
【程序5】
打印出所有的“水仙花数”，所谓“水仙花数”是指一个三位数，其各位数字立方和等于该数本身。例如：153是一个“水仙花数”，因为153=1^3＋5^3＋3^3
**********************************************************************************

@echo off
for /l %%i in (1 1 9) do (
        set a=%%i
  for /l %%j in (0 1 9) do (
        set b=%%j
    for /l %%k in (0 1 9) do (
        set c=%%k
        set num=%%i%%j%%k
        call :calc
        )
    )
)
pause>nul
:calc
set /a sum=a*a*a+b*b*b+c*c*c
if %num% equ %sum% (echo %num%)
goto :eof
复制代码

**********************************************************************************
【程序6】
将一个正整数分解质因数。例如：输入90,打印出90=2*3*3*5。  
**********************************************************************************

@echo off
set n=1
set /p num=请输入一个数字：
set /p "=%num%=" <nul
:start
for /l %%i in (2 1 %num%) do (
   set a=%%i
   call :sp
)
pause>nul
:sp
set /a yu=num%%a
set /a sh=num/a
if %yu% equ 0 (
   set /a num=sh
   if %n% neq 1 (set /p "=*" <nul)
   set /p "=%a%" <nul & set n=0
   goto start
)
复制代码

**********************************************************************************
【程序7】
输入两个正整数m和n，求其最大公约数和最小公倍数。
**********************************************************************************

@echo off
set /p n=请输入数字 n=
set /p m=请输入数字 m=
if %m% gtr %n% (
  set /a min=n & set /a max=m
      ) else (
  set /a min=m & set /a max=n
  )
for /l %%i in (%min% -1 1) do (
   set a=%%i
   call :sp
)
:an
echo 最大公约数是 %a%
echo 最小公倍数是 %b%
pause>nul &exit
:sp
set /a y1=n%%a
set /a y2=m%%a
set /a s=max%%min
if %s% equ 0 (
    set /a b=max ) else (
      set /a b=max*min
      )
if %y1% equ 0 (
  if %y2% equ 0 (
    if %y1% equ %y2% (goto an)
    )
)
复制代码

[ 本帖最后由 wangshuping42 于 2009-9-30 14:36 编辑 ]

nopr

@echo off
setlocal enabledelayedexpansion
:1
set/a b+=1
for /l %%j in (1 1 4) do (
     set a=□■
     set/p=!a!<nul)
echo.
for /l %%i in (1 1 4) do (
     set a1=■□
     set/p=!a1!<nul)
echo.
if %b% geq 4 pause>nul&goto :eof
call :1
复制代码

就是棋盘有点小!

nopr

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1,1,9) do (
     echo.
     for /l %%j in (1,1,9) do (
     set /a aa=%%i*%%j
     set a=%%jx%%i=!aa!
     if %%j leq %%i set/p=!a! <nul
     )
     )
pause>nul
复制代码