youxi01

建议将程序问题 和 解决方案按照如下格式罗列：
问题：***

解决方案：***F(***楼）
以便于查阅

huajinghua

对哦，呵呵，碰到大的素数时却是运算很慢。

youxi01

转一个自己较早前写的代码了：

@echo off
echo.
echo          求两数的最大公约数、最小公倍数
echo ========================================
title 求两数的最大公约数
setlocal enabledelayedexpansion
set /p num1=请输入第一个数字：
set /p num2=请输入第二个数字：
set/a res=%num1%*%num2%
echo ----------------------------------------
echo %num1%和%num2%：&echo.
:test
     set /a temp=%num1% %% %num2%
     if %temp% NEQ 0 (
         set /a num1=!num2!
         set /a num2=!temp!
         goto :test)

set /a res=%res%/%num2%
echo 最小公倍数为：%res% 最大公约数为：%num2%
pause>nul
复制代码

youxi01

代码够简洁，不错。
但是碰到大指数肯定会遭遇效率问题，举例：3659

随风

这么多题，在答题时，把题目一起贴出来好吗？

youxi01

测试代码（里有一bug，不知各位是否测试的出来，目前并不明白bug产生原因）

@echo off&setlocal enabledelayedexpansion
:start
cls
set "str=1"
set /p EN=请输入一个数字：
call :CheckPrime %EN% Prime Remainder
set str=%str% x !OBJ! 

if "!str:~-2,1!"=="1" set str=!str:~0,-4!
if not "!str:~-6,1!"=="1" set str=!str:~4!

echo.&echo %EN% = !str!
pause>nul
goto :start

:CheckPrime OBJ Prime Remainder
set /a OBJ=%~1,Remainder=0
set /a var=!OBJ!/2+1,var_=!OBJ! %% 2
if !var_! EQU 0 (
	set str=!str! x 2
	set/a Prime=2,Remainder=!OBJ!/2
	call :CheckPrime !Remainder! Prime Remainder
	)
for /l %%i in (3 2 !var!) do (
	set /a var_=!OBJ! %% %%i
	if !var_! EQU 0 (
		set str=!str! x %%i
		set/a Prime=%%i,Remainder=!OBJ!/%%i
		call :CheckPrime !Remainder! Prime Remainder
		)
	)
复制代码

huajinghua

【程序14】
题目：将一个正整数分解质因数。例如：输入90,打印出90=2*3*3*5。
程序分析：对n进行分解质因数，应先找到一个最小的质数k，然后按下述步骤完成：
(1)如果这个质数恰等于n，则说明分解质因数的过程已经结束，打印出即可。
(2)如果n<>k，但n能被k整除，则应打印出k的值，并用n除以k的商,作为新的正整数你n,
　重复执行第一步。
(3)如果n不能被k整除，则用k+1作为k的值,重复执行第一步。

代码如下

@echo off
set /p a=请输入要分解的数
set /a c=a/2
:a
set /a b=%b%+1
set /a d=%a%/%b%
set /a s=%a%%%%b%
if not "%s%"=="0" (goto a) else (set/p=%b% <nul &set a=%d% &set b=1&goto a)
pause
复制代码

[ 本帖最后由 huajinghua 于 2008-4-11 19:23 编辑 ]

随风

打印杨辉三角
转一个，
原创作者：wudixin96
:

@echo off&setlocal enabledelayedexpansion
:top
::原创作者：wudixin96
::  in=行数：
set/a ab=1,var=30,in=10
set str=1
for /l %%i in (1,1,%in%) do (
   set "num="
   set /a num2=0
   for %%a in (!str!) do (
   set /a num2+=1
   if !num2!==1 set "str1="
   set /a num1=%%a+num
   set "str1=!str1! !num1!"
   set num=%%a
   )
   call :lis "!str1:~1!"
   set "str=!str1! 0"
)
pause>nul
exit
:lis
set max=%~1
for /l %%a in (0 1 300) do (
  if not "!max:~%%a,1!"=="" set /a ci+=1
)
set /a ki=var-ci/2
for /l %%a in (1 1 !ki!) do set "kg= !kg!"
echo !kg!!max!
set nam!ab!=!kg!!max!
set /a ab+=1
set ci=0&set "kg="
goto :eof
复制代码

随风

【程序23】
题目：打印出如下图案（菱形）
*
***
******
********
******
***
*

:

@echo off&setlocal enabledelayedexpansion
set "ko=                              "
for /l %%i in (1 2 13) do (
  if defined flag (set /a n-=2&set /a c-=1) else set /a n=%%i&set /a c+=1
  call set m=%%ko:~!c!%%
  set /p=!m!<nul
  for /l %%b in (1 1 !n!) do set /p=*<nul
  echo.
  if !n! geq 7 set flag=a
)
echo.&pause
复制代码

youxi01

呵呵，这句非常不错，避免了重复计算。

for /l %%i in (0 1 9) do set /a t%%i=%%i*%%i*%%i

youxi01

测试代码：

@echo off&setlocal enabledelayedexpansion
echo 水仙花数有：&echo.
for /l %%i in (100 1 999) do (
        set var=%%i
        set/a num1=!var:~0,1!,num2=!var:~1,1!,num3=!var:~2,1!
        set/a var=!num1!*!num1!*!num1!+!num2!*!num2!*!num2!+!num3!*!num3!*!num3!
        if !var! EQU %%i echo %%i
        )

pause>nul
复制代码

随风

水仙花数
原创作者： 梦想种子
:

@echo off&setlocal enabledelayedexpansion
:: 原创作者： 梦想种子
for /l %%i in (0 1 9) do set /a t%%i=%%i*%%i*%%i
for /l %%i in (1 1 10000) do (
  set "k=00000%%i"
  set a=!k:~-1!
  set b=!k:~-2,1!
  set c=!k:~-3,1!
  set d=!k:~-4,1!
  set e=!k:~-5,1!
  set /a n=t!a!+t!b!+t!c!+t!d!+t!e!
  if "!n!" == "%%i" echo %%i
)
pause
复制代码

huajinghua

继续讨论水仙花数……

youxi01

呵呵，换做400时，将第二个for循环中的 15 改成 20 即可！！

huajinghua

@echo off&setlocal EnableDelayedExpansion
for /l %%a in (101 2 200) do (
set t=%%a
set "flag="
set /a x=!t!/2
  for /l %%b in (2 1 !x!) do (
    set /a m=%%a %% %%b
     if !m! equ 0 set flag=A
  )
  if not defined flag echo 素数 %%a
)
echo\&pause
其实上面这段代码通用的，就是每个数让他去除小于它开根的数（但批处理不能算出根号，所以把范围在扩大为这个数到一半），youxi01的代码在101-200之内没问题，但换作把范围400时就多出了很多结果，呵呵，但用在101-200之内时就正确，而且运行速度快。上面这段代码就运行速度慢了点，但是没错误

[ 本帖最后由 huajinghua 于 2008-4-11 13:42 编辑 ]