77七

回复 18# kokoxx


   应该是 猜你喜欢: 这个字符串在原文中没有找到。
使用你提供的文件，我这里测试正常。

kokoxx

回复 17# 77七


    感谢大佬答复

我这边将关键词去掉冒号（将`find /n "猜你喜欢:" ^<"%%i"`   改成`find /n "猜你喜欢" ^<"%%i"`   ）测试成功

至于为啥要去掉冒号才成功，我也不知道为什么～

77七

回复 12# kokoxx


  

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "useback delims=" %%i in (`dir /b /a-d *.txt`) do (
	setlocal
	for /f "useback tokens=1* delims=[]" %%a in (`find /n "猜你喜欢:" ^<"%%i"`) do (
		set _"%%a"=1
	)
	for /f "useback tokens=1* delims=[]" %%a in (`find /n "更多推荐:" ^<"%%i"`) do (
		set _"%%a"=1
	)
	(for /f "useback tokens=1* delims=[]" %%a in (`find /n /v "" ^<"%%i"`) do (
		if not defined _"%%a" (
			echo=%%b
		) else (
			echo=
		)
	))>$
	move $ "%%i"
	endlocal
)
pause
复制代码

kokoxx

回复 15# Batcher



    我是直接将测试样本里的对应文本（包括冒号）复制粘贴的，最起码的关键词替换我还是懂的……

Batcher

回复 14# kokoxx


    12楼给的例子是中文冒号，14楼给的样本是英文冒号。你根据实际情况修改代码再试试吧。

kokoxx

回复 13# Batcher


感谢大佬百忙中出手，不过我这边测试无效T-T

附带一个测试失败的样本：

    https://www.123pan.com/s/pbxrVv-ROAY.html

Batcher

回复 12# kokoxx

@echo off
chcp 65001 >nul
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
    echo %%i
    findstr /i /v /c:"猜你喜欢：" /c:"更多推荐：" "%%i" > "%%i.ttttt"
    move /y "%%i.ttttt" "%%i" >nul
)
复制代码

kokoxx

回复 11# 77七


    大佬，又来叨扰您了

请问bat能否做到查找同文件夹下的*.txt中包含有“猜你喜欢：”和“更多推荐：”的一行后，将其所在的一行替换为空行

举例：

【原版】

我是奥特曼
猜你喜欢：斗破苍穹 武动乾坤 神墓
更多推荐：斗破苍穹 武动乾坤 神墓
你也是奥特曼

【修改后效果】

我是奥特曼


你也是奥特曼

77七

回复 10# kokoxx


  

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "useback delims=" %%i in (`dir /b /a-d *.txt`) do (
	(for /f "useback tokens=1* delims=[]" %%a in (`find /n /v "" ^<"%%i"`) do (
		echo=
		echo=%%b
	))>$
	move $ "%%i"
)
pause
复制代码

kokoxx

回复 9# 77七


    最后一个问题

如何用bat在同文件夹下*.txt的行与行之间增加一个空白行？

-- 嗯，我知道这个功能用wps或word可以很轻松实现，但是代价是wps/word处理大体积txt（超过5m）时，会出现卡死崩溃现象

-- 本来是想单独再发一个求助帖，不过有自我觉得这么搞有发垃圾求助帖的嫌疑，就只能再叨扰大佬了（捂脸）～

举例：

【原版（不包括引号）】
“
我是奥特曼
你也是奥特曼
”


【修改后版本（不包括引号）】
“

我是奥特曼

你也是奥特曼

”

77七

回复 8# kokoxx


   
代码第6行改为

	for /f "useback tokens=1* delims=[]" %%a in (`find /n /v "" ^<"%%i" ^|find "]第" ^|find "章" ^|find /v "此行不做添加空行处理"`) do (
复制代码

kokoxx

回复 5# 77七


大佬，试过了你的脚本，确实有用

追加一个提问：

如果我要实现 文本行同时出现“第x章”和“此行不做添加空行处理”（举例，可以在代码里修改成任意值）字样，就不做添加空行处理，该怎么在原有代码的基础上做修改

举例：

【原版】

我是赛罗奥特曼
第1章 变身
我是泰罗奥特曼
第2章 此行不做添加空行处理
我是迪迦奥特曼

【修改后效果】

我是赛罗奥特曼



第1章 变身



我是泰罗奥特曼
第2章 此行不做添加空行处理
我是迪迦奥特曼

Five66

不知行否，会在原本文件名前面添加new_创建新文件

@echo off

set "z=绗.*绔"

chcp 65001
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
setlocal

(for /f "delims=" %%k in ('findstr /n .* "%%i"') do (
set "str=%%k"
setlocal enabledelayedexpansion
echo=!str:*:=!|findstr /i /b  "!z!" 1>nul && set aaa=1
if defined aaa (
echo=&echo=&echo=
echo=!str:*:=!
echo=&echo=&echo=
set aaa=
) else (
echo=!str:*:=!
)
endlocal
))>"new_%%i.txt"

endlocal
)

chcp 936&echo done&pause&exit /b
复制代码

77七

wfr
http://bcn.bathome.net/tool/wfr.exe

wfr *.txt /encin:utf-8 /encout:utf-8 -r:"^\s*第\s*\d+\s*章.*" -t:"\n\n\n\0\n\n\n"
复制代码

77七

@echo off
rem 批处理保存为utf-8编码格式
chcp 65001 >nul
for /f "useback delims=" %%i in (`dir /b /a-d *.txt`) do (
	setlocal
	for /f "useback tokens=1* delims=[]" %%a in (`find /n /v "" ^<"%%i" ^|find "]第" ^|find "章"`) do (
		set _"%%a"=1
	)
	(for /f "useback tokens=1* delims=[]" %%a in (`find /n /v "" ^<"%%i"`) do (
		if not defined _"%%a" (
			echo=%%b
		) else (
			echo=
			echo=
			echo=
			echo=%%b
			echo=
			echo=
			echo=
		)
	))>$
	move $ "%%i"
	endlocal
)
pause
复制代码

使用前先备份！可能会有误差，如果”章“后面有个空格，代码改为 find "章 " 误差应该小点