ppll2030

回复 19# qixiaobin0715


    感谢指导。看来是字体问题了。
换了自带记事本，依然混乱。

buyiyang

回复 19# qixiaobin0715


    显示宽度其实是取决于字体，等宽还是比例，全角和半角等，控制台一般是consoles字体，是等宽的，全角输入中英文字符也是相同宽度。

qixiaobin0715

回复 18# ppll2030
输出的txt文件你用“记事本”打开看看。
不同的文本编辑器，字符不同占用宽度可能会有区别。

ppll2030

回复 17# qixiaobin0715


    请问大佬，有没有办法输出到txt还能保持队形的。
上面的大佬们都是cmd下输出结果。
计算最大字符串并补齐空格，这个我也搞出来了。
就是不能输出到txt还保持不变形。

qixiaobin0715

回复 12# 娜美
只要计算出每列的最大字节数，以及各列字节数与最大字节数的差值，然后用空格补齐即可。
可能会稍微复杂些，抽空试试。

newswan

假如知道最大宽度是10

awk '{ printf "%-10s %-10s %-10s\n", $1, $2, $3 }' a.txt
复制代码

shenlong

回复 14# aloha20200628


    万分感谢，达到预期效果。

aloha20200628

回复 11# shenlong

参考12楼的经验，谢谢 重写了9楼代码，用以下1.txt示例文件测试效果明显 楼主可试试...
1.txt》
aa  自x车 1232   米
mm命名  abc 5555  米
bbbbb  密码可靠 66  米
同轴3xx   国产321   456 米

qixiaobin0715

这样可能要美观一些：

@echo off
for /f "tokens=1-3" %%i in (a.txt) do (
    echo,%%i>>temp1
    echo,%%j>>temp2
)
set /a n1=n2=0,y1=y2=0
setlocal enabledelayedexpansion
for %%a in (1 2) do (
    echo,a>>temp%%a
    for /f "delims=:" %%i in ('findstr /o .* temp%%a') do (
        set /a x%%a=%%i-y%%a
        if !n%%a! lss !x%%a! set /a n%%a=x%%a
        set y%%a=%%i
    )
    del temp%%a
    set /a n%%a+=4
for /l %%i in (1,1,!n%%a!) do set BS%%a= !BS%%a!
)
(for /f "tokens=1-2*" %%i in (a.txt) do (
    if "%%j"=="" (set f1=%%i) else (set f1=%%i!BS1!&set f1=!f1:~,%n1%!)
    if "%%k"=="" (set f2=%%j) else (set f2=%%j!BS2!&set f2=!f2:~,%n2%!)
    set f3=%%k
    echo,!f1!!f2!!f3!
))>b.txt
pause
复制代码

娜美

字节不同 要对齐  似乎只能改用制表符

awk  -v OFS="\t"  '{print $1,$2,$3}' a.txt
复制代码

shenlong

回复 7# aloha20200628


    多谢帮助。

shenlong

回复 8# qixiaobin0715


    多谢，效果可以，就用这个了。

aloha20200628

回复 1# shenlong

@echo off &setlocal enabledelayedexpansion &set "maxZ=0"
for /f "delims=" %%a in (1.txt) do for %%s in (%%a) do (
	set "s=%%s" & (call :_strLen s z)
	if !z! gtr !maxZ! set "maxZ=!z!"
)
set "ms=" &for /l %%n in (1,1,!maxZ!) do set "ms=!ms! "
endlocal &set "maxZ=%maxZ%"&set "ms=%ms%"
setlocal enabledelayedexpansion
for /f "delims=" %%a in (1.txt) do (
	set "s="
	for %%s in (%%a) do (set "_s=%%s"&set "_s=!_s!%ms%"&set "s=!s!	!_s:~0,%maxZ%!")
	echo,!s:~1!
)
endlocal&pause&exit/b
:_strLen
   set "_str=_!%~1!" &set "_Len=0"
   for %%n in (64 32 16 8 4 2 1) do (
      if "!_str:~%%n,1!" neq "" (set/a "_Len+=%%n"&set "_str=!_str:~%%n!")
   )
   set "%~2=!_Len!" &exit/b
复制代码

特此备注》重写了原代码，改用批处 ‘原装’ 的字符串长度计算方法，再请出制表符 ‘显灵’，似乎消除了以前格式化输出时中英文字符混合字段的占位问题...

qixiaobin0715

只能这样勉为其难了：

@echo off
setlocal enabledelayedexpansion
type a.txt>temp
echo,a>>temp
set /a n=0,y=0
for /f "delims=:" %%i in ('findstr /o .* temp') do (
    set /a x=%%i-y
    if !n! lss !x! set /a n=x
    set y=%%i
)
del temp
for /l %%i in (1,1,!n!) do set BS= !BS!
for /f "tokens=1-2*" %%i in (a.txt) do (
    set f1=%%i!BS!
    set f2=%%j!BS!
    echo,!f1:~,%n%!!f2:~,%n%!%%k
)
pause
复制代码

aloha20200628

回复 1# shenlong

文本行的格式化输出，须确定最大列宽即最大字段长度。简单处理是由楼主预设一个最大列宽值，否则就要实时遍历整个文本文件获取其中最大字段长度...
给一个批处版本，代码如下》获取文本文件中的最大字段长度，假设字段分隔符是批处默认的空格、逗号、分号、等号和制表符。

@echo off &setlocal enabledelayedexpansion &set "maxZ=0"
for /f "delims=" %%a in (1.txt) do for %%s in (%%a) do (
	set/p="%%s"<nul>0.0
	for %%b in (0.0) do if %%~zb gtr !maxZ! set "maxZ=%%~zb"
)
echo,!maxZ!
del/q "0.0"&endlocal&pause&exit/b
复制代码