defanive

利用位运算是否可以简化一下呢？

或者生成VBS。。。

cainiao736

谢谢Batcher的帮助！

Batcher

@echo off&setlocal enabledelayedexpansion
set /p zifu=请输入字母串：
set str=#abcdefghijklmnopqrstuvwxyz
for /l %%i in (0,1,26) do (
  set !str:~%%i,1!=%%i
)
:repeat
set tmp=%zifu:~0,1%
set /a sum+=%tmp%
set zifu=%zifu:~1%
if not "%zifu%"=="" (
  goto :repeat
) else (
  goto :end
)
:end
echo.%sum%
pause
复制代码

cainiao736

我已经去掉@echo off看过了，只是在set !str:~%%i,1!=%%i 之后多了条“命令语法不正确”，然后接着往下执行，没有再发生错误，结果也是正确的。不知道为什么

Batcher

你把@echo off删除
自己看看执行过程先

cainiao736

@echo off&setlocal enabledelayedexpansion
set /p zifu=请输入字母串：
set str= abcdefghijklmnopqrstuvwxyz
for /l %%i in (0,1,26) do (
set !str:~%%i,1!=%%i )
:repeat
set tmp=%zifu:~0,1%
set /a sum+=%tmp%
set zifu=%zifu:~1%
if not "%zifu%"=="" ( goto repeat ) else ( goto eof )
:eof
echo %sum%
pause
复制代码

代码结果是正确的，但是奇怪的是set !str:~%%i,1!=%%i 这句代码之后会提示“命令语法不正确”，调试了好久都没解决，希望版主帮忙分析下，谢谢了！

keen

有点复杂：

@echo off&setlocal enabledelayedexpansion
set str=abcdefghijklmnopqrstuvwxyz
set /p var=please input:
:lp
set v=%var:~0,1%
set /a c+=1
set n=0
:loop
set r=!str:~%n%,1!
set /a n+=1
if /i "%v%"=="%r%" set s%c%=%n% &goto next
goto loop
:next
set var=%var:~1%
if "%var%"=="" goto end
goto lp
:end
for /l %%i in (%c% -1 1) do set /a s+=!s%%i!
echo %s%
pause
复制代码

[ 本帖最后由 keen 于 2009-4-1 15:49 编辑 ]

batman

@echo off&setlocal enabledelayedexpansion
for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
    set /a n+=1&set "code=!code! %%i#!n!"
)
set /p str=请输入字母：
:lp
for %%a in (%code%) do (
    for /f "tokens=1,2 delims=#" %%i in ("%%a") do (
        if /i "%str:~,1%" equ "%%i" set /a num+=%%j
    )
)
set "str=%str:~1%"
if defined str goto lp
echo %num%&pause>nul
复制代码

loveruixue

学习一下！！！！！！！

xwfswh

还不懂怎么弄，以后再看。。

随风

再来一个，似乎更简洁。。

@echo off
:main
cls
set /p input= 
echo %input%|findstr "^[a-zA-Z]*$">nul||goto main
echo 你输入的是 %input%
for %%b in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
  set /a num+=1
  call set %%b=%%num%%
  call set input=%%input:%%b=+%%b%%
)
set /a str=0%input%
echo.&echo 它们的总和是 %str%
echo.&pause&exit
复制代码

novaa

小楼的方法好啊！
我开始想的是这样
for %%i in ( a b c d ....z) do (
set /a num+=1
call set %%i=%%num%%
然后利用!字符!（比如!a!就是1了）加就可以了。但是这样除了利用截字符就没有办法了。
小楼的那个跳转和判断太漂亮了。

随风

方法一、

@echo off
:main
cls
set /p input=
echo %input%|findstr "^[a-zA-Z]*$">nul||goto main
echo 你输入的是 %input% 
call :ie
echo.&echo 它们的总和是 %str%
echo.&pause&exit
:ie
set num=0
set var=%input:~0,1%
for %%b in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
        set /a num+=1
        if /i "%var%"=="%%b" (
                  set /a str+=num
                  call set input=%%input:~1%%
                  call :ie
        )
)
goto :eof
复制代码

方法二、

@echo off
:main
cls
set /p input=
echo %input%|findstr "^[a-zA-Z]*$">nul||goto main
echo 你输入的是 %input% 
for %%b in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
  set /a num+=1
  call set %%b=%%num%%
)
:ie
set /a str+=%input:~0,1%
set input=%input:~1%
if defined input goto ie
echo.&echo 它们的总和是 %str%
echo.&pause&exit
复制代码

[ 本帖最后由 随风 于 2008-1-8 15:49 编辑 ]

辉少

ieutk
你还有一个大写字母的情况没有写进去哦

ieutk

@echo off&setlocal enabledelayedexpansion
:main
cls&echo.
set input=
set /p input=  请输入字母: 
if not defined input goto main
echo %input%|findstr "^[a-z]*$">nul||goto main
call :ya %input% len
for /l %%a in (0 1 %len%) do call :ie %%a _num
echo.
echo   你输入了 "%input%" ,它们的总和为 "%_num%"
echo.
pause
set _num=0
goto main

:ya
for /f "tokens=1 delims=:" %%a in ('^(echo %1^&echo.^)^|findstr /o ".*"') do set /a %2=%%a-4
goto :eof
:: 在随风发的贴子中看到此方法，现学现用，拿来试下

:ie
for %%b in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
	set /a num+=1
	if "!input:~%1,1!"=="%%b" set /a %2+=!num!
    )
set num=0
goto :eof
复制代码