[文本处理] 批处理如何每5分钟批量ping多个ip 并将ave值放入txt文件？

doubat

做网络时延的实验。想使用ping采集数据。
实现功能：
1、 一天内每5分钟批量ping多个ip
2、从txt中读入ip地址
3、 将每次ping的ave值放入txt文件
格式:
      ip    date time  ave

terse

修改下 隐藏运行

if "%~1"=="" mshta vbscript:createobject("wscript.shell").run("%~s0 0",0)(window.close)&exit
@echo off&setlocal enabledelayedexpansion
if not exist "ip.txt" msg %username% /time:5 "错误！！请确认IP地址已存入当前目录下的ip.txt文本！！！"&exit
if not exist "ping_result.txt" >ping_result.txt echo.IP		Date		Time		AVE
:loop
for /f "delims=" %%i in (ip.txt) do (
  set "Ave=NULL"
  for /f "skip=11 tokens=4 delims==" %%j in ('ping -w 500 -n 4 %%i') do set "Ave=%%j"
  >>ping_result.txt echo;%%i	!date:~,10!	!time:~,8!	!Ave: =!
)
ping/n 300 127.1>nul
goto loop
复制代码

测试环境 win xp3

再世情緣

刚刚写了一个，测试还行。。。
注意把批处理命名为pp.bat，为后面的vbs定时脚本用。。。

@echo off &&color 0a
setlocal enabledelayedexpansion
pushd "%cd%\"
:main
if not exist "ip.txt" msg %username% /time:5 "错误！！请确认IP地址已存入当前目录下的ip.txt文本！！！" &&call exit
if not exist "ping_result.txt" echo.IP		Date		Time		AVE >ping_result.txt
for /f "delims=" %%a in (ip.txt) do (
  set "ip=%%a"
  echo.正在Ping !ip! , 请稍后 ....
  ping -w 500 -n 4 !ip! | findstr /i "Average" >tmp.txt ||set "Ave=NULL" 
  for /f "tokens=3 delims=," %%i in (tmp.txt) do (
    set "Average=%%i"
    for /f "tokens= 3 delims= " %%m in ("!Average!") do (
    set "Ave=%%m"
    )
  )
  echo.!ip!	!date:~,10!	!time:~,8! 	!Ave! >>ping_result.txt
)
del /q /f tmp.txt
call exit
复制代码

每次Ping 会生成一个临时文件tmp.txt，你要的结果放在脚本所在目录，文档名称为ping_result.txt，如果Ping 不通，Ave值为Null ，请把ip地址列表放在脚本所在目录，格式为

192.168.1.1
192.168.1.2
......
复制代码

至于你要的每5分钟自动ping。。。这个。。。批处理窗口一直开着。。。有时候系统会自动结束cmd(貌似是，反正我的机器经常自动结束cmd.exe，尤其是后台运行的时候。。。)，建议用vbs脚本写，放在同一目录，直接运行vbs就行，我vbs刚刚入门。。。。再次献丑了。。。

for i=0 to 65536
  WSCript.CreateObject("WSCript.shell").run "pp.bat", 1
  WSCript.sleep "300000"
next
复制代码

这个。。。刚才测试360竟然说这个vbs是木马。。。。兄弟，天地良心啊，至于你用不用。。。。您看着办吧。。。对了，vbs运行的时候是后台的。。。如果需要关闭，打开一个新的cmd窗口

taskkill /f /im "wscript.exe"
复制代码