【练习-003】批处理实现文本左右对齐排版

pusofalse

如1.txt内容如下。

111111111111111111111    98912 张三
222222222222222222    150020 李四四
  333333333333333333333    360000 王五
444444444444444444    2332 赵六六
  555555555555555555    222 田七
666666666666666666666    999999 舞吧COPY

通过批处理输出为：

 
111111111111111111111      98912 张三
222222222222222222        150020 李四四
333333333333333333333     360000 王五
444444444444444444          2332 赵六六
555555555555555555           222 田七
666666666666666666666     999999 舞吧COPY

代码要求，不生成任何临时文件。
代码简洁，视思路与代码加分！
------------------------------------------------------------------------------------------
本题只是给出一个简单的文本通过批处理排版，而要求代码的通用，正如batman版主所说，会是一个繁琐的过程，于是就题解题，不必考虑代码的通用。

[ 本帖最后由 batman 于 2008-7-27 23:57 编辑 ]

qixiaobin0715

根据3楼思路改写，实现列与列之间空格最少：

@echo off
setlocal enabledelayedexpansion
set n=0
for /f "tokens=1,2" %%i in (1.txt) do (
    set "var=%%i%%j"
    set m=0
    call :1
)
for /l %%x in (1,1,!n!) do set KG= !KG!
set /a n+=1
for /f "tokens=1-3" %%a in (1.txt) do (
    set str=%%a%%b%KG%
    for %%y in (!n!) do set str=!str:~0,%%y!
    set str=!str:%%b=!%%b %%c
    echo !str!
)
pause
goto :eof
:1
if not "!var:~%m%,1!"=="" set /a m+=1&goto 1
if %m% gtr %n% set n=%m%
goto :eofCOPY

qixiaobin0715

就题解题，前2列字符目视不超过30个字符，KG30的值取30个空格：

@echo off
set KG30=                              
setlocal enabledelayedexpansion
for /f "tokens=1-3" %%a in (1.txt) do (
set str=%%a%%b%KG30%
set str=!str:~0,30!
set str=!str:%%b=!%%b %%c
echo !str!
)
pauseCOPY

ai20110304

回复 1# pusofalse

::文本两端对齐
@echo off & setlocal enabledelayedexpansion
cd /d %~dp0
::将空格替换成#号，再在基础上进行切割，结合tab水平制作符。
for /f "delims=" %%i in (1.txt) do (
	set "str=%%i" 
	set "str=!str: =#!"
	rem echo;!str!
 
	for /f "tokens=1-3 delims=#" %%a in ("!str!") do echo;%%a	%%b	%%c
	
)
pauseCOPY

yujw668

回复 12# batman


    版主，您好，看了您的代码很实用，但是如果有一种情况就是第二列有空的，怎么处理呢？
例如原文本：
111111111111111111111    98912 张三
222222222222222222    150020 李四四
  333333333333333333333    360000 王五
444444444444444444         赵六六
  555555555555555555        田七
666666666666666666666    999999 舞吧

如果第二列为空的话，生成的第三列就跑到了第二列去了，请问下怎么解决呢？

ShenMian

格式printf 字符串1 空格数 字符串2 空格数 ... 空格数 字符串n
代码:

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2,3" %%a in (1.txt) do (
    call:printf %%a 20 %%b 20 %%c
    echo;
)
exit /b
 
:printf
set /p "=%~1"<nul
set length=0
set "str=%~1"
:printf_0
if "!str:~%length%!" == "" (
	for /l %%a in (%length%,1,%2) do set /p = <nul
	shift
	shift
	if not "%~3" == "" goto printf
	exit /b
)
set /a length+=1
goto printf_0COPY

依山居

"""
#方法4 重用了方法3的上半部分代码算出列1列2最大长度，以此对齐顶点。
#这个方法的思路是不使用空格或者其它符号填充，而是在写入文件时，
#指针直接前移使字符对齐。空的字符位置会自动被\x00填充？
#
"""
def f4():
    
    f=open("1.txt","r")
    txt=f.readlines()
    maxa=0
    maxb=0
    for line in txt:
        line=line.rsplit()
        la=len(line[0])
        lb=len(line[1])
        if la >maxa:
            maxa=la
        if lb > maxb:
            maxb=lb
 
    w=open("temp.txt","w+")
    for line in txt: 
        line=line.rsplit()
        la=len(line[0])
        lb=len(line[1])
        w.write(line[0])
        #算了半天
        tw=maxa+maxb+1-la-lb
        w.seek(tw+w.tell())
        w.write(line[1])
        w.seek(w.tell()+1)
        w.write(line[2]+"\n")
    w.flush()
    w.seek(0)
    txt=w.read()
    print(txt)
        
"""
输出：
111111111111111111111COPY

-_-!剪贴碰到00自动截断了。输出内容不能完全贴上来。

依山居

# python版实现文本左右对齐排版
# 题目来源: http://www.bathome.net/thread-1246-1-1.html
# 依山居 7:17 2015/11/4
 
# str.format 字符串格式化参考：
# http://www.crifan.com/python_string_format_fill_with_chars_and_set_alignment/
 
# just()字符串对齐 参考：
# http://blog.csdn.net/u012515223/article/details/20463231
'''
1.txt内容：
111111111111111111111    98912 张三
222222222222222222    150020 李四四
  333333333333333333333    360000 王五
444444444444444444    2332 赵六六
  555555555555555555    222 田七
666666666666666666666    999999 舞吧
'''
 
#说明我的代码没按题目要求全部使用空格填充是为了让代码用法看起来直观一些。
 
#方法一 format格式化对齐
def f1():    
    with open("1.txt","r") as f:
        for s in f:
            l=s.rsplit ()
            t='{0:-<25} {1: >7} {2}'.format(l[0],l[1],l[2])    
            print(str(t))
 
'''
输出:
111111111111111111111----   98912 张三
222222222222222222-------  150020 李四四
333333333333333333333----  360000 王五
444444444444444444-------    2332 赵六六
555555555555555555-------     222 田七
666666666666666666666----  999999 舞吧
'''
 
#方法2 使用just()对齐
r=''
def f2():
    f=open("1.txt","r")
    for s in f:
        l=s.rsplit()
        print(l[0].ljust(25," "),l[1].rjust(10,"^"),l[2])
 
'''
输出：
111111111111111111111     ^^^^^98912 张三
222222222222222222        ^^^^150020 李四四
333333333333333333333     ^^^^360000 王五
444444444444444444        ^^^^^^2332 赵六六
555555555555555555        ^^^^^^^222 田七
666666666666666666666     ^^^^999999 舞吧
'''
 
#方法3
'''
思路是rsplit拆分成三列,l得到如['111111111111111111111', '98912', '张三']
算出列1,列2的最长，以此算出需要填充的长度，
'''
def f3():
    f=open("1.txt","r")
    txt=f.readlines()
    maxa=0
    maxb=0
    for line in txt:
        line=line.rsplit()
        la=len(line[0])
        lb=len(line[1])
        if la >maxa:
            maxa=la
        if lb > maxb:
            maxb=lb
 
    for line in txt:       
        line=line.rsplit()
        la=len(line[0])
        lb=len(line[1])
        if la ==maxa:
            tla=line[0]
        elif la<maxa:
            tla=line[0]+">"*(maxa-la)
        if lb ==maxb:
            tlb=line[1]
        elif lb<maxb:
            tlb=" "*(maxb-lb)+line[1]
        print(tla,tlb,line[2])
'''
输出：
111111111111111111111  98912 张三
222222222222222222>>> 150020 李四四
333333333333333333333 360000 王五
444444444444444444>>>   2332 赵六六
555555555555555555>>>    222 田七
666666666666666666666 999999 舞吧
'''COPY

尘丶

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2,3 delims= " %%a in (a.txt) do (
set k=%%a
set k1=%%b
    for /l %%c in (1,1,25) do if "!k:~%%c,1!"=="" set "k=!k! "
    for /l %%d in (1,1,5) do if "!k1:~%%d,1!"=="" set "k1=!k1! "
echo;!k! !k1! %%c
)
pauseCOPY

bailong360

@Echo Off
SetLocal EnableDelayedExpansion
For /F "Tokens=1,2,3" %%i In (1.txt) Do (
	Set L1=%%i                    
	Set L2=                    %%j
	Echo !L1:~0,25!!L2:~-15! %%k
)COPY

shelluserwlb

@echo off  
setlocal EnableDelayedExpansion
set "space= "
for /f "tokens=1,2*" %%a in (1.txt) do (
    set "str1=%%a"& set /a n=0 
    set /a s=1 &  call :1 
    set "x=!str1!!str2!" & set str2=
 
    set "str1=%%b" & set /a n=0
    set /a s=2 & call :1 
    set "y=!str2!!str1!" & set str2=
 
    set "str1=%%c" & set /a n=0
    set /a s=3 & call :1 
    set "z=!str2!!str1!" & set str2=
    echo !x!!y!!z!
)
pause>nul
goto :eof
:1
if not "!str1:~%n%,1!"=="" set /a n+=1 & goto :1
if %s% equ 1 (set /a m=26-%n% & goto :2)
if %s% equ 2 (set /a m=10-%n% & goto :2)
set /a m=10
:2
for /l %%i in (1,1,!m!) do set "str2=!str2!%space%"
goto :eof COPY

效果见下图：

CrLf

下载了10楼附件，可是还是没效果啊，莫非win7不支持这样么...

vincentzhou

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1-3" %%a in (1.txt) do (
set str=%%a%%b
call:count
set a=%%a
set /a num=32-!num!
set/p=!a!<nul
for /l %%i in (1 1 !num!) do (set /p= <nul)
echo %%b %%c
)
pause>nul
:count
if defined num set num=
:loop
if not "!str!"=="" (
set str=!str:~1!
set /a num+=1
goto loop
) COPY

weichenxiehou

新接触批处理，很有意思，请各位大侠多多指教。在此送上我的代码，多多指教！既然各位大侠都说了就题解题，那不好意思了，嘿嘿……

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1-3" %%i in (test.txt) do (
 set temp1=%%i$$$$$&set temp2=$$$$$%%j&set temp3=%%k$$$$$
 set temp1=!temp1:~0,21!&set temp2=!temp2:~-6!&set temp3=!temp3:~0,3!
 set tempstr=!temp1!      !temp2! !temp3!
 set tempstr=!tempstr:$= !
 echo !tempstr! 
)COPY

[ 本帖最后由 weichenxiehou 于 2010-12-30 23:37 编辑 ]

随风

不知此帖是否够通用？不过创建了临时文件。
http://bbs.bathome.net/viewthrea ... mp;highlight=%C5%C5