[文本处理] 已知开始行号和结束行号，批处理怎样把这之间的内容复制出来？

wheat611

是用for语句吗？怎么把行号之间的内容复制到另一个文件里面呢？

PowerShell

最近初学powershell的坛友呢?速来回答此简单问题!拿楼主练手!
提示:Get-Content 问题.

batman

行数较多，并考虑空行和特殊字符的情况：

@echo off
set /a startline=23,endline=2234
(for /f "delims=" %%a in ('findstr /n .* a.txt') do (
  for /f "delims=:" %%b in ("%%a") do (
    set "str=%%a"
    setlocal enabledelayedexpansion
    set "str=!str:*:=!"
    if %%b geq %startline% if %%b leq %endline% echo,!str!
    endlocal
  )
))>new.txt
start new.txt
复制代码

batman

行数不太多的话，用findstr来取：

@echo off&setlocal enabledelayedexpansion
set /a startline=23,endline=234
for /l %%a in (%startline%,1,%endline%) do set "num=!num! ^%%a:"
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* a.txt^|findstr /r "%num:~1%"') do echo,%%b)>new.txt
start new.txt
复制代码

522235677

@echo off & setlocal ENABLEDELAYEDEXPANSION
set head=2
set end=9
set file=robots.txt
for /f "delims=" %%a in (%file%) do (
	set /a hs+=1
	if "!hs!" GEQ "%head%" (echo %%a)
	if "!hs!"=="%end%" goto ok
)
:ok
pause
复制代码

等等，这个貌似会忽略掉空行。坐等高手

林小七

回复 1# wheat611

能给出文本吗？亲~~