[ 新手练习 4 ] 批处理计算字符串长度

wxcute

假定一字符串 “123ABC上中下”，计算出这个字符串的长度，即有几个字符。

目的：掌握变量截取与条件判断用法。

要求：让批处理自动计算出字符串的长度。字符串可自定义，暂不考虑特殊字符。

评分：代码可读性 1 分；
　　　首个新方法 6 分，第二个 5 分，依次类推，最少 2 分；
　　　一人可多种方法，新方法追加 3 分，已经出现过的方法追加 1 分。

唯尘

@echo off&setlocal enabledelayedexpansion
set /p var=请输入需要判断的字符串：

:agin
set var=!var:~0,-1!
set /a n+=1
if not "!var!"=="" goto :agin

echo 字符串长度：!n!
pause>nul

唯尘

@echo off
set /p input=请输入需要检测的字符串：
set var=%input%
:sc_start
set var=%var:~0,-1%
set /a n+=1
if not "%var%"==""  (goto sc_start)
echo 字符串长度是%n%
pause>nul&exit

懒虫阿布

@echo off
setlocal enabledelayedexpansion

::%1  字符串
set str=%1

set strLen=0
:StartLoop
if  "%str%"==""  goto EndLoop
set str=!str:~1!
set /a strLen+=1
goto StartLoop
:EndLoop

echo %1 length is !strLen!
复制代码

happy886rr

回复 28# 老刘1号
255个已经够用了。再长的批处理自己也能计算。

老刘1号

回复 27# happy886rr


    感谢鼓励，
新版本出炉，峰值达到255个
用法： Batname <String>
继续学习汇编～～

@Echo off
IF /i "%PROCESSOR_ARCHITECTURE%" EQU "AMD64" (
	echo DEBUG和8086_ASM不支持64位的系统。
	Pause&Exit
)
Set "Str=%*"
>%tmp%\DEBUGASM.TMP (
	ECHO A20:0
		ECHO DB "%Str:~,70%"
		ECHO DB "%Str:~70,70%"
		ECHO DB "%Str:~140,70%"
		ECHO DB "%Str:~210,45%"
		ECHO DB 0
	ECHO.
	MORE +20 "%~0"
)
For /f "Tokens=2" %%a in (
	'^<%tmp%\DEBUGASM.TMP DEBUG^|Findstr /c:"0020:0000"'
) Do Set /a Strlen=0x%%a 2>nul
Echo %Strlen%&DEL /F %tmp%\DEBUGASM.TMP&Exit /b
A100
	MOV	BX,20		;一段安全的空间
	MOV	DS,BX
	SUB	BX,BX		;清空BX
	MOV	CL,[BX]		;获取Ascii
	JCXZ	10E		;判断是否为NUL并跳出
	INC	BX		;计数
	JMP	107		;循环读取
	MOV	[0],BX		;将字符串长度写入内存
	INT	21H

G
D20:0 0
Q
老刘制作～
复制代码

happy886rr

回复 26# 老刘1号
很棒，71个够用了，一般太长的都直接C语言解决。

老刘1号

回复 25# happy886rr


    峰值为71个
DEBUG一行就那么长...

happy886rr

回复 24# 老刘1号
超过65个字符就不行。

老刘1号

8086ASM（DEBUG版）

Echo off&CLS
IF /i "%PROCESSOR_ARCHITECTURE%" EQU "AMD64" (
	echo DEBUG和8086_ASM不支持64位的系统。
	Pause&Exit
)
>"%Tmp%\DEBUGASM.TMP" (
Echo	A
Echo		MOV	BX,20		;一段安全的空间
Echo		MOV	SS,BX
Echo		MOV	SP,80		;清理安全空间
Echo		MOV	CX,40		;循环次数（HEX）=清理字节数（128B）/入栈大小（2B）
Echo		SUB	BX,BX		;清空BX
Echo		PUSH	BX		;执行入栈（清理）
Echo		LOOP	10D		;循环压栈
Echo		SUB	CX,CX		;清空CX
Echo		INT	21H
Echo.&Echo	G)
Set /P str=Input a string:
Echo E20:0 "%STR%">>"%Tmp%\DEBUGASM.TMP"
More +25 "%~0" >>"%Tmp%\DEBUGASM.TMP"
For /f "Tokens=2" %%a in (
	'^<%tmp%\DEBUGASM.TMP DEBUG^|Findstr /c:"0020:0000"'
) Do Set /a Strlen=0x%%a
DEL %tmp%\DEBUGASM.TMP
Echo %Strlen%&Pause&Exit /b
A100
	MOV	BX,20		;一段安全的空间
	MOV	DS,BX
	SUB	BX,BX		;清空BX
	MOV	CL,[BX]		;获取Ascii
	JCXZ	10E		;判断是否为NUL并跳出
	INC	BX		;计数
	JMP	107		;循环读取
	MOV	[0],BX		;将字符串长度写入内存
	INT	21H

G
D20:0 0
Q
Q
复制代码

diverpan

参变量的最少个数为1，最少循环次数也为1，思路清晰了，也挺好写的

回家路上

回复 21# taofan712

最好标明出处，方便看到的朋友系统学习。如果是你没记出处，就是你的问题了。
http://www.bathome.net/thread-11799-1-1.html
结合帖子中设置为一个变量调用的思路，也试着把这种方式写成一行试试

@echo off & setlocal enabledelayedexpansion
set "_strlen=set $=#^!$^!&set ##=&for /l %%a in (12,-1,0)do set/a"##^|^=1^<^<%%a"&for %%b in (^!##^!)do if ^!$:~%%b^!.==. set /a"##^&^=~1^<^<%%a""

for %%i in (
	12345678901234567890123456789012345678901234567890
	1234567890123456789012345678901234567890
	123456789012345678901234567890
	12345678901234567890
	1234567890
	1
) do (
	set "$=%%i" & (%_strlen%)
	echo;!##! : %%i
)

pause & exit /b
复制代码

taofan712

@echo off
set "var=qwertyuioplkjhgfdsazxcvbnm"
call :strLen var long
echo;%long%
pause&exit /b 
:strLen 

(   SETLOCAL ENABLEDELAYEDEXPANSION
    set "str=A!%~1!"
    set "len=0"
    for /L %%A in (12,-1,0) do (
        set /a "len|=1<<%%A"
        for %%B in (!len!) do if "!str:~%%B,1!"=="" set /a "len&=~1<<%%A"
    )
)
( ENDLOCAL 
    IF "%~2" NEQ "" SET /a %~2=%len%
)
goto :eof
复制代码

很偏门，但很好用，不忍独享,文件出处http://www.it1352.com/328587.html

taofan712

@echo off
set str=123ABC上中下
:loop
set /a a+=1
set str=%str:~0,-1%
if "%str%"=="" (echo %a%&pause>nul ) else goto loop
复制代码

Nsqs

回复 12# batman

@echo off
set n=12345689
set n=%n%;
for /f "tokens=1 delims=:" %%1 in ('^(echo %n:;=^&echo.%^)^|findstr  /o ".*"')do set /a c=%%1-3
echo %c%
pause
复制代码

不用临时文件