[文件操作] [分享]批处理重命名文件只保留最后部分

Batcher

【问题描述】

大佬们，我这个应该怎么写？我只想要红框的内容

terse

假若"_._"为关键词的话

@echo off&setlocal enabledelayedexpansion 
for /f "delims=" %%i in ('dir /b/a-d "*_._*.mp4"') do (
     set file=%%i
     ren "!file!" "!file:*_._=!"
) 
pause 
复制代码

semiuel

@echo off
setlocal enabledelayedexpansion 
for /f "delims=" %%i in ('dir /b/a-d "*_._*.mp4"') do (
set aa=%%i
set bb=!aa:~63,30!
echo ren "!aa!" "!bb!"
) 
pause 
复制代码

aloha20200628

@echo off
for /f "tokens=1-2 delims=·" %%a in (' dir /b/a-d "*_·_*.mp4" ') do for /f "tokens=1 delims=_" %%A in ("%%b") do ren "%%a·%%b" "%%A"
pause&exit/b
复制代码

qixiaobin0715

从示范文件名来看，最终重命名结果就是原文件名去掉以"_"分隔的前6段字符，保留其余。

@echo off
cd /d "%~dp0"
for /f "tokens=1-6* delims=_" %%a in ('dir /b /a-d *_*_*.mp4') do (
    ren "%%a_%%b_%%c_%%d_%%e_%%f_%%g" "%%g"
)
pause
复制代码

Batcher

回复 3# zhengzhenhui






批处理for命令从入门到精通以及配套练习题
http://bbs.bathome.net/thread-2189-1-1.html
http://bbs.bathome.net/thread-2336-1-1.html

zhengzhenhui

第三行的代码   _    是作为分隔符去区分的吗
上述出现三个（ _）可以这样理解不  2024-7-8-图片名，此代码就可以排除掉_之前的字而保留

Batcher

【解决方案】

@echo off
cd /d "%~dp0"
for /f "tokens=1-8* delims=_" %%a in ('dir /b /a-d *_*_*.mp4') do (
    if "%%i" == "" (
        echo ren "%%a_%%b_%%c_%%d_%%e_%%f_%%g_%%h" ---^> "%%h"
        ren "%%a_%%b_%%c_%%d_%%e_%%f_%%g_%%h" "%%h"
    ) else (
        echo ren "%%a_%%b_%%c_%%d_%%e_%%f_%%g_%%h_%%i" ---^> "%%h_%%i"
        ren "%%a_%%b_%%c_%%d_%%e_%%f_%%g_%%h_%%i" "%%h_%%i"
    )
)
pause
复制代码