freesoft00

回复 20# apang


    哦，是这样呀，我主要是不想用c-z这样的形式都搜索一遍。而是'fsutil fsinfo drives 后迭代一下。c-z都搜索，在一些有读卡器的电脑，会出现驱动器没有准备好或者驱动器空的类似的错误提示。

apang

横排

@echo off & setlocal enabledelayedexpansion
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
        if exist %%a:\ (
                fsutil fsinfo drivetype %%a:|findstr /i "固定 Fixed" && set "v=!v! %%a:"
        )
)>nul
if defined v echo,%v:~1%
pause
复制代码

竖排

@echo off
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
        if exist %%a:\ (
                fsutil fsinfo drivetype %%a:|findstr /i "固定 Fixed">nul && echo,%%a:
        )
)
pause
复制代码

apang

fsutil fsinfo drives 在xp和win7显示结果不一样，以前有过很多次的讨论

pcl_test

回复 17# freesoft00
10楼就是

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1*" %%a in ('fsutil fsinfo drives ^|find ":\"') do (
echo %%b
for %%i in (%%b) do set a=%%i & echo format !a:~,2!
)
pause
复制代码

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1*" %%a in ('fsutil fsinfo drives ^|find ":\"') do (
for %%i in (%%b) do set a=%%i & set "s=!s!!a:~,2! " & echo !a:~,2!
)
echo !s:~,-1!
pause
复制代码

freesoft00

回复 16# pcl_test


    这个只是获取一个盘符的批处理吗？那么请改一下获取全部的盘符，谢谢！横排和竖排分别显示。
但是这个我在xp下面运行是可以获取全部盘符的呀。

pcl_test

回复 12# freesoft00
你这个代码本身就只是列出一个盘符，有什么问题？

bailong360

回复 14# freesoft00


    第一个问题只要加上2>nul就行了

不支持wmi这倒是没想到...

freesoft00

回复 13# bailong360
Format C:
Format D:
Format E:
Format


   
结果中多了一行后面没有盘符的format
另外，wmi在pe中有很多不支持，而其它的方法只要pe中有文件比较好实现

bailong360

@Echo Off
For /F "Skip=1" %%i In ('Wmic LogicalDisk Where DriveType^="3" Get Caption') Do Echo Format %%i
复制代码

感觉Wmic在这个时候要好用一点

freesoft00

回复 10# pcl_test


    再请教：

@echo off
setlocal enabledelayedexpansion
for /f "delims=\" %%i in ('fsutil fsinfo drives^|find /v ""') do (
set var=%%i
set drive=!var:~-2!
fsutil fsinfo drivetype !drive!|find "驱动器">nul&& echo !drive!

)
pause
复制代码

这段在xp下面没有问题，而在win7下面只有一个盘符A（我的系统中有A盘）

freesoft00

回复 10# pcl_test


    thank you！

pcl_test

回复 9# freesoft00

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1*" %%a in ('fsutil fsinfo drives ^|find ":\"') do (
for %%i in (%%b) do set a=%%i & echo format !a:~,2!
)
pause
复制代码

freesoft00

比如我要执行fsutil fsinfo drives列出来本地硬盘，然后把执行后的结果作为盘符变量
执行后面的格式化命令
format %str%

freesoft00

另外一个命令

fsutil fsinfo drives执行的解决是横排，

驱动器: C:\: D:\  E:\  F:\
复制代码

同样也是，把上面的结果作为变量参数传递到下面的命令执行，下面的命令比如是echo吧，上面的运行结果中有一个驱动器:是需要去掉的。

freesoft00

ok了，谢谢各位的热心！