[系统相关] [已解决]批處理提取CPU名字問題

stealthfire

我為了提取CPU名字使用以下命令:

for /f "tokens=2* delims==" %%i in ('wmic cpu get name /format:list') do echo %%i
复制代码

結果如下:
Intel Core CPU X9000 @ 3.5GHz

問題是我只想取名字,不需要顯示Hz.
另外CPU名字有以下格式:
Intel XXX CPU XXXXX @ XXXHz
Intel XXX CPU XXXXX XXXHz
Intel XXX CPU XXXXX

請問如何有"@"和包含"Hz"字串就進行移除否則直接輸出?

stealthfire

回复 6# apang


    感謝你的幫忙,已得到想要的數值.
    set原來有這樣的用法...證明我用功不夠...-_-

    "CPU"字串我也不需要的,更改後如下:

@echo off
for /f "tokens=2*delims=@=" %%i in ('wmic cpu get name /format:list') do (
    set "cpu=%%i%%j"
)
set "cpu=%cpu:CPU= %"
set "cpu=%cpu: =\%"
for /f "delims=" %%a in ("x:\%cpu:Hz=\..%") do set "cpu=%%~fa"
set "cpu=%cpu:\= %"
echo,%cpu:~3%
pause
复制代码

terse

@echo off
for /f "tokens=2 delims==" %%i in ('wmic cpu get name /value') do for /f "tokens=*" %%i in ("%%i") do set cpu=%%i
for /f "delims=" %%i in ('mshta "javascript:new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).Write('%cpu:@=%'.replace(/[^ ]*Hz$/ig,''));close()"') do set cpu=%%~nxi
echo %cpu%
pause
复制代码

apang

回复 5# stealthfire


    我理解错了，这样试试：

@echo off
for /f "tokens=2*delims=@=" %%i in ('wmic cpu get name /format:list') do (
    set "cpu=%%i%%j"
)
set "cpu=%cpu: =\%"
for /f "delims=" %%a in ("x:\%cpu:Hz=\..%") do set "cpu=%%~fa"
set "cpu=%cpu:\= %"
echo,%cpu:~3%
pause
复制代码

stealthfire

感謝說明,已然從教學中第7章明白用法.
但依照你的代碼會出現以下結果:

for /f "tokens=2* delims==" %%i in ('wmic cpu get name /format:list') do (
   set "cpu=%%i"
)
set "cpu=%cpu:@ =%"
set "cpu=%cpu:Hz=%"
echo %cpu%
复制代码

Intel Core CPU X9000 3.5G
复制代码

我需要把包含Hz的字串移除...
結果應該是:

Intel Core CPU X9000
复制代码

Hz有以下類型:
700MHz , 1.1GHz , 3GHz , 2.55GHz ......

apang

回复 3# stealthfire


    把第5行改成 set "cpu=%cpu:Hz=%" 就可以了
    第4行是把@ 替换成空值，即删除@ ，具体用法可以搜索论坛http://bbs.bathome.net/thread-14927-1-1.html

stealthfire

謝謝你的問答.
可否解釋第四行如何把@移除?
另外一個是把包含Hz字串移除而不是最後2個字移除
e.g. 700MHz , 1.1GHz , 3GHz , 2.55GHz .....

apang

for /f "tokens=2*delims==" %%i in ('wmic cpu get name /format:list') do (
    set "cpu=%%i"
)
set "cpu=%cpu:@ =%"
if "%cpu:~-2%" == "Hz" set "cpu=%cpu:~,-2%"
echo,%cpu%
复制代码