buyiyang

回复 9# aloha20200628

http://www.bathome.net/redirect. ... 9133&pid=282222

aloha20200628

回复 8# buyiyang

试试7楼的代码运行结果，应该总是显示‘成功’，除非在for之前errorlevel已被赋予非零值...

buyiyang

回复 7# aloha20200628

if errorlevel 0 如何证明 errorlevel 会被预赋值为零

aloha20200628

在任何一个复合语块（如for或if）中的 %var% 变量均会被预先赋值，errorlevel亦是%var%
例如下式中的 errorlevel 会被预赋值为零，而无视循环体内每次 rar.exe 的真实返回值
假定下式中的 abc.zip, 123.rar 均为不存在的压缩包文件...

@echo off &for %%F in ("abc.zip" "123.rar") do (
	rar.exe x %%F 2>nul >nul
	if errorlevel 0 (echo,解压成功) else echo,解压失败
)
pause&exit/b
复制代码

ppll2030

@echo off
set "input=D:\我的文档\桌面\批量压缩文件\实例\A"
set "output=D:\我的文档\桌面\批量压缩文件\实例\B"
rem 采用7zip压缩，请修改为实际路径
set "exe=D:\实际路径\7-Zip\7z.exe"
set "pwd=20240731QWEasd"
pushd %input%
(for /d %%d in (*) do (
	"%exe%" a -p%pwd% -t7z "%output%\%%d.7z" ".\%%d\*" >nul 2>nul
	if errorlevel 1 (
			echo %DATE% %TIME% %%~fd --- 压缩失败
		) else (
			echo %DATE% %TIME% %%~fd --- 压缩成功
		)
	
))>%~dp0LOG.txt
popd
start "" LOG.txt
exit/b
复制代码

77七

回复 4# 304802301


  

@echo off
rem 保存为ansi
rem 代码使用winrar\下的rar.exe，使用需添加到系统环境变量，或者写明绝对路径
cd /d "%~dp0"
set pwd=QWEasd
set f1=D:\实例_20240731_151654\A
set f2=D:\实例_20240731_151654\C
set log=d:\1.txt

md "%f2%" 2>nul
pushd "%f1%"
call :getdt d
(for /d %%d in (*) do (
	pushd "%%d"
	for /f "delims=" %%a in ('forfiles /s /m * /c "cmd /c if @isdir equ FALSE echo @relpath"') do (
		call :getdt
		set /p="%%~dpa,%%~nxa,"<nul
		rar a "%f2%\%%d.zip" -p%d%%pwd% "%%~a" 1>nul 2>nul
		if errorlevel 1 (
			echo 压缩失败
		) else (
			echo 压缩成功
		)
	)
	popd
))>>"%log%"
pause
exit

	:getdt
	for /f %%a in ('wmic os get localdatetime ^|findstr [0-9]') do (
		set t=%%a
	)
	if "%~1" equ "d" (
		set %~1=%t:~0,4%%t:~4,2%%t:~6,2%
	) else (
		set /p="%t:~0,4%年%t:~4,2%月%t:~6,2%日%t:~8,2%时%t:~10,2%分%t:~12,2%秒,"<nul
	)
	exit /b
复制代码

304802301

回复 2# 77七


    再补充下，只要A路径下的子文件夹，每个子文件夹及下面的文件+文件夹都打包成一个压缩包即可（不考虑再下一层子还是否有子文件夹的情况）。

304802301

回复 2# 77七

压缩过程中把压缩结果输出到指定路径的日志文件里，包含时间、文件名字、源文件的完整路径、压缩结果
XXXX年XX月XX日XX点XX分XX秒，XX路径，XX文件名，压缩成功
XXXX年XX月XX日XX点XX分XX秒，XX路径，XX文件名，压缩失败


就类似这种的日志格式，大致上差不多就行

77七

上传3个文件夹和3个压缩包没什么意义...
日志文件相比来说更需要说明，请给个示例