[文件操作] 请帮着修改BAT代码拖放文件夹修改文件名

dzwind

请各位大师帮忙看看以下的代码，我用AI做的，但执行不了，提示找不到文件。谢谢。
要求1、建好BAT文件后，以拖动文件夹至该BAT程序上执行
2、程序会将目录下的所有的docdocx文件改名，文件名称起以保留前2个字符，后面以时间的文件名。
想建的BAT内容如下：

set /a folder=%1
pushd %folder%
for /r. %%f in (*.doc *.docx) do (
    set filename=%%~nf
    set newfilename=!filename:~0,2!-%date%.%ext!
    ren "%%f" "%newfilename%"
)
popd
echo 改名完成!
复制代码

77七

@echo off
for /f "delims=" %%a in ('powershell -c "'{0:yyyyMMdd_hhmmss}' -f (get-date)"') do (
	for /r "%~1" %%i in (*.doc?) do (
		set f=%%i
		set n=%%~nxi
		setlocal enabledelayedexpansion
		ren "!f!" "!n:~0,2!_%%a%%~xi"
		endlocal
	)
)
pause
复制代码

Five66

保存为ansi编码的bat
文件夹名最好不要包含^&%之类的特殊字符

@echo off

if "%~1" == "%cd%\" echo error&pause&exit/b
set bbb=""%*
set bbb=%bbb:~2%

setlocal enabledelayedexpansion
if exist "!bbb!" (
cd /d !bbb!
if errorlevel 1 endlocal&pause&exit/b
for %%i in ("!cd!") do endlocal&cd /d "%%~i"
) else endlocal&echo error&pause&exit/b

set "ddd=%date:/=-%"
for /r %%i in (*.doc) do (
set name=%%~ni
set ext=%%~xi
setlocal enabledelayedexpansion
rename "!name!!ext!" "!name:~,2!-%ddd%!ext!"
endlocal
)

echo done&pause
复制代码

dzwind

谢谢楼上各位大师的无私帮助

ShowCode

回复 1# dzwind

@echo off
if "%~1" == "" exit /b
if not exist "%~1" exit /b
cd /d "%~1"
set "Today=%date:/=-%"
for /r %%i in (*.doc) do (
    set "BaseName=%%~ni"
    setlocal enabledelayedexpansion
    ren "%%~i" "!BaseName:~,2!-%Today%%%~xi"
    endlocal
)
复制代码

aloha20200628

回复 1# dzwind

订正代码如下
特别注意》被处理的目录/文件夹的路径文件名中如没有空格但包含 ^ 字符，将会导致拖入批处理脚本文件时出错 所以建议路径文件名不要包含 ^ 字符

@echo off
if "%~1"=="" exit/b
pushd "%~1" &set "d=%date:/=-%"
for /r %%F in (*.doc *.docx) do (
	set "nF=%%~nF" &setlocal enabledelayedexpansion
	ren "%%~F" "!nF:~,2!-%d%%%~xF" &endlocal
)
popd &pause &exit/b
复制代码