WHY

@if(0)==(0) echo off
pushd "D:\Test"
for /f "tokens=1*delims=|" %%i in ('dir /b *_*.pdf ^| cscript -nologo -e:jscript "%~f0"')do (
    echo ren "%%i" "%%j"
)
pause & exit
@end

var max = 0, arr = [];
var reg = /_([0-9]+)(?=\....$)/;

while (!WSH.StdIn.AtEndOfStream) {
    var file = WSH.StdIn.ReadLine();
    var m = file.match(reg);
    if (!m) continue;
    if (max < m[1].length) max = m[1].length;
    arr.push(file);
}

var zero = new Array(max).join('0');
var reg1 = new RegExp('_[0-9]{' + max + '}(?=\....$)');

for (var i = 0; i < arr.length; i++) {
    if (arr[i].match(reg1)) continue;
    var newFile = arr[i].replace(
        reg,
        function(s0,s1){return '_' + (zero + s1).slice(-max)}
    )
    WSH.Echo(arr[i] + '|' + newFile);
}
复制代码

WHY

回复 14# buyiyang


    这个可能跟 CMD 预处理机制本身有关。

echo;a&echo;b
pause
复制代码

保存为批处理，运行后可以看到预处理之后的样子：echo;a  & echo;b
echo;a后面为两个空格，多出了一个空格。CMD 它想这么解析，没办法。

buyiyang

回复 13# ppll2030


    %%a已经是被"_"分割后的第二个数字字段了，findstr /o 通过偏移值获得%%a的长度，.pdf是4，另一个数字应该也是4（两个引号、回车、换行），
但(echo "%%a"&echo.)通过管道却多了一个空格，所以实际是5，我的问题是为什么会多空格。

ppll2030

回复 10# buyiyang
我的理解是， “新建文档_” = 5    “.pdf” = 4

buyiyang

回复 11# ShowCode
执行

(echo,a)>1.txt
复制代码

1.txt十六进制为：

61 0D 0A
复制代码

echo,a|find /v "">1.txt
61 0D 0A 
复制代码

(echo,a)|find /v "">1.txt
61 20 0D 0A
复制代码

(echo,a&echo,b)>1.txt
61 0D 0A 62 0D 0A
复制代码

(echo,a&echo,b)|more>1.txt
61 20 0D 0A 62 20 0D 0A 0D 0A 
复制代码

主要是疑惑为什么通过管道会多空格字符（20h)。

ShowCode

回复 10# buyiyang


在CMD窗口里面执行这个命令应该能理解：

(echo "ABC"&echo.)|findstr /o ".*"
复制代码

buyiyang

回复 8# ShowCode


    请问这里"set /a StrLen=%%i-5-4"的 5 是怎么得来的？

aloha20200628

用纯P拿下本帖的一个看点是如何准确简捷地获取文件名末尾的序号最大长度（无论序号连续与否），给一个请findstr出场的版本，其一是goto方案，是可控循环。其二是for/L方案，是不可控循环，只能预设上限。
第3行代码用了老帖中关于!v!续命传值给%v%的方法，此处用之为免其后截取变量字符串时不必调用for句式方可完成的开销。
代码可存为test.bat，将目标目录拖至脚本运行即可完成其中文件更名，如*_1.pdf 》*_001.pdf

@echo off &setlocal enabledelayedexpansion
dir /b/s/a-d "%~1\*.pdf">0.0 & (call :getMax 0.0 m)
(endlocal & set "max=%m%") & setlocal enabledelayedexpansion
for /L %%n in (1,1,%max%) do set "p=0!p!"
for /f "delims=" %%F in (0.0) do (
   set "xF=%%~xF"
   for /f "tokens=1-2 delims=_" %%1 in ("%%~nF") do (set "q=!p!%%2" & ren "%%~F" "%%1_!q:~-%max%!!xF!")
)
del 0.0 & endlocal & exit/b
:getMax // %1=listF %2=digits
  :[loop]
  set/a "k+=1" & set "n=!n![0-9]" & findstr "!n!\.pdf" %1>nul && goto[loop] || (set/a "%~2=k-1" & exit/b)
复制代码

随附 for/L 方案如下仅供参考

:getMax // %1=listF %2=digits
  for /L %%n in (0,1,9) do set "n=!n![0-9]" & findstr "!n!\.pdf" %1>nul || (set/a "%~2=%%n" & exit/b)
复制代码

ShowCode

回复 1# qd2024

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
set "MaxLen=0"
for /f "tokens=2 delims=_" %%a in ('dir /b /a-d *_*.pdf') do (
    for /f "skip=1 delims=:" %%i in ('^(echo "%%a"^&echo.^)^|findstr /o ".*"') do (
        set /a StrLen=%%i-5-4
    )
    if !StrLen! gtr !MaxLen! (
        set "MaxLen=!StrLen!"
    )
)
set "MaxNum=1"
for /l %%a in (1,1,!MaxLen!) do (
    set /a MaxNum=MaxNum*10
)
for /f "tokens=1* delims=_" %%a in ('dir /b /a-d *_*.pdf') do (
    set "FileNum=%%b"
    set "FileNum=!MaxNum!!FileNum:~0,-4!"
    ren "%%a_%%b" "%%a_!FileNum:~-3!%%~xb"
)
复制代码

pd1

如果数字不连续或者不是从1开始  这样试试

<# :
@echo off
powershell -NoProfile -ExecutionPolicy bypass "Get-Content -literal '%~f0' |Out-String|Invoke-Expression"
pause
#>
$file=dir *.pdf
$max=($file|%{[int]$_.BaseName.split("_")[1]}|Measure-Object -Maximum).Maximum
$n=([string]$max).Length
$file|%{ren $_ ([regex]::Replace($_.name,'(?<=_)\d+',{param([string]$a) "{0:d${n}}" -f [int]$a}))}
复制代码

pd1

我是直接看文件个数判断总位数的，如果你数字从1开始不间断的可以这样试试

<# :
@echo off
powershell -NoProfile -ExecutionPolicy bypass "Get-Content -literal '%~f0' |Out-String|Invoke-Expression"
pause
#>
$file=dir *.pdf
$n=([string]$file.Length).Length
$file|%{ren $_ ([regex]::Replace($_.name,'(?<=_)\d+',{param([string]$a) "{0:d${n}}" -f [int]$a}))}
复制代码

qixiaobin0715

假设序号不超过5位数：

@echo off
setlocal enabledelayedexpansion
for %%i in (1 10 100 1000 10000) do if exist *_%%i.pdf set n=%%i
set /a n*=10
for /f "tokens=1* delims=_" %%i in ('dir /b /a-d *_*.pdf') do (
    set m=%%~nj
    set /a m+=n
    ren "%%i_%%j" "%%i_!m:~1!%%~xj"
)
pause
复制代码

qd2024

回复 2# newswan


    是的

wanghan519

#@&cls&powershell "type '%~0'|out-string|iex"&pause&exit
dir *.pdf | group {$_.Name -replace '_.*$'} | %{$m=0;$_.Group | sort {$_.Name.Length} -Descending | %{$a=$_.Name -split '[_.]';if($a[-2].Length -gt $m){$m=$a[-2].Length};rni $_.Name ($_.Name -replace '_(\d+)\.',"_$($a[-2].PadLeft($m,'0')).")}}
复制代码

写的比较啰嗦，凑活能用，回头再改

newswan

一个文件夹就一个序列？