/zhqsystem/zhq

回复 9# 依山居
这个怎么用,不是标准批处理语法一句没看懂,无语了

依山居

python 练手

f=open("a.txt","r")
txt=f.read()
uppertxt=txt.upper()
复制代码

bailong360

@echo off >nul 3>"%~dp1U_%~nx1"
setlocal enabledelayedexpansion
set list=aA bB cC dD eE fF gG hH iI jJ kK lL mM nN oO pP qQ rR sS tT uU vV wW xX yY zZ
for /f "delims=" %%i in (%~s1) do (
    set "strU=%%i"
    set "strD=%%i"
    for %%i in (%list%) do (
        set let=%%i
        for /f "tokens=1,2" %%i in ("!let:~,1! !let:~-1!") do (
            set "strU=!strU:%%j=%%j!"
            set "strD=!strD:%%i=%%i!"
        )
    )
    echo;!strU!
    >>"%~dp1D_%~nx1" echo !strD!
)
复制代码

忘记在哪里看到过一段大小写转换的代码,非常巧妙
实现起来大概就是这个样子,利用的是批处理在替换时不区分大小写的特性

/zhqsystem/zhq

回复 6# pcl_test
多谢指导,正在研究此段代码,学习中...

pcl_test

回复 5# /zhqsystem/zhq

稍微修改下，转换方法没变，可处理字符串或是文件，加入了参数模式，提供了三种执行方式，然并卵……

@echo off
call :字母大小写互转 "%~1" %~2 %~3
pause&exit
:字母大小写互转
setlocal enabledelayedexpansion
if "%~1" equ "" (
    echo;用法:
    echo;   1、call :字母大小写互转 "字符串或文件路径" [/U^|/L] [/F]
    echo;   2、支持外部调用    字母大小写互转.bat "字符串或文件路径" [/U^|/L] [/F]
    echo;   3、支持拖放文件到批处理图标上执行转换
    echo;   /U    转为大写
    echo;   /L    转为小写
    echo;   /F    处理文件
    goto :eof
) else (
    if "%~2" equ "" (
        set /p c=请选择转化模式（U=转为大写，L=转为小写）:
        if exist "%~1" (
            call :字母大小写互转 "%~1" /!c! /F
        ) else call :字母大小写互转 "%~1" /!c!
        goto :eof
    ) else (
        set "#2=%~2"
        set "#2=!#2:-=/!"
        if "%~3" equ "" (
            if /i "!#2!" equ "/U" (goto :U) else if /i "!#2!" equ "/L" (goto :L)
        ) else (
            set "#3=%~3"
            set "#3=!#3:-=/!"
            if /i "!#3!" equ "/F" (
                if /i "!#2!" equ "/U" (goto :U) else if /i "!#2!" equ "/L" (goto :L)
            ) else (
                if /i "!#3!" equ "/U" (
                    if /i "!#2!" equ "/F" (goto :U)
                ) else if /i "!#3!" equ "/L" (
                    if /i "!#2!" equ "/F" (goto :L)
                )
            )
        )
        echo;参数有误！&goto :eof
    )
)
:U
set "var=A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"
goto :Convert
:L
set "var=a b c d e f g h i j k l m n o p q r s t u v w x y z"
:Convert
set "str=%~1"
if "%~3" equ "" (
    for %%a in (%var%) do set "str=!str:%%a=%%a!"
    echo;!str!
) else (
    (for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%~1"') do (
        set "str=%%b"
        if not defined str (echo;) else (
            for %%a in (%var%) do set "str=!str:%%a=%%a!"
            echo;!str!
        )
    ))>"%~dp1new_%~nx1"
)
goto :eof
复制代码

/zhqsystem/zhq

回复 4# pcl_test
主要还是希望各位大神挑错误,进行完善毕竟在这里不只是要分享,也需要学习,可以进行共赢(共同学习),因为里边错误也有很多,只是不知道怎么完善了
像%1中的路径遇到空格目录居然就提示出错,还有文本中变量冲突时会替换代码中的执行变量,这些都是我解决不了的错误,希望大家帮忙完善,如果觉得没错误也可以留着备用
代码的优点就是利用26个英文字母进行循环替换,替换途中会每行替换26次(如果少于26个英文字母随自己的意愿改个数字和字母变量就完成了),取值最后一次的值完整取出来

pcl_test

回复 3# /zhqsystem/zhq

转换方法不是原创，但你加入了自己意愿的一些交互进而加工，所以也可视为半原创；
但是我要问，你是要分享代码，还是希望别人帮你完善代码呢？从你的标题和描述，我现在是意会不出来了

/zhqsystem/zhq

回复 2# pcl_test
原创代码区不适合因为提取路径时带空格时有错误，毕竟没有实际全部测试，权限也不够。涉及到版权，不可能每个论坛都去找有没有发过
转载区更不适合，因为研究了一晚上，而实际链接地址和作者我去找谁，只能发到求助讨论板块

pcl_test

发错版块了，应发“原创BAT代码”或“转载BAT代码”版块