批处理产生四个四位不重复的随机数

youxi01

要求：
1、随机数的位数为4位（首位不能为0）,且随机数由四个不重复的数字组成；
2、随机数之间不能重复

unknown_world

对53楼做下改进

@echo off
::设置四个变量a,b,c,d，产生四个1位的随机数组全四位数

set /a i=%random% %% 9+1
set a=%i%

:sui2
set /a i=%random% %% 10
if %i% neq %a% (set /a b=%i%)  else goto sui2

:sui3
set /a i=%random% %% 10
if %i% neq %a% if %i% neq %b% (set /a c=%i%)   else goto sui3

:sui4
set /a i=%random% %% 10
if %i% neq %a% if %i% neq %b% if %i% neq %c% (set /a d=%i%)  else goto sui4

echo %a%%b%%c%%d%
pause >nul
复制代码

unknown_world

@echo off

::设置四个变量a,b,c,d，产生四个1位的随机数组全四位数

:sui1
set /a i=%random% %% 10
if %i% neq 0 (set /a a=%i%)  else goto sui1

:sui2
set /a i=%random% %% 10
if %i% neq %a% (set /a b=%i%)  else goto sui2


:sui3
set /a i=%random% %% 10
if %i% neq %a% if %i% neq %b% (set /a c=%i%)   else goto sui3

:sui4
set /a i=%random% %% 10
if %i% neq %a% if %i% neq %b% if %i% neq %c% (set /a d=%i%)  else goto sui4

echo %a%%b%%c%%d%

pause >nul
复制代码

wutarnow

回复 1# youxi01

@echo off
setlocal enabledelayedexpansion

for /l %%I in (1,1,4) do (
    call :CreateRandom
    echo !createRandom!
)
goto :EOF

:CreateRandom
set createRandom=%RANDOM%
if %createRandom% LEQ 999 (
    goto :CreateRandom
) else if %createRandom% LSS 10000 (
    call :IsFourSame %createRandom%
    if !isFourSame! EQU 0 (
        exit /b
    ) else (
        goto :CreateRandom
    )
) else (
    goto :CreateRandom
)

:IsFourSame
set value=%1
set ch1=%value:~,1%
set ch2=%value:~1,1%
if %ch1% EQU %ch2% set isFourSame=1 & exit /b
set ch3=%value:~2,1%
if %ch3% EQU %ch1% set isFourSame=1 & exit /b
if %ch3% EQU %ch2% set isFourSame=1 & exit /b
set ch4=%value:~3,1%
if %ch4% EQU %ch1% set isFourSame=1 & exit /b
if %ch4% EQU %ch2% set isFourSame=1 & exit /b
if %ch4% EQU %ch3% set isFourSame=1 & exit /b
set isFourSame=0
exit /b
复制代码

路过

@echo off
set d=0
setlocal enabledelayedexpansion

:lc
set/a a=%random%%%9000+1000
set p=n!a!
for /l %%a in (0,1,9) do (set q=!p:%%a=!
 if !q! neq !p! (if "!q:~3,1!"=="" (goto lc)
 )
)
set/a d+=1
echo;!a!
if %d% equ 4 (pause&exit)
goto lc
复制代码

生成4个

尘丶

@echo off&setlocal enabledelayedexpansion
set /a shuzi=%random%%%1000+1
set /a shuzi1=%shuzi%*4-4
for /l %%a in (1,1,9) do (
    for /l %%b in (0,1,9) do (
        for /l %%c in (0,1,9) do (
            for /l %%d in (0,1,9) do (
                if not %%a==%%b if not %%a==%%c if not %%a==%%d if not %%b==%%c if not %%b==%%d if not %%c==%

%d ( 
   if not defined #%%a%%b%%c%%d (set /a n+=1&set #%%a%%b%%c%%d=1)
   if !n! geq !shuzi1! echo;%%a%%b%%c%%d&set /a t+=1
   if !t!==4 goto a
   )
      )
    ) 
  )
)
:a
pause>nul
复制代码

这也算随机数了，就是值范围差不多，得改随机数。

shelluserwlb

@echo off
:again
set /a h1=%random%%%9+1
set /a h2=%random%%%9
set /a h3=%random%%%9
set /a h4=%random%%%9
if %h1% neq %h2% (
if %h1% neq %h3% (
if %h1% neq %h4% (
if %h2% neq %h3% (
if %h2% neq %h4% (
if %h3% neq %h4% (
    echo %h1%%h2%%h3%%h4%
    pause>nul
))))))
goto :again
复制代码

楚牛香

回复 47# 楚牛香


    不知道有没有符号，可以实现或的意思，比如 如果m不等于x或者w的话，这句话有代码能写吗

楚牛香

@echo off
:main
set /a n=%random%%%10
if %n%==0  goto main
:y
set /a m=%random%%%10
if %m%==%n% (goto y) else (set /a b=10*m+n)
:second
set /a x=%random%%%10
if %x%==%n% (goto second)
if %x%==%m% (goto second) else (set /a b=100*x+b)
:third
set /a w=%random%%%10
if %w%==0 (goto third)
if %w%==%n% (goto third)
if %w%==%m% (goto third)
if %w%==%x% (goto third) else (set /a b=1000*w+b)
echo %b%
pause>nul
复制代码

keiamy

測試了很久....還要多加努力

@echo off&setlocal enabledelayedexpansion
:lp
for /l %%i in (1 1 9) do set .!random!!random!=%%i
for /f "tokens=1-2 delims==" %%i in ('set .') do (
 set /a n+=1,m=n%%4
 set "var=!var!%%j"
 if !m! equ 0 if not defined #!var:~-4! (
 echo !var:~-4!
 set /a "num+=1"
 set "#!var:~-4!=flag")
 if "!num!" equ "100" pause&exit
 set "%%i=")
set "var="&set "n="
goto lp
复制代码

scarcr

嗯，首先，我遇到了一个麻烦，从昨天晚上6点弄个现在，7个小时，学到了许多也没有解决。
我在运行 call set %%var:%a%=%%这种类型的嵌套变量的时候是注定要跳错进入死循环的。
自我无奈之后，坛子里有这种句式的代码我也运行了六七套，全部失败。
看来，非战之罪。所以，我还是把我写的代码交上来吧，大家看看，有错帮我找出来啊。谢谢。

我在想我用的盗版xp还真的是恶心人啊，就是贪ghost方便了，结果系统驱动也没有装好，运行ghost总有意外的惊喜，
不过我是有正版的xp序列号的，还是professional，不过这年头装原版xp是有自残倾向的，太慢了，又太费劲了。

15楼的这段的'set #'这里是什么意思，什么效果，理解不能呢。
for /f "tokens=2 delims=#=" %%i in ('set #') do echo %%i

这段实现了题目的全部要求，生成四个四位不同的不同的随机数。
第二个for循环我手动输入数测试了一下，没有问题，这个程序理论上可以生成所有的四位不同的四位数，只是会越来越慢
只要改一下!m! equ 4这里，还有第二个for循环的( 1 1 4 )这里，把4改成别的数，可以获得想要位数的四位不同随机数，
如果使用变量，可以由键盘输入需要数目的随机数，这样题目的要求就扩展了。
我认为我完成了。累死了。

@echo off&setlocal enabledelayedexpansion
:A
if !m! equ 4 (pause&goto :eof)
set /a nu=%random%%%9000+1000&set a=%nu%
for /l %%i in (1,1,3) do (
    set "b=!a:~,1!"&&set "c=!a:~1!"
    call set "b=%%a:!b!=%%"
    if !b! equ !c! (set a=!c!) else (goto A)
    )
for /l %%i in (1,1,4) do (
    if "!#%%i!"=="" (
        set #%%i=!nu!&&echo !#%%i!&&set /a m+=1&&goto A
        ) else if !#%%i! equ !nu! (goto A))
复制代码

获得经验有二，
当你无法取得成功时，可以去看看成功人士的例子，也许会柳暗花明又一村。
第二个for循环的第一个if判断里应该使用&&而不是使用&，避免出现命令运行不完整的现象，嗯，我这里出现了，所以改成现在这个样子。

common

用了最笨的方法，但可以实现功能
为什么我总是想不到简单的方法，是我对命令还不够熟悉吗？

@echo off
setlocal enabledelayedexpansion
:sat
set num=%random%
if %num% lss 1000 goto :sat
if %num% gtr 9999 goto :sat
set a=%num:~0,1%
set b=%num:~1,1%
set c=%num:~2,1%
set d=%num:~3,1%
echo !a!
echo !b!
echo !c!
echo !d!
if !a! == !b! goto :sat
if !a! == !c! goto :sat
if !a! == !d! goto :sat
if !b! == !c! goto :sat
if !b! == !d! goto :sat
if !c! == !d! goto :sat
echo %num%
pause
复制代码

stuqx

稍等一下   正在修改   有问题

[ 本帖最后由 stuqx 于 2011-1-13 18:13 编辑 ]

mac007cn

关于楼主这个题目，目前为止（竟然3年多了）几乎没有人做到楼主的第2个要求，正如楼主在10楼所说，“对于多个随机数，没有进行重复性判断（尽管这种几率很小）”。我想，如果把这个题目的要求1改一下，生成100个3位数或者10个2位数，这样重复的几率就很大了，必须考虑判断重复性。

下面是俺写的一段关于判断重复性的代码：

set "AllNum="
:LOOP
产生一个满足要求1的随机数num的部分代码略
REM 判断重复性
if not defined AllNum (
	set "AllNum=%num%"
	set /a n=1
	goto :LOOP
)
set "temp=%AllNum%"
set "temp=!temp:%num%=!
REM 如果%AllNum%去掉%num%前后是同一个字符串,
REM 则说明%num%与先前产生的随机数不重复。
if "%temp%"=="%AllNum%" (
	set "AllNum=%AllNum%,%num%"
	set /a n+=1
	if !n! geq 4 goto :LIST
)
goto :LOOP

:LIST
echo %AllNum%
复制代码

[ 本帖最后由 mac007cn 于 2011-1-13 10:04 编辑 ]

caruko

大概是中规中矩的办法吧...

@echo off
setlocal enabledelayedexpansion
set str=1234567890
set n=9
for /l %%a in (1 1 4) do (
	set /a rd=!random!%%!n!
	call set n%%a=%%str:~!rd!,1%%
	call set str=%%str:!n%%a!=%%
	set /a n=!n!-1
)
echo %n1%%n2%%n3%%n4%
复制代码