[注册表类] [已解决]注册表指定路径下，含有关键字的键值。如何搜索并删除？

ygqiang

[已解决]注册表指定路径下，含有关键字的键值。如何搜索并删除？

HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run

关键字是：MicrosoftEdgeAutoLaunch

键值名如下类似的，可能还有其他更多的。
MicrosoftEdgeAutoLaunch_98769996E24836F99EC8617644423B4C
MicrosoftEdgeAutoLaunch_ED290F2741A0DC7799A9C29B127CCBAC
MicrosoftEdgeAutoLaunch_B8188322885C6DD24FAC5C8FE26E079B
MicrosoftEdgeAutoLaunch_85C848D66A0F5F006EC89D7F6F2AD429
。。。等等类似的

删除某个键值
reg delete "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v "键值名" /f

ygqiang

回复  ygqiang


点击右上角的COPY按钮复制代码，不要使用鼠标选中之后再复制。
如果还是不行，而且你 ...
Batcher 发表于 2023-9-28 14:39

    谢谢，代码正常了

Batcher

回复 4# ygqiang


点击右上角的COPY按钮复制代码，不要使用鼠标选中之后再复制。
如果还是不行，而且你也不知道如何调整test-2.bat，那么就先用test-1.bat吧。

ygqiang

回复  ygqiang


test-2.bat
Batcher 发表于 2023-9-28 13:19

    这个代码，
echo reg delete "%RegKey%" /v "!ValueName!" /f >b1.txt
测试输出结果b1.txt内容如下：

reg delete "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v "MicrosoftEdgeAutoLaunch_B8188322885C6DD24FAC5C8FE26E079B    " /f

键值后面带空格了。

Batcher

回复 1# ygqiang


test-2.bat

@echo off
set "RegKey=HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run"
set "StrKey=MicrosoftEdgeAutoLaunch"
for /f "tokens=*" %%i in ('reg query "%RegKey%" ^| findstr /i /c:"%StrKey%"') do (
    set "StrFull=%%i"
    setlocal enabledelayedexpansion
    set "StrSuffix=!StrFull:*    REG_SZ=!"
    call set "ValueName=%%StrFull:    REG_SZ!StrSuffix!=%%"
    reg delete "%RegKey%" /v "!ValueName!" /f
    endlocal
)
复制代码

Batcher

回复 1# ygqiang


test-1.bat

@echo off
set "RegKey=HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run"
set "StrKey=MicrosoftEdgeAutoLaunch"
for /f "delims=" %%i in ('reg query "%RegKey%" ^| findstr /i /c:"%StrKey%"') do (
    set "StrFull=%%i"
    setlocal enabledelayedexpansion
    for /f "delims=|" %%a in ("!StrFull:    =|!") do (
        reg delete "%RegKey%" /v "%%a" /f
    )
    endlocal
)
复制代码