WHY

多个关键词同时遍历，显然更快更科学；先删目录，再删文件，显然更快更科学。

@echo off
setlocal enabledelayedexpansion
for /f "tokens=*" %%i in (config.ini) do (
    set key=!key! "*%%i*"
)
endlocal & set key=%key%

for /f "delims=" %%i in ('dir /b /ad /s %key% ^| sort /r') do (
    rd /s /q "%%i"
)
del /s /a /f /q %key%
pause
复制代码

aloha20200628

回复 8# lovekix

稳妥起见（避免搜索文件与搜索目录仅为部分交集而有漏删），先遍历各目录删除所有包含指定搜索词的文件，再遍历各目录删除所有包含同一搜索词的目录及其子目录，利用 rd 命令的容错性，任其自行处理即可...

@echo off & for /f "delims=" %%c in (config.ini) do (
	for /f "delims=" %%F in ('dir /b/s/a-d "*%%c*" ') do del /f/q "%%F"
	for /f "delims=" %%D in ('dir /b/s/ad "*%%c*" ') do rd /s/q "%%D"
) 2>nul
pause&exit/b
复制代码

lovekix

回复 10# WHY

ar-sa
af-za
am-et
as-in
az-latn-az
arab~und-arab
bg-bg
bn-in
bs-latn-ba
ba-ru
be-by
bn-bd
beng~und-beng
复制代码

我把 这些放在了  config.ini文件里面了
怎么才能快速的删除 包含 这些的文件夹和文件

lovekix

回复 11# 77七


    又有文件夹  又有文件

77七

楼主可以添加点文字描述，不要以代码代表...

楼主代码中的 ar-SA 指的是文件还是文件夹？

WHY

windows 文件系统本身是不区分大小写的，dir 如果区分大小写就没意义了。

del 删除文件时，支持搜索子目录，支持通配符。
dir + findstr + del ，或者 dir + del 都是多此一举。

del /s /a /f /q *af-ZA* *am-ET* *ar-SA* *bg-BG* *az-Latn-AZ*
复制代码

可以添加很多关键字，只要命令总长度不超过 8192 字符就行。

rd 删除目录需要 dir 辅助，因为子目录必须 sort /r

aloha20200628

回复 8# lovekix
如果 config.ini 文件每行内容如下：
af-ZA
...
zh-TW
可用以下代码

@echo off & for /f "delims=" %%c in (config.ini) do (
    for /f "delims=" %%i in ('dir /b /s /a-d "*%%c*" ') do del /a /f /q "%%i"
)
pause&exit/b
复制代码

lovekix

回复  lovekix

可以。但其实 dir /b /s /a-d^|findstr /i "ar-sa" 还可以简化如下
       dir /b /s / ...
aloha20200628 发表于 2024-9-1 13:54

    可以 吧ar-sa .....
写到一个 config.ini 里面 吗？

aloha20200628

回复 5# lovekix

可以。但其实 dir /b /s /a-d^|findstr /i "ar-sa" 还可以简化如下
       dir /b /s /a-d "*ar-sa*"
       dir /b /s /ad "*ar-sa*"
dir 不区分路径文件名大小写
用 dir /b/s ... 搜索匹配的结果是全路径文件名/目录名，可直接交付给 del/rd 操作，没必要再用 pushd ...

lovekix

-------------

lovekix

回复 4# aloha20200628


    对对对   忘记了

这样对吗

) do (for /f "delims=" %%i in ('dir /b /s /ad^|findstr /i %%c') do rd /s/q "%%i")
pause&exit/b
复制代码

aloha20200628

回复 3# lovekix

删除文件用 del
删除目录用 rd
但有可能目录中包含与目录名搜索词不匹配的文件...
可在命令行分别用 del /? 和 rd /? 查看用法详解

lovekix

回复 2# aloha20200628

@echo off
for %%c in (
   "af-ZA"
   "am-ET"
    ....... 
   "zh-TW"  
) do (for /f "delims=" %%i in ('dir /b /s /a-d^|findstr /i %%c') do del /a /f /q "%%i")
pause&exit/b
复制代码

要是 想把文件夹和文件都删除 是不是  只要去掉  /a-d

aloha20200628

第一问》findstr 加 /i 参数即可

for /f "delims=" %%i in ('dir /b /s /a-d^|findstr /i "ar-sa"') do del /a /f /q "%%i"
复制代码

第二问》可将所有搜索字段 "a..." 至 "z..." 逐行复制到以下代码第2至第7行之间即可

@echo off
for %%c in (
   "af-ZA"
   "am-ET"
    .....
   "zh-TW"  
) do (for /f "delims=" %%i in ('dir /b /s /a-d^|findstr /i %%c') do del /a /f /q "%%i")
pause&exit/b
复制代码