[分享]批处理利用set /p与重定向输入分行获取文本内容

CrLf

起因是前几天的某个帖子中看到 cmd<1.txt 的用法，原以为1.txt 中的 pause 之所以被跳过是因为执行完后马上接收到了一个回车符，于是我把1.txt 中的所有 pause 都改成 pause&rem ，并去除所有回车符进行试验，下为去除回车符的代码：

@echo off&setlocal enabledelayedexpansion
set hh=^


::获取换行符
for %%a in (
        "@echo off" "pause&rem" "echo abc" "pause&rem"
) do set str=!str!!hh!%%~a
echo !str:~2!>3.txt
::只用换行符断行

cmd<3.txt
echo;
echo ________end________
pause
复制代码

假设修改后 1.txt内容如下（测试时，此文本中不存在回车符）：

@echo off
pause&rem
echo abc
pause&rem
复制代码

结果仍然没有等待用户输入，并且还吞掉了下一行 echo 的第一个字符，导致 cmd 显示：

        请按任意键继续. . .
        'cho' 不是内部或外部命令，也不是可运行的程序
        或批处理文件。
        请按任意键继续. . .
复制代码

对此感到非常疑惑，百思不得其解之下去请教寒夜版主，他问我 pause 等待的是什么输入，我才忽然醒悟，原来 pause 等待的是“任意键”，也就是说，它把 echo 的 e 当作用户输入给接收了（因为行末的 0D 0A被 cmd 接收了，所以 pause 接收的第一个字符就是下一行的首字符 e），因此这里用 pause 无法实现暂停的效果，这就推翻了我原来的认识，证明等待用户输入的命令并不是以回车符作为终止输入的信号。
（另：其实现想来这个问题也好解决，既然是类似 cmd /c "pause"<1.txt 这样的原因造成 pause 从 1.txt 获取了任意输入，那么改成 pause<con 即可重定向为从键盘获取输入）

进一步思考一下，众所周知， set /p 首行=<1.txt 能获取 1.txt 第一行，那么对含有大量 set /p 的语块进行重定向，又是什么结果呢？

@echo off
(for /l %%a in (1 1 10) do set /p .%%a=)<%0
set.
pause
复制代码

可以看到，通过 set /p 配合重定向，能够把文本每一行都设为变量值，这是全新的技巧，更重要的是，这是一种全新的遍历文本的方式，它相当于不跳过空行的 for until ，这与 for /f 的 skip 参数相映成趣，而且还对特殊字符有极佳的兼容性。不过有得必有失，使用 set /p 赋值时，变量长度不能超过 1024 字节，所以局限了这个技巧的适用范围。
        
激动之余，又产生了两个疑惑：
    1、set /p 是以什么为依据断行
    2、当循环数大于文本行数时，为什么没有停顿下来等待用户输入

和寒夜版主一起做了几个试验，证明无论是单纯的 0D 回车符或者 0A 换行符都无法实现平时在 cmd 窗口中敲回车结束 set /p 输入的效果，必须出现连续的一组 0D 0A 才能够终止对一个 set /p 的输入。关于终止 set /p 输入的“特征码”，25 楼的 mxxcgzxxx 提出了更合理的猜想：0D 0A 和 0A 0D 这两种组合都能起到终止 set /p 输入的作用。
(25楼链接：http://bbs.bathome.net/viewthrea ... muid=30406#pid86638)
        
而第二个问题，绕了半天弯子终于得到一个比较合理的猜测：当重定向的输入被前面执行的命令取用完的时候，剩下的就是从空设备的输入，也就是 set /p .5=<nul。所以假如文本有N行，那么超过第 N 次的 set /p 都接收到了来自空设备的输入因而没有被赋值，示例如下，假设原 bat 为：

(set /p .a=
set /p .b=)<只有一行的文件.txt
set.
复制代码

其作用相当于：

set /p .a=<只有一行的文件.txt
::取首行
set /p .b=<nul
::从空设备获取输入，等于无输入
set.
::显示以 . 开头的变量
复制代码

通过这个猜测和其他一些命令接收重定向输入时表现出的特性衍生出一个推测，那就是 cmd 在接受重定向输入到命令的时候，也许是一个字符一个字符顺序传递给语块\语句的，那些能够接受重定向输入的命令会自发地从中获取输入，直到命令自行关闭输入句柄为止。
        
这可以理解为 cmd 中出现重定向输入的时候，输入中的字符在排队等候被命令依次提走，一直到无字符可提的时候，重定向输入的来源就成为了一个空设备 nul。
        
好比一个旅行团在打车，出现愿意载客的出租车时，队伍就有序地依次上车，一辆车客满后就再等下一辆（旅行团并不知道当前这辆车何时客满，他们只需要机械地让排头的人上车、直到司机喊停为止），最终所有人都打车走光，这时候新来的出租车就找不到客人了，所以空车离开时当然还是空车。
        
当然有些命令是以任意合法字符或者固定字符来判定何时结束输入的，比如 choice、set /p 和 pause，这就很有利用的价值。
        
此处仅以 set /p 举几个例子：

@echo off
set /p line=要获取的行所在行数：
(for /l %%a in (1 1 %line%) do set /p 内容=)<a.txt
set 内容
::获取指定行内容的新方法，由于无需遍历整个文本，要获取的行位置靠前的情况下有很大优势
复制代码

@echo off
(for /l %%a in (1 1 100) do set /p .%%a=)<%0

::不跳过空行赋值，但是 tmplinshi 版主的测试结果表明这比常规办法稍慢，它只在某些场合有优势，比如只获取前 N 行时，或者要兼容空行的情况，再或者需要兼容特殊字符的时候。
复制代码

(5楼链接：http://bbs.bathome.net/viewthrea ... muid=30406#pid86516)

@echo off&setlocal enabledelayedexpansion

set n=1
(for /l %%a in (1 1 5) do (
    if defined .!n! set /a n+=1
    set /p .!n!=
))<%0
::当然也同样可以跳过空行只将前 N 行赋值，但是这里的“前 N 行”计数时其实还是包括空行的，如果是要求取不把空行计算在内的前 N 行，我想最经济的方法就是先用 findstr . a.txt 输出非空行再分别赋值了
复制代码

@echo off
(for /l %%a in (1 1 7) do (
    pause
    set /p echo=
    echo !echo!
)<%0
::去除每行行首第一个任意字符的另一种方法，如果不计较效率的话，用 choice 可以只保留指定字符
复制代码

@echo off
(for /l %%a in (1 2 7) do (
    set /a a=1,b=2
    set /p a=
    set /p b=
    if !a!==!b! echo 相等
)<%0
::以两行为周期判断其内容是否相等，这比起老方法省下了许多麻烦，比如无需用 setlocal、endlocal 来兼容特殊字符
复制代码

@echo off
(for %%a in (
1-关回显 2-循环体 3-循环内容 4-do 4-设变量 5-输入 6-查看变量 7-注释
) do (
    set /p .%%a=
))<%0
set.
::可以通过无参数的for来循环，实现了以往无法实现的效果
复制代码

@echo off&setlocal enabledelayedexpansion
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* 1.txt') do (
    set t2=
    set /p t2=
    echo;%%b!t2!
))<2.txt>合并.txt
::由于可以有两个不同的输入来源并存，所以双文本乃至多文本合并就成为轻而易举的事了
复制代码

@echo off&setlocal enabledelayedexpansion
for %%a in (a\*.txt b\*.txt) do set /a n+=1
dir /b /a-d /o-n b\*.txt>list.$
::计算文件总数为 %n%，生成要复制的文件列表为 list.$
(for /l %%a in (1 1 %n%) do (
	if not exist a\%%a.txt (
		set /p f=
		copy "b\!f!" "a\%%a.txt"
	)
))<list.$
::以往让人头疼的按递增文件名复制文件的问题，也可以这样解决
del /f list.$>nul
pause
复制代码

无奈的是，可以分段接受重定向输入的命令寥寥无几，所以暂时还没有想到更多的实用技巧，还是等待大家来补充吧。

感谢 寒夜孤星、mxxcgzxxx、tmplinshi 等人的指点和共同探讨、测试。

LJY4.0

空设备真的是空的吗
pause<nul

GNU

回复 35# liero1982


    可以学习并使用PowerShell用它来取代BAT

CrLf

回复 35# liero1982


    可以试试 conset、CSet、seti 之类的第三方工具，除此之外没有简洁的办法了

liero1982

回复 34# CrLf


    谢谢，受教了；那按照这个思路，是不是就真没办法用一条简单的语句实现命令输出到变量（我现在只知道用 临时文件 或者用 for /f）

CrLf

回复 33# liero1982


与换行符无关，是父进程不能获取子进程变量环境的原因，解释如下：

这样实际上是可以获取到的：

dir | set /p VAR=^& set VAR
::此处已经捕获变量
pause

set VAR
::此处变量消失
pause
复制代码

为什么会有这种现象，是因为管道是前后两个进程通信，cmd 如果发现前后的语句是内部命令（或用 & | && || 连接的代码块），就会启动一个 cmd 去执行这一部分
所以上面的代码相当于：

cmd /c dir | cmd /c "set /p VAR=& set VAR"
复制代码

也就是说，VAR 变量是在被管道启动的子进程 cmd.exe 中赋值的，只在子进程中有效，当前运行的父进程 cmd.exe 是获取不到的

liero1982

问：

dir | set /p v=0
复制代码

这句是不能达到获取命令输出首行文字的目的的。读了楼主的分析，估计是因为只有cr没有lf的缘故，如何通过命令补一个lf让set /p捕获前文输出呢？

tkaven

@echo off&color a&setlocal enabledelayedexpansion
::用法 call :insert "要修改的本文文档路径" "在哪一行下面插入文字" "所要插入的文字"
call :insert "C:\Users\Administrator\Desktop\新建 Text Document.txt" "5" "我好喜欢你啊，哈哈哈"
endlocal
echo 操作完成,按任意键退出&pause>nul
exit

:insert
FOR /F %%l in ('find /c /v ""^< %1') do (
	for /l %%a in (1 1 %%l) do (
		set /p str=
		set /a 当前行=当前行+1
		if !当前行! GTR %~2 (
			echo.!str!
			) else (
			if !当前行! EQU %~2 (echo.!str!&echo.%~3) else (echo.!str!)
		)
		set str=
	)
)< %1 >> "%~d1%~p1%~n1_已处理%~x1"
goto :eof
复制代码

garyng

回复 31# DAIC


    我觉得你发错地方了～

DAIC

回复 30# netbenton


版主请帮忙看看这个合并文件时处理特殊字符的问题吧
http://bbs.bathome.net/thread-13735-1-1.html

netbenton

这个真的是新发现，竟然还支持嵌套，看来多个文件合并也可以了

@echo off
(set/p a1=

   (set /p b1=
   set /p b2=
   )<bb.txt

set/p a2=)<aa.txt


set a
set b

pause
复制代码

raymai97

回复 27# mxxcgzxxx


    其实我有些混乱了，你的代码的意思是这样么？

(pause>nul&set /p a=)<%0
复制代码

利用批处理开头来获取换行字符和空格字符

set "b=!a!"
复制代码

换行+空格+退回字符=换行+不会再退回的退回字符=完整实用的换行符？

就达成了0d 0a组合的目的？

mxxcgzxxx

用提取的换行符玩下，虽然不知实用性在哪方面可以应用？
因为论坛会吃单空格行，所以我使用：号

 
:
@echo off
::获取0A换行符
(pause>nul&set /p a=)<%0
echo 你好%a%我在哪?
pause>nul
复制代码

由于半个换行让“我在哪？”进行了无间道，不存在的东西
但开了变量延时后就不一样了

 
:
@echo off
setlocal enabledelayedexpansion
::获取0A换行符
(set/p=&pause>nul&set /p a=)<%0
echo 你好！!a!我在哪啊？!a!你也不知道吗？!a!真是可惜……
pause>nul
set "b=123!a!456!a!789"
echo !b!
pause>nul
复制代码

效果不是太理想但也很好了，一次三行内容，就是后面的每行多一个符号，可以加个退格符就可以了！！
而且可以通过赋值传达给别的函数，但一定要开变量延时和加上一个退格符！

我也搜索了论坛，应该来说这个方法是快而简便获取换行符的方法，
又一个新技术诞生了哈！

 
:
@echo off
setlocal enabledelayedexpansion
::获取0A换行符
(pause>nul&set /p a=)<%0
::通过赋值用退格符将换行符后的空格修整得到完整实用的换行符
set "b=!a!"
echo !b!123456!b!789
pause>nul
复制代码

CrLf

25# mxxcgzxxx


好！确实很有可能，测试代码如下：

@echo off
set x0a=^



::空行请自行添加
for /f %%a in ('copy /z %~s0 nul') do set x0d=%%a
cmd /v:on /c echo abc!x0a!!x0d!123!x0a!!x0d!>1.txt
(for /l %%a in (1 1 10) do set /p .%%a=)<1.txt
set.
pause>nul
复制代码

证明确实是以三行为一周期（汗一个，早先对此的测试结果是忘了加上被换行的那一行的，所以当时测试所得的周期很没有规律...误导人啊误导人），而且很有可能确实是像老兄说的那样，只要碰到一组 0D 0A，无论它们字符顺序如何，都能结束 set /p 的输入行为。

可用如下代码进行验证：

@echo off&setlocal enabledelayedexpansion
set a=^


(for /f %%a in ('copy /z %0 nul') do set b=%%a
set<nul /p=赋值成功!a!!b!赋值失败)>1.txt
set /p e=<1.txt
echo !e!
pause
echo d|debug 1.txt
::如果未出现赋值失败的字眼则代表 0A 0D 成功地结束了 set /p 的输入，结果证明确实如此
复制代码

越来越完善了

mxxcgzxxx

24# zm900612


那可以这样理解吗？ 0D 0A 和0A 0D 都可以起到结束SET/P的输入过程
三行空行时
0D 0A
0D 0A
0D 0A
第一个0D被吃  SET/P得到0A 0D （强行终结）
第二个0A被吃   SET/P得到0D 0A （完整）
这样还能解释为什么三个空行被赋值两次
0A 0D 的组合有没有代表什么？
5个空行情况：
吃 ---- 留
0D---0A| 0D
0A|---0D  0A|
0D---0A| 0D
0A|---文本，所以正常不换行

以此类推，基本都合理了
1空行：0A 换行文本
2空行：完整文本
3空行：文本少头一字符
4空行：0A 换行文本
5空行：完整文本
。。。三个空行一个循环，所以：
1，4，7，10。。。为换行文本
2，5，8，11。。。为不少字的完整文本
0，3，6，9。。。为少头一字符的文本

刚才测试了下，完全符合这个规律！