批处理怎样随机发牌？

小竹

要求：一副扑克52张牌（不包括大小王），随机发出13张。

随风

以前写的个.

@echo off
:lis
cls&setlocal enabledelayedexpansion
for %%a in (黑桃 红桃 梅花 方块) do (
  for /l %%b in (2 1 14) do (
  set ww=00%%b
  set ww=!ww:~-2!
  set _!random!=!ww!-%%a
))
for /f "tokens=2,3 delims=_-=" %%a in ('set _^|sort /r') do (
   set /a var+=1&if !var! leq 13 set +%%a-%%b=%%a
)
for /f "tokens=1,2 delims=+=" %%a in ('set +^|sort') do (
  for /f "tokens=1,2 delims=-" %%i in ("%%a") do (
     set /a suz=100%%i%%100,jia=10
     for %%k in (J Q K A) do set /a jia+=1&call set suz=%%suz:!jia!=%%k%%
     set %%j=!%%j! !suz!
))
for %%a in (黑桃 红桃 梅花 方块) do if not "!%%a!"=="" echo %%a !%%a!
echo\&echo 按任意键，进行下一轮发牌。
pause>nul&endlocal
goto lis
复制代码

youxi01

楼上的不错,不过提个建议

黑桃,梅花等不应该由你用文字表述出来，而应该是 用批处理显示出来
比如:方块 A可以这样
------------------------
|    ◆       A     |
|                             |
|                             |
|   A               ◆     |
-----------------------
当然，还可以做的漂亮些

novaa

楼上的提议好。顶个。

foxJL

楼上建议不错,我刚写好就照你们说的改了一下,看看效果如何.

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1,1,13) do (call :random&call :model)
echo.&pause>nul&exit
:random
set random1=%random%
set random2=%random%
set /a random1%%=14
set /a random2%%=5
if %random1% equ 0 (goto random) else (
	(set 11=J)&(set 12=Q)&(set 13=K)
	if %random2% equ 0 (goto random) else (
	(set 1=桃)&(set 2=杏)&(set 3=梅)&(set 4=方)
	set model=!%random2%!
	if %random1% lss 11 (
		if %random1% equ 1 (set num= A) else (set num= !random1!)
	) else (set num= !%random1%!)
	goto :eof
	)
)
:model
echo.  ┌────┐
echo.  │!model!　　!num!│
echo.  │　　　　│
echo.  │　　　　│
echo.  │　　　　│
echo.  │　　　　│
echo.  │!num!　　!model!│
echo.  └────┘
goto :eof
复制代码

youxi01

呵呵，还有一个建议
一行可以　显示　几张牌的嘛

小竹

是小楼吧？？？？？？？？？？？？

小竹

请教一下，黑桃、红桃、草花的符号有怎么输呢？？？

youxi01

呵呵，就是那个家伙
都叫他都用　小楼　他就是不用！！！
死脑筋！！

小竹

言归正传，黑桃、方块、草花符号？？？

youxi01

只会输　方块，其它的不会　输

ieutk

♥ ♠ ♣ ♦

在开始-程序-附件-系统工具-字符映射表，字体为“Times New Romen”，
差不多最下面的位置

[ 本帖最后由 ieutk 于 2007-12-31 02:12 编辑 ]

youxi01

呵呵，加分
还不错嘛

小竹

这个我知道，关键是怎么让它们在批处理中显示出来？？