[出题]批处理限制输入只能为字母且个数在3-10之间 - 出题挑战 - 批处理之家 BAT,CMD,批处理,PowerShell,VBS,DOS - Powered by Discuz!

批处理之家 » 出题挑战 » [出题]批处理限制输入只能为字母且个数在3-10之间

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

返回列表发帖

Rank: 8 Rank: 8

帖子: 1759
积分: 5387
技术: 51
捐助: 210
注册时间: 2007-10-26

10楼 跳转到 »

发表于 2009-3-27 23:03 | 只看该作者

batcher 真是细心 echo.%input% 就可以解决了

技术问题请到论坛发帖求助！

Rank: 12

帖子: 14935
积分: 46142
技术: 857
捐助: 745
注册时间: 2008-6-9

9楼

发表于 2009-3-27 23:01 | 只看该作者

回复 4楼的帖子

输入off
代码出现误判
^_^

我帮忙写的代码不需要付钱。如果一定要给，请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家，加入VIP会员！】http://bbs.bathome.net/thread-67716-1-1.html

Rank: 8 Rank: 8

帖子: 1759
积分: 5387
技术: 51
捐助: 210
注册时间: 2007-10-26

8楼

发表于 2009-3-27 22:55 | 只看该作者

回复 7楼的帖子

I 服了 you !
思路倒是不错，只是代码。。。。。

技术问题请到论坛发帖求助！

Rank: 6 Rank: 6

帖子: 381
积分: 1801
技术: 9
捐助: 0
注册时间: 2008-10-27

7楼

发表于 2009-3-27 22:50 | 只看该作者

@echo off&setlocal enabledelayedexpansion
:repeat
set /p input=请输入: 
echo !input!>%temp%\#tmp#
findstr /xi "[a-z][a-z][a-z] [a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z]" %temp%\#tmp# >nul || goto repeat
pause
复制代码

或者：

@echo off
:repeat
set /p input=请输入: 
(call set/p="%%input%%"<nul&echo.)>%temp%\#tmp#
findstr /xi "[a-z][a-z][a-z] [a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z] [a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z][a-z]" %temp%\#tmp# >nul || goto repeat
pause
复制代码

[ 本帖最后由 tireless 于 2009-3-27 23:47 编辑 ]

1 评分人数

随风: 思路还是不错的！PB + 2

Rank: 12

帖子: 14935
积分: 46142
技术: 857
捐助: 745
注册时间: 2008-6-9

6楼

发表于 2009-3-27 22:50 | 只看该作者

@echo off
rem 限制输入3位至10位字母
set LenMin=3
set LenMax=10
set AllLetter=a b c d e f g h i j k l m n o p q r s t u v w x y z

:GetInput
set input=
set /p "input=请输入3至10位字母："
if "%input%" neq "" (
  if "%input:~2,1%" equ "" (
    echo 不足%LenMin%位
    goto :GetInput
  ) else if "%input:~10,1%" neq "" (
    echo 多于%LenMax%位
    goto :GetInput
  )
) else (
  echo 输入不能为空
  goto :GetInput
)
setlocal enabledelayedexpansion
for %%a in (%AllLetter%) do (
  set input=!input:%%a=!
  if "!input!" equ "" (
    goto :RightInput
  )
)
if "!input!" neq "" (
  echo 只能输入纯字母[a-zA-Z]
  endlocal
  goto :GetInput
)

:RightInput
echo 恭喜输入正确
pause
复制代码

[ 本帖最后由 Batcher 于 2009-3-29 14:20 编辑 ]

1 评分人数

随风: 对各种错误都进行了明确提示，导致代码超长PB + 5

我帮忙写的代码不需要付钱。如果一定要给，请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家，加入VIP会员！】http://bbs.bathome.net/thread-67716-1-1.html

Rank: 8 Rank: 8

帖子: 1759
积分: 5387
技术: 51
捐助: 210
注册时间: 2007-10-26

5楼

发表于 2009-3-27 22:46 | 只看该作者

回复 4楼的帖子

>nul2>nul 两句中间应该要个空格吧。

技术问题请到论坛发帖求助！

Rank: 6 Rank: 6

帖子: 187
积分: 3145
技术: 4
捐助: 0
注册时间: 2008-10-30

4楼

发表于 2009-3-27 22:39 | 只看该作者

@echo off
:repeat
set/p input=请输入: 
if "%input:~2,1%" equ "" goto repeat
if "%input:~10,1%" neq "" goto repeat
echo.%input%|findstr/i "^[a-z]*$">nul2>nul||goto repeat
pause
复制代码

[ 本帖最后由 zhouyongjun 于 2009-3-27 23:08 编辑 ]

1 评分人数

随风: 不错！PB + 8

Rank: 8 Rank: 8

帖子: 1759
积分: 5387
技术: 51
捐助: 210
注册时间: 2007-10-26

3楼

发表于 2009-3-27 22:15 | 只看该作者

回复 2楼的帖子

未对大小写作判断。。

1 评分人数

tireless: delims里的字母竟区分大小写，才知道。PB + 2

技术问题请到论坛发帖求助！

Rank: 6 Rank: 6

帖子: 381
积分: 1801
技术: 9
捐助: 0
注册时间: 2008-10-27

2楼

发表于 2009-3-27 22:07 | 只看该作者

@echo off
:repeat
set /p input=请输入: 
if "%input:~2,1%" equ "" goto repeat
if "%input:~10,1%" neq "" goto repeat
for /f "delims=abcdefghijklmnopqrstuvwxyz" %%a in ("%input%") do (
  if "%%a" neq "" goto repeat
)
pause
复制代码

2 评分人数

随风: 不错！PB + 5
pusofalse: 精彩PB + 8