[文件操作] [分享]批处理获取图片文件拍摄时间的几个方法

aloha20200628

基本目的是》不用下载预装第三方，只用系统内置的资源，在批处脚本中直接调用 findstr/jscript/powershell 获取图片文件内置的 ‘拍摄时间’ (与资源管理器显示的图片文件拍摄时间一致)，为此参考了老帖中的一些有效方法，梳理精装了测试代码分享如下，均予测试通过

方法一》直接用 findstr 匹配图片文件中内置的 ‘拍摄时间’ 字段，取用最后一个匹配结果

@echo off &set/p "pF=拖入一个图片文件(查看其拍摄时间)："
for /f "delims=" %%t in (
	'findstr "199 200 201 202" %pF%^|more^|findstr /rc:"[12][09][0-9][0-9]:[0-9][0-9]:[0-9][0-9]" '
) do set "t=%%t"
echo,%t%&pause&exit/b
复制代码

方法二》通过 powershell 调用 wia.imageFile (微软标定的一种 ‘图像信息获取接口’) 提取与 ‘拍摄时间’ 对应的属性数据

@echo off &set/p "pF=拖入一个图片文件(查看其拍摄时间)："
for /f "delims=" %%t in (
	'powershell "$i=new-object -comobject WIA.ImageFile;$i.LoadFile('%pF%');$i.properties.item('ExifDTOrig').value" '
) do echo,%%t
pause&exit/b
复制代码

方法三：代码存为 test.bat 运行》通过 jscript 调用 wia.imageFile 提取与 ‘拍摄时间’ 对应的属性数据

@set @v=1 /* &@echo off &set/p "pF=拖入一个图片文件(查看其拍摄时间)："
for /f "delims=" %%t in ('cscript /nologo /e:jscript "%~f0" %pF%') do echo,%%t
pause&exit/b */
v=WSH.arguments, img=WSH.createObject('WIA.imageFile'), img.loadFile(v(0));
WSH.echo(img.properties.item('ExifDTOrig').value);
WSH.quit();
复制代码

方法四：代码存为 test.bat 运行》通过 jscript 调用 shell.appliction 提取与 ‘拍摄时间’ 对应的属性数据

@set @v=1 /* &@echo off &setlocal&set/p "pF=拖入一个图片文件(查看其拍摄时间)："
for /f "delims=" %%t in ('cscript /nologo /e:jscript "%~f0" %pF%') do set "t=%%t"
echo,%t:?=% &endlocal&pause&exit/b */
v=WSH.arguments, s=WSH.createobject('shell.application');
n=v(0).lastIndexOf('\\'), p=v(0).slice(0,n), f=v(0).slice(n+1);
d=s.NameSpace(p), i=d.ParseName(f);
WSH.echo(d.GetDetailsOf(i, 12)); //属性序号=12 对应属性名='dateTaken'
WSH.quit()
复制代码

aloha20200628

回复 3# Five66

参见》https://photo.stackexchange.com/ ... -in-what-circumstan

Five66

貌似标签号 0x0132(DateTime) 和 0x9003(DateTimeOriginal/ExifDTOrig) 是一样的

buyiyang

也可以直接读取图片文件的exif信息，
从9003标签的DE数据获取拍摄时间信息的偏移量，
根据文件头判断大小端序，然后解码出拍摄时间，简单写了一下

@echo off&setlocal enabledelayedexpansion
set /a size=2048
for %%i in (*.jpg *.jpeg *.tiff *.raw *.cr2 *.cr3) do (
    copy /y "%%i" $.temp >nul
    fsutil file seteof $.temp %size% >nul
    certutil -encodehex -f $.temp $.temp >nul
    set /a n=tag=len=end=t=dt=le=0&set "offset="
    (for /f "tokens=1*" %%a in ($.temp) do (
        set "str=%%b"
        for /f "delims=。" %%s in ("!str:   =。!") do for %%h in (%%s) do (
            if !end! lss 19 (
                set /a n+=1,tag+=1
                if /i "%%h"=="2a" if "!pre!"=="49" if "!ppre!"=="49" set /a n=3
                if /i "%%h"=="00" if "!pre!"=="4d" if "!ppre!"=="4d" set /a n=3,le=1
                if !le! equ 1 (
                    if "!pre!%%h"=="9003" set /a 1/t 2>nul||set /a tag=1009003,t+=1
                    ) else if "%%h!pre!"=="9003" set /a 1/t 2>nul||set /a tag=1009003,t+=1
                if !tag! gtr 1009009 if !tag! leq 1009013 (
                    if !le! equ 1 (set "offset=!offset!%%h") else set "offset=%%h!offset!"
                    set /a len+=1
                    )
                if !len! equ 4 if !n! gtr 0x!offset! echo,%%h&set /a end+=1
                set "pre=%%h"&&set "ppre=!pre!"
                )
            )
        ))> $.time
    certutil -decodehex -f $.time $.time >nul
    for /f "tokens=* delims=" %%t in ($.time) do set dt=%%t
    if !dt! equ 0 (echo,------nothing---------%%i) else echo,!dt!---%%i
    )
del /q $.temp $.time
pause
复制代码