a590687

@echo off&setlocal enabledelayedexpansion
::先获取行数并把 行数较大的文本设为和t1另一个为t2
for %%a in ('sed "$=" a.txt') do (
	for %%b in ('sed "$=" b.txt') do (
		if %%a gtr %%b (
			set "t1=a.txt" 
			set "t2=b.txt" 
		) else (			
				set "t1=b.txt" 
				set "t2=a.txt"
			)
	)
)
::交叉输出t1和t2
for /f "delims=" %%i in (!t1!) do (
	set /a n+=1
	echo %%i
	for /f "tokens=1,* delims=:" %%j in ('findstr /n ".*" !t2!') do (
		if %%j equ !n! echo %%k
	)
)
pause
复制代码

ccr438758900

@echo off
setlocal enabledelayedexpansion
set "xp=goto :eof"
for /f "delims=" %%i in (1.txt) do (set "me=%%j"&echo %%i&call :a)
set xp=&set vs=pause
goto a
:a
for /f "%a% delims=" %%j in (2.txt) do (echo %%j&set /a b+=1&set a=skip=!b!
%xp%)
%vs%
复制代码

[ 本帖最后由 ccr438758900 于 2010-1-13 00:22 编辑 ]

qzwqzw

再把老古董翻出来晒晒吧 :-P

第一眼看到这个题目
下意识就想到用find+sort
后来发现everest79 已经有了类似的解题思路了
东施效颦的事我可不想做
本来就想放弃的

再后来我突然又想起了阔别很久的文物程序fc
也把它翻出来晒晒后
证实思路是可行的

@(for /f "tokens=1* delims=: " %%a in ('fc /lb10000 /n ?.txt %SystemDrive%\io.sys^|find ": "^|sort') do @echo.%%b)>out2.txt
复制代码

比everest79的代码简单一些倒是其次
最关键的是这是一个新的创意

本以为万事大吉
可是再再后来又注意到netbenton与everest79 的对话
发现无论如何也不明白everest79的代码
怎么就避免了netbenton所说的错行问题

因为sort是按文本顺序排序的
而且无法指定排序起始点
不能指定排序停止点
那么文本的内容必然会影响到文本的顺序
试验证实也确实如此

关键糟糕的是
我的代码也存在同样的问题
而且它也把两个文本行首的空格给过滤掉了
于是只好再翻翻doshelp
终于找到解法

用findstr给文本行加个文件名前缀
让sort可以按照我们的规矩“正常排序”
而文本行首的空格也给保留了

虽然使用了临时文件
而且也多了两句代码
但这是没办法的事情
何况效率也没大影响
索性就这样结束了吧

@echo off
for %%f in (1.txt 2.txt) do findstr $ %%f? > %temp%\~%%~nf.%~n0
(for /f "tokens=2* delims=:" %%a in ('fc /lb10000 /n %temp%\~*.%~n0 %SystemDrive%\io.sys^|find ": "^|sort') do echo.%%b)>out3.txt
del %temp%\~*.%~n0
复制代码

everest79

原帖由 netbenton 于 2009-4-30 23:34 发表
是我搞错了，呵呵，没注到前面的是find,而不是findstr


君的方法，不知道这样是不是可以不限行数了呢:
find /v /n "" ?.txt |findstr "[ ]"|sort

应该不行，把不同位数的行数分捡开来是为了让sort来正确排序，否则会排成
1
10
11
2
20
21
3
....
这样
超过一百行要再加一句

for /f "tokens=1* delims=[]" %%a in ('find /v /n "" ?.txt^|findstr /b "\[[0-9][0-9][0-9]\]"^|sort') do echo.%%b >>out.txt

 
复制代码

defanive

改了一下，前两行的显示貌似要快点，实际上与LS的代码都是一样快的（测试耗时：0.05秒）

@echo off
for /f %%a in (1.txt) do echo %%a&for /f %%b in (2.txt) do echo %%b&goto loop
:loop
set /a lines+=1
set erl=0
for /f "skip=%lines%" %%a in (1.txt) do echo %%a&set /a erl+=1&goto loop_1
:loop_1
for /f "skip=%lines%" %%a in (2.txt) do echo %%a&goto loop
if %erl%==0 (pause) else (goto loop)
复制代码

defanive

自己写了一个，感觉前两行速度有点慢，其他都很快，利用for /f加goto偷鸡。。。

@echo off
set /p line1=<1.txt&set /p line2=<2.txt
echo %line1%&echo %line2%
:loop
set /a lines+=1
set erl=0
for /f "skip=%lines%" %%a in (1.txt) do echo %%a&set /a erl+=1&goto loop_1
:loop_1
for /f "skip=%lines%" %%a in (2.txt) do echo %%a&goto loop
if %erl%==0 (pause) else (goto loop)
复制代码

netbenton

是我搞错了，呵呵，没注到前面的是find,而不是findstr


君的方法，不知道这样是不是可以不限行数了呢:
find /v /n "" ?.txt |findstr "[ ]"|sort

everest79

原帖由 netbenton 于 2009-4-30 07:38 发表
楼上的不一定会交替的吧？
有可能会这样的
a.txt  行
b.txt  行
b.txt  行
a.txt  行

for /l %%i in (1,1,40) do (
echo A:%%i >>a.txt
echo B:%%i>>b.txt
)
复制代码

你试了没有

inittab

兼容两文件行数不同情况。

@echo off&setlocal enabledelayedexpansion
set/a n=0,m=0
for /f "delims=" %%a in (2.txt) do set/a n+=1&set #!n!=%%a
for /f "delims=" %%a in (1.txt) do (
set/a m+=1
if defined #!m! (echo %%a&call echo %%#!m!%%) else echo %%a
)
set /a m+=1
if !n! gtr !m! for /l %%i in (!m!,1,!n!) do echo !#%%i!

pause
复制代码

abc001

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('type 1.txt') do set /a a+=1
for /f "delims=" %%a in ('type 2.txt') do set /a b+=1
set /a t1+=!a!-!b!
set /a t2+=!b!-!a!
for /f "delims=" %%a in ('type 1.txt') do (
set m=
set /a n+=1
for /f "delims=" %%b in ('type 2.txt') do (
set /a m+=1
if "!n!" == "!m!" (
echo %%a
echo %%b
)
)
)
if !a! gtr !b! more 1.txt +!t1!
if !a! lss !b! more 2.txt +!t2!
)
pause
复制代码

netbenton

楼上的不一定会交替的吧？
有可能会这样的
a.txt  行
b.txt  行
b.txt  行
a.txt  行

everest79

一百行以内

@echo off
for /f "tokens=1* delims=[]" %%a in ('find /v /n "" ?.txt^|findstr /b "\[[0-9]\]"^|sort') do echo.%%b >>out.txt
for /f "tokens=1* delims=[]" %%a in ('find /v /n "" ?.txt^|findstr /b "\[[0-9][0-9]\]"^|sort') do echo.%%b >>out.txt

pause
复制代码

netbenton

 
@echo off&setlocal enabledelayedexpansion
for /f "delims="  %%a in (1.txt) do (set /a n+=1&set #!n!=%%a)
for /f "delims=" %%a in (2.txt) do (
    set/a m+=1
    echo %%a
    if defined #!m! for %%b in (!m!) do echo !#%%b!
)
set/a m+=1
for /l %%a in (!m!,1,!n!) do echo !#%%a!
复制代码

batman

呵呵，本人最老的一道题也被你们翻出来了，加油，有这股劲就对了!

keen

batman就是强！
我的跟batman的第一种方法（15楼）基本一样了。
batman的第二种方法（见18楼），更是高手典范。