[文本处理] 求助批处理TXT文件首位添加固定字符如何去除换行符？

zhuyihzx

需要批量给txt文件开头添加字符##，
但是怎么改都会有换行，请高手帮忙解决，谢谢！~

需要：
你好，世界
得到：
##你好，世界

目前得到的是如下，多一个换行，
##
你好，世界

@echo off
for /f "delims=" %%i in ('dir /a-d /b /s *.txt') do (
echo %%i 
(echo ##
type "%%i" )>tem.yky
move tem.yky "%%i")
复制代码

77七

@echo off
for /f "delims=" %%i in ('dir /a-d /b /s *.txt') do (
	set /p str=<"%%i"
	>$ call echo ##%%str%%
	>>$ more +1 "%%i"
	move $ "%%i"
)
pause
复制代码

Batcher

回复 7# zhuyihzx


不需要事先准备外部文件的方法

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /a-d /b /s *.txt') do (
    echo %%i
    set /p =##<nul >temp.yky
    type "%%i" >>temp.yky
    move /y temp.yky "%%i" >nul
)
复制代码

Five66

不知行否

@echo off
for /f "delims=" %%i in ('dir /a-d /b /s *.txt') do (
echo %%i 
set/p=##>tem.yky <nul
type "%%i" >>tem.yky
move tem.yky "%%i"
)
复制代码

zhuyihzx

回复 8# qixiaobin0715
    感谢大佬，可以用了，

qixiaobin0715

将文本文件00.txt修改为00.log，代码中的00.txt也修改为00.log，再试试。
直接使用代码加效率不如这样好。

zhuyihzx

回复 6# qixiaobin0715


可以增加了，但是有个小问题，
运行后先在00.txt上增加了##，然后后续的##都变成####了，
有没有办法不用外接00.txt，直接在BAT中加上##呢？
感谢大佬的帮忙

qixiaobin0715

回复 5# zhuyihzx
已修改

zhuyihzx

请在与批处理同目录处新建一个文本文件00.txt，其内容为##，只一行不要回车。
qixiaobin0715 发表于 2023-9-19 15:10

好像不行，显示如下信息，

copy /b "00.txt+E:\123\
move "temp" "E:\123\
文件名、目录名或卷标语法不正确。
已复制         0 个文件。
系统找不到指定的文件。

qixiaobin0715

请在与批处理同目录处新建一个文本文件00.txt，其内容为##，只一行不要回车。

@echo off
for /f "delims=" %%i in ('dir /b /s /a-d *.txt') do (
    copy /b "00.txt"+"%%i" "temp"
    move "temp" "%%i"
)
复制代码

zhuyihzx

回复 2# Batcher
就是开头的第一行就行了，谢谢

Batcher

回复 1# zhuyihzx


    只在第一行开头添加吗？还是每一行开头都添加？