[文本处理] 【已解决】获得的信息如何保存到INI文件

dnvplj

请问各位朋友，如何将下面代码获得的信息保存到INI文件。

代码是本论坛管理员Batcher的，在此感谢。

@echo off
rem 指定待搜索的文件
set "FileName=abat.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
        pushd %%a:\
        for /r %%b in (*%FileName%) do (
            if /i "%%~nxb" equ "%FileName%" (
                echo,%%b
            )
        )
        popd 
    )
)

pause
复制代码

保存位置和文件名：
C:\Soft\wj.ini

保存的内容：
[Cupy]
ITEM=获得信息的路径和文件名

dnvplj

先建个文件夹就正常了

dnvplj

回复 4# Batcher

感谢回复，运行后有，C盘下什么都没有？提示：系统找不到指定的路径

Batcher

@echo off
rem 指定待搜索的文件
set "FileName=abat.txt"
>"C:\Soft\wj.ini" echo [Cupy]
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
        pushd %%a:\
        for /r %%b in (*%FileName%) do (
            if /i "%%~nxb" equ "%FileName%" (
                >>"C:\Soft\wj.ini" echo ITEM=%%b
            )
        )
        popd 
    )
)
复制代码

dnvplj

回复 2# Batcher

是的，请老大指点，谢谢。

Batcher

wj.ini里面只有那两行内容吗？