newswan

支持全角字符
awk -f format-table.awk data.txt

function getWidth(str,LenStr,LenASC,LenHZ) {
	LenStr = length(str)
	LenASC = gsub( /[\x00-\x7F]/ , "" , str )
	LenHZ = length(str) / length("一")
	return  LenASC + LenHZ * 2
}

function getLengthHZ(str,LenHZ) {
	gsub( /[\x00-\x7F]/ , "" , str )
	LenHZ = length(str) / length("一")
	return  LenHZ
}

BEGIN {
	FS = " "
	while ( getline < ARGV[1] ) {
		for (i = 1; i <= NF; i++) {
			len = getWidth($i)
			if ( len > maxWidth[i] ) {
				maxWidth[i] = len
			}
		}
	}
#	print "--maxWidth--"
#	for ( i in maxWidth ) {
#		printf "%4s" , maxWidth[i]
#	}
#	printf "\r\n"
#	print "----"
}

{
	for (i = 1; i <= NF; i++) {
		LenHZ = getLengthHZ($i)
		printf "%-*s:" , maxWidth[i] + LenHZ , $i
	}
	printf "\r\n"
}
复制代码

注意 第 35 行 由于 awk 环境不同，可能是 "+ LenHZ" 可能是 "- LenHZ"

aloha20200628

用7楼获取全文最大字段长度的方法（中英文字符按存储字节数计算长度）可以进一步简化34楼所用计算方法中须区分中英文字符的步骤...

@echo off &setlocal enabledelayedexpansion &set "maxZ=0"
for /f "delims=" %%a in (1.txt) do for %%s in (%%a) do (
	set/p="%%s"<nul>"0.0"
	for %%b in (0.0) do if %%~zb gtr !maxZ! set "maxZ=%%~zb"
)
for /f "delims=" %%a in (1.txt) do (
	set "ss=" &for %%s in (%%a) do (
		set/p="%%s"<nul>"0.0" &for %%b in (0.0) do set/a "z=maxZ-%%~zb"
		set "_s="&for /l %%k in (1,1,!z!) do set "_s=!_s! "
		set "ss=!ss! %%s!_s!"
	)
	echo,!ss:~1!
)
del/q "0.0"&endlocal&pause&exit/b
复制代码

aloha20200628

关于中英文混合文本行的对齐输出最终取决于显示字体
已知的 ‘英文用一个字节，中文用2个字节’ 是指存储单位，而每个字符被物理显示到屏幕上的 ‘显示宽度’ 还是要看所选字体
选择中英文字符等宽字体可以简化算法步骤（因批处的字符串截取偏移量视同中英文字符偏移量=1），但显示观感会大打折扣
而选择中英文字符显示宽度成等分关系的字体（例如英文字符占1个显示宽度，中文字符占2个显示宽度，而cmd简中窗口的默认字体即为此型字体）须实时获取每个字段的显示宽度与 ‘全文最长字段’ 显示宽度的差距，此差距即所谓 ‘每个字段的空格填充量’，由此确保每行各列不等长字段能够对齐显示，据此原理调整了9楼代码如下，并已在cmd简中窗口中实测多种样本（最长混合字段可自定义，列数可自定义）均予顺利通过...

@echo off &setlocal enabledelayedexpansion &set "maxZ=0"
for /f "delims=" %%a in (1.txt) do for %%s in (%%a) do (
	set "s=%%s"&set "_len="&(call :_strLen)
	if !_len! gtr !maxZ! set "maxZ=!_len!"
)
for /f "delims=" %%a in (1.txt) do (
	set "ss=" &for %%s in (%%a) do (
		set "s=%%s"&set "_len="&(call :_strLen)
		set/a "z=maxZ-_len"&set "_s="&for /l %%k in (1,1,!z!) do set "_s=!_s! "
		set "ss=!ss! %%s!_s!"
	)
	echo,!ss:~1!
)
endlocal&pause&exit/b
:_strLen //逐个字符计算》中文字符累加2，英文字符累加1。
   if not defined s exit/b
   if "!s:~0,1!" gtr "Z" (set/a "_len+=2") else (set/a "_len+=1")
   set "s=!s:~1!" &goto :_strLen
复制代码

newswan

回复 29# 娜美

前面发的都没计算全角字符
#36 #37  计算了全角，用 ":" 分隔字段

ppll2030

回复 31# buyiyang


    厉害了。大佬这个应该是完美通用版了。

buyiyang

回复 25# ppll2030

这个不限列数，还用了两种方法算字符宽度。

@echo off
chcp 437 >nul
set "Separator=@"
set "inputfile=a.txt"
setlocal enabledelayedexpansion
:loop
set /a column+=1
set /a #C%column%max=mark=0
for /f "tokens=%column%" %%i in (%inputfile%) do (
    call :strlen "%%i"
    if !len! geq !#C%column%max! set /a #C%column%max=len
    set mark=1
    )
if %mark% equ 1 goto :loop
set /a column-=1
chcp 936 >nul
set /a lines=0
(for /l %%i in (1,1,%column%) do call :output %%i)>$.temp
set "Separator="&set arg=" delims=%Separator%" "rem"
set "inputfile=$.temp"&(for /l %%i in (1,1,%lines%) do call :output %%i %arg%)>output_%inputfile%
del /q $ $.temp
pause&exit

:strlen
set "str=_%~1"
set "len=0"
for %%n in (64 32 16 8 4 2 1) do (
    if "!str:~%%n,1!" neq "" (
        set/a "len+=%%n"
        set "str=!str:~%%n!"
        )
)
exit /b
:output
if %1 equ 1 goto :output_2
for /f "tokens=1,%1%~2" %%a in (%inputfile%) do (
    if "%%b"=="" (set "field=-") else set "field=%%b"
    %~3 set/p="!field!"<nul>$&for %%i in ($) do (set len=%%~zi)
    %~3 set /a spaceNum=!#C%1max!-len+2,n+=1
    set "outstr=!outstr!%Separator%!field!"
    %~3 for /l %%i in (1,1,!spaceNum!) do set "outstr=!outstr! "
    )
%~3 if %n% geq %lines% set /a lines=n
%~3 set /a n=0
echo,!outstr!
set "outstr="
exit /b
:output_2
for /f "tokens=%1%~2" %%a in (%inputfile%) do (
    if "%%a"=="" (set "field=-") else set "field=%%a"
    %~3 set/p="!field!"<nul>$&for %%i in ($) do (set len=%%~zi)
    %~3 set /a spaceNum=!#C%1max!-len+2,n+=1
    set "outstr=!outstr!%Separator%!field!"
    %~3 for /l %%i in (1,1,!spaceNum!) do set "outstr=!outstr! "
    )
%~3 if %n% geq %lines% set /a lines=n
%~3 set /a n=0
echo,!outstr!
set "outstr="
复制代码

buyiyang

回复 20# buyiyang

批处理没有格式化输出，要对齐要注意两点：
    1.等宽字体和比例字体。等宽字体每个西文宽度相同，才能对齐；而比例字体会将西文宽度按比例调整以便于观看。中文一般都是等宽的。
    2.全角和半角。半角字符占1个标准字符宽度，西文（包括空格）一般为半角；而全角字符占2个标准字符宽度，中文均为全角。
楼上批处理是根据字节计算宽度的，有findstr算偏移量、for的%%~zi增强扩展算size的,都是根据：
    在ansi（gb2312）编码中一个汉字必须是两个值大于127的字节连在一起，并兼容ASCII。所以一个汉字=2个字节=2个标准字符宽度，一个ASCII字符=1个字节=1个标准字符宽度。
其实可以通过if比较区分每个字符是中文还是英文。
还有通过控制台437代码页将双字节的字符分成两个字符来算字符宽度的方法。
如果是utf-8等其他编码方式则会不同。

娜美

回复 26# newswan

长度如果不超过宽度基本没有问题

   但如遇到这样的长短都不一

aa          1232    米
bbbbb     66       米
b 66  米 
cccccccccccccccccccccccccccccccccccc    c   cccccccccccccccccccccccccccccc  cc   c          米 c
c cc    ccc     v          米
补补补补补补补补补补补补补补补补补  cccccccccccccccccccccccccccccc          补补补补补补补补补补补补补补补补补       c       c                 c
补  c                      cccccccccccccccccccccccccccccc    c             c                c
复制代码

想要完全解决问题,  似乎需要检查每1列最后一个空格在什么位置, 记录最后一个空格位置数值,  再用空格来填充所有,   才可以彻底解决

newswan

powershell

$file = Get-Content -Path "data.txt" -Encoding UTF8
$maxlen = @(0) *10

$file | ForEach-Object {
	$arr = $_  -split "\s+"
	for ( $i =0 ; $i -lt $arr.count ; $i++ ){
		if ( $maxlen[$i] -lt ($arr[$i]).length ) {
			$maxlen[$i] = ($arr[$i]).length
		} 
	}
}
$maxlen = $maxlen -join " " -replace "( 0)*" -split "\s+"

$file | ForEach-Object {
	$arr = $_  -split "\s+"
	$str = ""
	for ( $i =0 ; $i -lt $arr.count ; $i++ ){
		$str += ($arr[$i]).PadRight($maxlen[$i]," ") + "  "
	}
	write-host ( $str -replace "\s$","" )
}
复制代码

Five66

不如将空格换成tab
文本编辑器来打开时会自行处理

newswan

保存为 a.awk ,然后 awk -f a.awk a.txt

BEGIN {
	FS = " "
	while ( getline < ARGV[1] ) {
		for (i = 1; i <= NF; i++) {
			if ( length($i) > maxlen[i] ) {
				maxlen[i] = length($i)
			}
		}
	}
}

{
	for (i = 1; i <= NF; i++) {
		printf "%-*s\t",maxlen[i],$i
	}
	printf "\r\n"
}
复制代码

ppll2030

我也发一个吧。也是用字节数补齐空格的方式。
就是代码啰嗦了一些。而且局限列数为5列。
不知道还能不能精简，望各位老大指点一二。

@echo off 
setlocal enabledelayedexpansion 
rem 计算字符的字节，cmd下输出是对齐状态，导出txt会变形，需改换等宽字体，cmd默认是Consolas。
REM 获取文本最大字符串的字节
for /f "delims=" %%a in (1.txt) do for %%s in (%%a) do (
	set/p="%%s"<nul>$
	for %%b in ($) do if %%~zb gtr !maxZ! set "maxZ=%%~zb"
)
for /f "tokens=1-4*  delims= " %%a in (1.txt) do (
    rem 获取每列字符串的字节
    set "a=%%a"&set "b=%%b"&set "c=%%c"&set "d=%%d"&set "e=%%e"
    set/p="%%a"<nul>$&for %%i in ($) do (set az=%%~zi) 
    set/p="%%b"<nul>$&for %%i in ($) do (set bz=%%~zi) 
    set/p="%%c"<nul>$&for %%i in ($) do (set cz=%%~zi) 
    set/p="%%d"<nul>$&for %%i in ($) do (set dz=%%~zi) 
    set/p="%%e"<nul>$&for %%i in ($) do (set ez=%%~zi) 
    rem 获取每列字符串的字节差，并用空格补齐
    set/a Na=!maxZ!-!az!&set/a Nb=!maxZ!-!bz!&set/a Nc=!maxZ!-!cz!&set/a Nd=!maxZ!-!dz!&set/a Ne=!maxZ!-!ez!
    for /l %%i in (1,1,!Na!) do set "a=!a! "
    for /l %%i in (1,1,!Nb!) do set "b=!b! "
    for /l %%i in (1,1,!Nc!) do set "c=!c! "
    for /l %%i in (1,1,!Nd!) do set  "d=!d! "
    rem for /l %%i in (1,1,!Ne!) do set  "e=!e! "
    echo !a! !b! !c! !d! !e!
)
del/q $&pause&exit
复制代码

qixiaobin0715

按照各列字节数与最大字节数的差值，然后用空格补齐的方法，适用含有中文字符的列：

@echo off
set colsn=4
set /a colsn-=1
for /f "tokens=1-%colsn%" %%1 in (a.txt) do (
    echo,%%1>>temp1
    echo,%%2>>temp2
    echo,%%3>>temp3
)
setlocal enabledelayedexpansion
for /l %%a in (1,1,%colsn%) do (
    echo,a>>temp%%a
    set /a x=n%%a=0
    for /f "tokens=1,2 delims=:" %%i in ('findstr /n /o .* temp%%a') do (
        set /a "x%%a=%%j-x"
        set /a "m=%%i-1"
        set "n%%a#!m!=!x%%a!"
        if !n%%a! lss !x%%a! set /a "n%%a=x%%a"
        set "x=%%j"
    )
    del temp%%a
)
for /f "tokens=1-%colsn%*" %%1 in (a.txt) do (
    set /a "n+=1"
    set f=
    set "f1=%%1"
    set "f2=%%2"
    set "f3=%%3"
    for /l %%x in (1,1,%colsn%) do (
        set /a "m%%x=n%%x-n%%x#!n!"
        for /l %%y in (1,1,!m%%x!) do set "f%%x=!f%%x! "
        set "f=!f!!f%%x!    "
    )
    echo,!f!%%4
)
pause
复制代码

由于未及仔细考虑，代码存在以下缺点：
1.代码过于复杂，可读性差；
2.除最后一列外，其余各行各列字节数均预先设置变量，处理较大文件时，速度可能会比较慢，甚至超出变量设置的上限而出错；
3.上面代码是按4列文本来处理的，如果列数有变化，需要对以上代码进行修改（虽然写代码时，考虑到了列数变化时，尽量减少修改量），通用性不是太好。

下面举例说明列数变化时，代码调整的方法：
1.如果文本内容的列数为3列，代码做如下调整：
第2行变量值修改为3；
删除第7行；
删除第27行；
将第33行的%%4改为%%3；
2.如果文本内容的列数为5列，代码做如下调整：
第2行变量值修改为5；
第7行下面增加一行：echo,%%4>>temp4
第27行下面增加一行：set "f4=%%4"
将第33行的%%4改为%%5；

newswan

1 字体的宽度，夹杂中文，更纱一个字体，能完全对齐
2 中文的宽度，上面的所有方案，都没有计算中文宽度，用制表符处理误差，一旦前面中文过多，也不能对齐。

ppll2030

回复 20# buyiyang


    感谢解惑。更换字体后txt文件得到对齐的结果了。