[文件操作] 修改批处理保留指定字符串开头的文件{已经解决}

lovekix

C:\Windows\servicing\Packages  

文件夹下有很多文件

我想 保留指定 开头为 Microsoft-Windows- 的文件

我写了一个 批处理  不知道 问题出在什么地方

for /f "delims=" %%i in ('dir /b /a-d Microsoft-Windows-*') do del /a /f /q %%i
复制代码

路过

回复 10# lovekix 差不多吧，前面还要加set st=!file:~0,*!，*代表检测的字符的长度

lovekix

回复 18# went

@echo off 
cd /d "C:\Windows\servicing\Packages"
set "skip=0"
for /f "delims=:" %%i in ('findstr /b /n ":list" "%~0"') do set "skip=%%i"
for /f "usebackq skip=%skip% delims=" %%i in ("%~0") do call set "save=%%save%%:%%i"
for /f "delims=" %%i in ('dir /b /a-d ^| findstr /b /v "%save::= %"') do del %%i
pause&exit
REM 开头保存字符串,一行一个
:list
Microsoft-Windows-2
Package
Microsoft-Windows-Branding
复制代码

感谢  went   完美解决

把  源码发出来  备份  防止丢失

went

回复 17# lovekix


    你可以点我头像加我qq

lovekix

回复 16# went


    就是一闪  什么也没有  我录了屏  不知道 怎么发

went

回复 14# lovekix


    我这儿不会闪退,有没有截图

lovekix

回复 12# qixiaobin0715


    这个 不行     这个运行的是   包含这些字符的     不是开头的

lovekix

回复 13# went


    是ansi编码  

went

回复 9# lovekix

要保存ansi编码

qixiaobin0715

未测试，del慎用：

@echo off
set var="Package Microsoft-Windows-"
cd /d "C:\Windows\servicing\Packages"
for /f "delims=" %%i in ('dir /b /a-d ^| findstr /bv %var%') do del /a /f /q "%%i"
pause
复制代码

lovekix

回复 8# went


    研究半天   还是不行

lovekix

回复 7# 路过
[/url] went

    是不是  每加一行

if "!st!" neq "Package" (
			del /a /f /q %%i
复制代码

lovekix

回复 8# went

@echo off 
cd /d "C:\Windows\servicing\Packages"
for /f "delims=:" %%i in ('findstr /b /n ":list" "%~0"') do for /f "delims=" %%a in ('more +%%i "%~0"') do call set "save=%%save%%:%%a"
for /f "delims=" %%i in ('dir /b /a-d ^| findstr /b /v "%save::= %"') do del %%i
pause&exit
REM 开头保存字符串,一行一个
:list
Microsoft-Windows-
Package
复制代码

好像有问题    一闪就退出了  没有 任何操作

went

回复 6# lovekix

@echo off 
cd /d "C:\Windows\servicing\Packages"
for /f "delims=:" %%i in ('findstr /b /n ":list" "%~0"') do for /f "delims=" %%a in ('more +%%i "%~0"') do call set "save=%%save%%:%%a"
for /f "delims=" %%i in ('dir /b /a-d ^| findstr /b /v "%save::= %"') do echo %%i
pause&exit
REM 开头保存字符串,一行一个
:list
Microsoft-Windows-
Package
复制代码

路过

回复 4# lovekix

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d') do (
	set file=%%~i
	set st=!file:~0,18!
	if "!st!" neq "Microsoft-Windows-" (
		set st=!file:~0,7!
		if "!st!" neq "Package" (
			del /a /f /q %%i
		)
	)
)
pause
exit
复制代码