newswan

回复 23# qd2024

这个涉及到一个问题，仅本文件夹？包含子文件夹

qd2024

回复 22# newswan

成功 谢谢  有没有可能实际 对二级目录的批量处理   就是拖一个文件夹，这个文件夹根下没有视频文件，这个文件夹下有多个文件夹内包含视频文件，对这些文件夹进行追加时长处理

newswan

回复 15# qd2024

以0开头的数字

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
chcp 936
 
set ffPath=D:\Program Files
 
set folderPath=%~dp1
set folderName=%~nx1
 
 
pushd "%folderPath%\%folderName%"
 
echo "--1--"
set time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mp4 `) do (
	for /f "usebackq" %%i in (`" "%ffpath%\ffprobe.exe" -v error -show_entries format=duration -of default=noprint_wrappers=1:nokey=1 "%%a" "`) do (
		set time=!time! + %%i
	)
)
for /f "usebackq" %%a in (` powershell -command " [math]::Ceiling( (%time%) / 60 ) " `) do (
	set time=%%a
)
echo %time%
 
echo "--2--"
set/a time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mp4 `) do (
	for /f "usebackq tokens=1,2 delims=." %%i in (`" "%ffpath%\ffprobe.exe" -v error -show_entries format=duration -of default=noprint_wrappers=1:nokey=1 "%%a" "`) do (
		set/a time+=%%i
	)
)
set/a time/=60
set/a q=%time%%60
if %q% gtr 0 (set/a time+=1)
echo %time%
 
echo "--3--"
set/a time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mp4 `) do (
	for /f "usebackq tokens=2,3,4 delims=:. " %%i in (` ""%ffpath%\ffprobe.exe" "%%a" 2>&1 | findstr Duration" `) do (
		set/a time+=1%%i*3600+1%%j*60+1%%k-100*3600-100*60-100
	)
)
set/a time/=60
set/a q=%time%%60
if %q% gtr 0 (set/a time+=1)
echo %time%
 
popd
 
pushd "%folderPath%"
echo ren "%folderName%" "%folderName%[%time%]"
popd
 
pause
exit/bCOPY

qd2024

回复 18# newswan
我把代码调成这样

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
 
set ffPath=D:\Program Files
 
set folderPath=%~dp1
set folderName=%~nx1
 
pushd "%folderPath%\%folderName%"
 
 
set/a time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mp4 `) do (
	for /f "usebackq tokens=2,3,4 delims=:. " %%i in (` ""%ffpath%\ffprobe.exe" "%%a" 2>&1 | findstr Duration" `) do (
		set /a time+=%%i*3600+%%j*60+%%k
	)
)
set/a time/=60
echo %time%
 
popd
 
pushd "%folderPath%"
ren "%folderName%" "%folderName%【%time%】"
popd
 
pause
exit/bCOPY

把文件夹拖到BAT上 ，提示如下图，再帮我看盾是什么原因，别一段提示找不文件

buyiyang

@if(0)==(0) @echo off
cd /d "%~dp0"
for /d %%d in (*) do (
    pushd "%%d"
    for /f "delims=" %%i in ('dir /b /a-d "*.mp4"^|cscript /e:jscript /Nologo "%~f0"') do (
    popd
    ren "%%d" "%%d【%%i】"
    )
)
pause&exit
@end
objPlayer=new ActiveXObject("WMPlayer.OCX"),ws=WSH.stdin,durationInSeconds=0;
while (!ws.atendofstream) {
    var filePath = ws.readline();
    var objMedia = objPlayer.newMedia(filePath);
    durationInSeconds += objMedia.duration
}
WScript.Echo(Math.ceil(durationInSeconds/60));COPY

newswan

没下载你的文件，太大，用自己的文件测试了可行

newswan

回复 16# qd2024

不好意思，没有实际运行，忘记了 ren 不能用全路径
用了两种方法

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
 
set ffPath=D:\Program Files
 
set folderPath=%~dp1
set folderName=%~nx1
 
pushd "%folderPath%\%folderName%"
 
set/a time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mkv `) do (
	for /f "usebackq tokens=1,2 delims=." %%i in (`" "%ffpath%\ffprobe.exe" -v error -show_entries format=duration -of default=noprint_wrappers=1:nokey=1 "%%a" "`) do (
		set/a time+=%%i
	)
)
set/a time/=60
echo %time%
 
set/a time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mkv `) do (
	for /f "usebackq tokens=2,3,4 delims=:. " %%i in (` ""%ffpath%\ffprobe.exe" "%%a" 2>&1 | findstr Duration" `) do (
		set /a time+=%%i*3600+%%j*60+%%k
	)
)
set/a time/=60
echo %time%
 
popd
 
pushd "%folderPath%"
echo ren "%folderName%" "%folderName%[%time%]"
popd
 
pause
exit/bCOPY

ppll2030

回复 15# qd2024


    毒盘非会员，无法下载。
复制代码保存为bat文件，然后视频文件夹拖拽到bat文件上就可以了。
脚本需要第三方ffmpeg.exe。
第三行的ffmpeg路径请修改为自己的实际路径。
提示找不到文件，可能视频后缀名不对。已添加多个常用视频
照搬二楼的码。去除echo，无法更名的bug，12楼的已更正

qd2024

回复 13# newswan

提示如下图，帮我再看看，我上传例子文件到百度云盘了，谢谢。


链接：https://pan.baidu.com/s/1mPzdlyhFy4UY1l6OECw7IA?pwd=nro4
提取码：nro4
--来自百度网盘超级会员V10的分享

qd2024

回复 12# ppll2030

提示如下图，帮我再看看，我上传例子文件到百度云盘了，谢谢。

链接：https://pan.baidu.com/s/1mPzdlyhFy4UY1l6OECw7IA?pwd=nro4
提取码：nro4
--来自百度网盘超级会员V10的分享

qd2024

回复 10# newswan
提示如下图，帮我再看看，我上传例子文件到百度云盘了，谢谢。


    链接：https://pan.baidu.com/s/1mPzdlyhFy4UY1l6OECw7IA?pwd=nro4
提取码：nro4
--来自百度网盘超级会员V10的分享

newswan

文件名可能有空格

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
 
set folder=%~1
 
set ffPath=D:\Program Files
 
pushd "%folder%"
 
set/a time=0
for /f "usebackq tokens=* delims=" %%a in (` dir /b *.mkv `) do (
	for /f "usebackq tokens=2,3 delims=: " %%i in (` ""%ffpath%\ffprobe.exe" "%%a" 2>&1 | findstr Duration" `) do (
		set /a time+=%%i*60+%%j+1
	)
)
echo %time%
 
popd
 
echo ren "%folder%" "%folder%[%time%]"
 
pause
exit/bCOPY

ppll2030

二楼的时间好像有问题，我段位低，理解不了。
所以用Batcher大大的分段截取代码，再组合一下。
楼主可以试试。

@echo off
setlocal enabledelayedexpansion
set folder=%~1
set ffpath=H:\共享影视\Download\FFmpeg\ffmpeg.exe
pushd "%folder%"
for /f "delims=" %%i in ('dir /b /s /a-d *.avi *.mkv *.mp4 *.rmvb *.wmv') do (
    for /f "tokens=2 delims=, " %%a in ('%ffpath% -i "%%i" 2^>^&1 ^| find "Duration:"') do set "str=%%a"
    set str=!str:~0,-3!
    for /f "tokens=1-3 delims=:" %%x in ("!str!") do (
        set "hh=%%x"
        set "mm=%%y"
        set "ss=%%z"
        set /a minutes=1!hh!*60-6000
        set /a minutes+=1!mm!-100
        if !ss! neq 0 (set /a minutes+=1)
    )
   set /a  Totalduration+=!minutes!  
)
popd
echo ren "%~1" "%~n1【!Totalduration!】"
pauseCOPY

newswan

ai 给了一个直接获取时长的方法

ffprobe -v error -show_entries format=duration -of default=noprint_wrappers=1:nokey=1 input.mp4
30.024000COPY

newswan

路径有空格？

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
 
set folder=%~1
 
set ffPath=D:\Program Files
 
pushd "%folder%"
 
set/a time=0
for /f "usebackq" %%a in (` dir /b *.mkv `) do (
	for /f "usebackq tokens=2,3 delims=: " %%i in (` ""%ffpath%\ffprobe.exe" %%a 2>&1 | findstr Duration" `) do (
		set /a time+=%%i*60+%%j+1
	)
)
echo %time%
 
popd
 
echo ren "%folder%" "%folder%[%time%]"
 
pause
exit/bCOPY