[注册表类] 批处理在任务栏显示秒数（win10）

jkasnz

话不多说，上代码
通过修改注册表在任务栏显示秒数，只有win10才行

@echo off
mode con cols=100 lines=30
color f6
title 显示秒 一瞬飞无影制作 2019.12.14
echo.
echo. 显示秒 一瞬飞无影制作 2019.12.14
echo.
for /f "tokens=2* delims=[]" %%i in ('ver') do set v=%%i
for /f "tokens=2* delims= " %%i in ("%v%") do set winv=%%i
echo %winv%|findstr "10.0" >nul 2>nul
if errorlevel 1 (
echo. 本程序仅于win10下生效！
goto exit
)
REG QUERY HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v ShowSecondsInSystemClock|findstr "0x1" >nul 2>nul
set b=%errorlevel%
if %b% equ 0 (set status=已开启) else set status=已关闭
set value=0
echo. 是否在任务栏时钟处显示秒数？
echo.  （当前：%status%）
echo.
echo.  Y 是     N 否     Q 退出
choice /c ynq /n
if errorlevel 3 goto exit
if errorlevel 2 set value=0&goto set
if errorlevel 1 set value=1&goto set

:set
echo.
reg add HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v ShowSecondsInSystemClock /t REG_DWORD /d %value% /f
echo. 
echo. 设置完毕。是否立即应用？
echo.（警告：请关闭所有的文件夹窗口，并保存其他所有程序的变动）
echo.
echo.  Y 是     N 否
choice /c yn /n
if errorlevel 2 goto info1
if errorlevel 1 goto killp

:killp
echo.
taskkill /f /im explorer.exe
start explorer
echo.
echo. 完成！已应用更改
goto exit

:info1
echo.
echo. 稍后请手动打开 任务管理器 ，在 进程 列表中右键 Windows资源管理器 ，单击 重新启动 ，即可应用更改！
goto exit

:exit
echo.
echo. 按任意键退出程序。。。
pause>nul
exit
复制代码