pusofalse

测试如下

1、加密  2、解密
1
请输入明文 ：bbsbathome
请输入密钥 ：batch
dcmeiviipm
复制代码

而正确结果应该是

请输入密匙:batch
加密明文：bbsbathome
C B L D H U H H O L
复制代码

mkl

将方阵从右向左用

@echo off&setlocal enabledelayedexpansion
echo 1、加密  2、解密
set /p bs=
set var=1
for %%i in (a b c d e f g h i j k l m n o p q r s t u v w x y z) do (
    set ve=%%i
    set "%%i=!var!" 
	set "!var!=!ve!" 
	set /a var=!var!+1
)
goto %bs%
:1
set /p vaa=请输入明文 ：
goto ss
:2
set /p vaa=请输入密文 ：
:ss
set /p vab=请输入密钥 ：
:st
set va1=%vaa:~0,1% &set vaa=%vaa:~1%
set va2=%vab:~0,1% &set vab=%vab:~1%%vab:~0,1%
goto %bs%%bs%
:11
set /a vav=%va2%+%va1%
if %vav% gtr 26 set /a vav=%vav%-26
goto js
:22
set /a vav=%va1%-%va2%
if %vav% lss 1 set /a vav=%vav%+26
:js
set /p=!%vav%!<nul
if not "%vaa%"=="" goto st 
pause >nul
复制代码

虽然有些地方和batman相似但绝非抄袭

[ 本帖最后由 mkl 于 2008-8-23 13:57 编辑 ]

lygwdyanzi

到底是什么跟什么啊，一头雾水

都市浪子666

厉害呀，我看都看不起懂

batman

解密程序：

@echo off&setlocal enabledelayedexpansion
rem 生成方阵
set "codes=a b c d e f g h i j k l m n o p q r s t u v w x y z"
set "code=%codes: =%"
for %%i in (%codes%) do set /a n+=1&set "_!n!=%%i"
set "_a=%code%"
for /l %%i in (1,1,25) do (
    set "code=!code:~1!!code:~,1!"
    set  "_!code:~,1!=!code!"
)
echo.&set /p str=请输入密文:
echo.&set /p pss=请输入密匙:
echo.&set /p=解密的明文:<nul
:again
set "a1=%str:~,1%"&set "a2=%pss:~,1%"
set "str=%str:~1%"&set "pss=%pss:~1%%a2%"
set "var=!_%a2%!"&set "n=0"&call :lp
if defined str goto again
pause>nul&goto :eof
:lp
set "a=%var:~,1%"&set /a n+=1
if /i "%a%" equ "%a1%" set /p=!_%n%!<nul&goto :eof
set "var=%var:~1%"
goto lp
复制代码

[ 本帖最后由 Batcher 于 2009-5-1 20:57 编辑 ]

pusofalse

set "pss=%pss:~1%%a2%"
高！

batman

原帖由 pusofalse 于 2008-7-30 02:59 发表
我出这道题的初衷是希望写出代码之后可以作为一个实用的加密文本的工具，然后再由自己写解密工具，这是挺好的一件事情。
维热纳尔的加密意义不仅在于加密一个单词或一句英文，而是即使加密很长的一段文章也不会被频 ...

确实是没考虑周全，要通用也容易，只要按生成方阵的办法来循环密文就可以了，已修改于上。

pusofalse

我出这道题的初衷是希望写出代码之后可以作为一个实用的加密文本的工具，然后再由自己写解密工具，这是挺好的一件事情。
维热纳尔的加密意义不仅在于加密一个单词或一句英文，而是即使加密很长的一段文章也不会被频率破解。

既然是这样，那batman兄的代码也是不通用了，因为一个文本内容的长度问题。。。而密匙的长度就只有那几位，乘以10也不能保证多于明文的长度。

当然如果作为一个工具来讲，要想加密正确，要保证明文中只有字母，空格也不得包括。

pusofalse

batman兄的代码没有密匙，密文只是通过右移一位而来的。 另外有一处错误，是导致每次都右移一位的根本所在。
for %%i in (codes) do (
      set /a n+=1
      if /i "%%i" equ "%1" goto next
)

维热纳尔方阵加密出的密文非常牢固，要解开，必须要有双方协定好的密匙（可以是个有意义的英文单词）。
可能是我说的太模糊了，已修正。

[ 本帖最后由 pusofalse 于 2008-7-30 02:38 编辑 ]

batman

@echo off&setlocal enabledelayedexpansion
rem 生成方阵
set "codes=a b c d e f g h i j k l m n o p q r s t u v w x y z"
set "code=%codes: =%"
set "_a=%code%"
for /l %%i in (1,1,25) do (
    set "code=!code:~1!!code:~,1!"
    set  "_!code:~,1!=!code!"
)
echo.&set /p str=请输入明文:
echo.&set /p pss=请输入密匙:
echo.&set /p=生成的密文:<nul
:again
set "a1=%str:~,1%"&set "a2=%pss:~,1%"
set "str=%str:~1%"&set "pss=%pss:~1%%a2%"
call :lp
if defined str goto again
pause>nul&goto :eof
:lp
for %%i in (%codes%) do (
      set /a n+=1
      if /i "%%i" equ "%a1%" goto next
)
:next
set /a n-=1
set "var=!_%a2%!"
set "var=!var:~%n%,1!"
set /p=%var% <nul&set "n=0"
复制代码

[ 本帖最后由 Batcher 于 2009-5-1 20:56 编辑 ]