[文本处理] [已解决]批处理怎样判断一个txt文件是否为空/0字节？

zidian5

我有个系统，会生成一个文件“D：\aa.txt”
这个文件会被经常改写，有时为空（即：0字节），有时有内容（即：大于0字节）

我想用批处理来判断：若该文件为空，则执行"A.exe";
                              若该文件不为空，则执行"B.exe”

谢谢！

tmplinshi

方法六：
for /f "eol=" %%a in (a.txt) do set tmp=1
if defined tmp (a.exe) else b.exe
::忽略空行
zm900612 发表于 2011-3-25 13:08

"eol=" 会忽略以双引号开头的行。

dahual

以前不知道此用法，这下好了。学习帖。

另外，FOR 变量参照的替换已被增强。您现在可以使用下列
选项语法:

     %~I          - 删除任何引号(")，扩展 %I
     %~fI        - 将 %I 扩展到一个完全合格的路径名
     %~dI        - 仅将 %I 扩展到一个驱动器号
     %~pI        - 仅将 %I 扩展到一个路径
     %~nI        - 仅将 %I 扩展到一个文件名
     %~xI        - 仅将 %I 扩展到一个文件扩展名
     %~sI        - 扩展的路径只含有短名
     %~aI        - 将 %I 扩展到文件的文件属性
     %~tI        - 将 %I 扩展到文件的日期/时间
     %~zI        - 将 %I 扩展到文件的大小
     %~$PATH:I   - 查找列在路径环境变量的目录，并将 %I 扩展
                   到找到的第一个完全合格的名称。如果环境变量名
                   未被定义，或者没有找到文件，此组合键会扩展到
                   空字符串

可以组合修饰符来得到多重结果:

     %~dpI       - 仅将 %I 扩展到一个驱动器号和路径
     %~nxI       - 仅将 %I 扩展到一个文件名和扩展名
     %~fsI       - 仅将 %I 扩展到一个带有短名的完整路径名
     %~dp$PATH:I - 搜索列在路径环境变量的目录，并将 %I 扩展
                   到找到的第一个驱动器号和路径。
     %~ftzaI     - 将 %I 扩展到类似输出线路的 DIR
复制代码

CrLf

方法很多，
方法一：
findstr .* a.txt&&a.exe||b.exe
方法二：
for %%a in (a.txt) do if %%~za==0 (a.exe) else b.exe
方法三：
cd.>tmp
fc tmp a.txt&&a.exe||b.exe
方法四：
wmic...
::详见5楼
方法五：
vbs...
::但是我只知道有，不清楚怎么写
方法六：
for /f "eol=" %%a in (a.txt) do set tmp=1
if defined tmp (a.exe) else b.exe
::忽略空行

当然还可以写出很多引申的办法，就不一一列举了

hbwazxf

新人学习。感谢2楼的方法

wc726842270

无聊用WMIC写一个，当然不如用2L的方法好。
PS：空格真是上火，找了N久才发现

@echo off
set /p #a=请指定文件:
for %%i in (%#a%) do set #d=%%~di&set #p=%%~pi &set #n=%%~ni& set #e=%%~xi 
set b=%#p:\=\\%
set c=%b:~0,-1%
set x=%#e:~1,-1%
wmic datafile where "drive='%#d%' and path='%c%' and filename='%#n%' and extension='%x%'" get filesize
pause
复制代码

dashige

equ "0"
哈哈。。。。

zidian5

2# batman


非常感谢，已经解决了！

batman

@echo off
set "paths=d:\a.txt"
for %%a in ("%paths%") do (
     if "%%~za" equ "0" (
        start "" "完整路径(a.exe)"
        ) else (
        start "" "完整路径(b.exe)"
     )
)
复制代码