netbenton

@echo off&setlocal enabledelayedexpansion
set len=1&for /l %%a in (1,1,256) do (set/a len=len^<^<1,1/len 2>nul || (set len=%%a&goto :lp))
set len=512&rem 首先测出字长，应该达不到512位吧？
:lp
(set n=
set o=
set s=
set ns=
echo.
set /p n=输入一个整数：)
(if "%n%"=="" goto :eof
for /l %%a in (1,1,!len!) do (
        set/a m=n%%2,n=n^>^>1
        set s=!s!!m:~-1!
        set o=!m:~-1!!o!
        set/a ns=^(ns^<^<1^)+m
)
echo 正二进制：!o!   {%n%}
echo 逆转输出：!s!   {!ns!}
goto :lp)

lhjoanna

Re：netbenton
        我想正确的思路是不能留下隐患，至于有没有512的我不清楚，但计算机是不断发展的，也要考虑程序能适应以后的发展。当然在效率要求不是太严格或如需改变但代码变动不大的情况下也可以。
    还有个小问题，就是兄的代码在输入负数的情况下，逆转后的十进制数的正负存在点儿小问题。

netbenton

已经解决通用和符号问题

 
@echo off&setlocal enabledelayedexpansion
set/a len=1,n=1
:rep
set/a len=len+len,n=n^<^<len,1/n 2>nul&&goto :rep
:lp
(set n=
set o=
set s=
set ns=
echo.
set /p n=输入一个整数：)
(if "%n%"=="" goto :eof
for /l %%a in (1,1,!len!) do (
set/a m=n%%2,n=n^>^>1,m*=m
set s=!s!!m!
set o=!m!!o!
set/a ns=^(ns^<^<1^)+m
)
echo 正二进制：!o!   {%n%}
echo 逆转输出：!s!   {!ns!}
goto :lp)
复制代码

真的还可以精简，把一些地方换成了按位运算，更快更简
但初始化还是保持用set，反正只有四行，按字数来算还更少一点。

 
@echo off&setlocal enabledelayedexpansion
set/a len=1,n=1
:rep
set/a "len<<=1,n<<=len,1/n" 2>nul&&goto :rep
:lp
set n=&set o=&set s=&set ns=&echo.&set /p n=输入一个整数：
(if "%n%"=="" goto :eof
for /l %%a in (1,1,%len%) do (
set/a "m=n&1,n>>=1,ns=ns<<1|m"
set s=!s!!m!
set o=!m!!o!
)
echo 正二进制：!o!   {%n%}
echo 逆转输出：!s!   {!ns!}
goto :lp)
复制代码

[ 本帖最后由 netbenton 于 2009-4-27 22:44 编辑 ]

lhjoanna

Re：netbenton
         执行结果，要求都正确，代码还有几处可以精简的地方。进入循环刚开始的四个变量清空操作可以在循环首尾用一对setlocal enabledelayedexpansion和endlocal代替。还有可移植性的另一种思路在12楼与15楼都有体现！

lhjoanna

今天忽然想到了用递归来算，代码以32位为例，效率也没有纯位运算高，仅作研究。

@echo off
 set /p "value=INPUT:"
 set /a "i=1<<31",flag=1
 call :loop %i%
 pause>nul&goto :eof
:loop
 set /a "i=%1,n=i&value,i>>=1,n=!(!n)"
 if %flag% equ 1 set /a i="1<<30" &set flag=0
 if %i% neq 0 (call :loop %i% %n%) else <nul set /p=%n%
 <nul set /p=%2
复制代码

terse

以前写的2进制转换的  改下 不知通否

@echo off&setlocal enabledelayedexpansion
set/p a=INPUT:
set i=1
for /l %%i in (31,-1,0) do (
    set/a n=^!^(^!^(a%%2^)^)2>nul
    set/a i*=n"<<"%%i,d+=i,i=1
    set b=!b!!n!
    if !a! geq 2 (set/a a/=2)else set a=0
  )
echo Decimal:%d% &echo Binary :%b%
pause
复制代码

lhjoanna

兄的代码在负数情况有些小问题

terse

原帖由 lhjoanna 于 2009-5-1 11:54 发表
兄的代码在负数情况有些小问题

是的  有问题  这样呢

@echo off&setlocal enabledelayedexpansion
set/p a=INPUT:
for /l %%i in (31,-1,0) do (
    set/a "n=a&1,a>>=1,d+=n<<%%i"
    set b=!b!!n!
  )
echo Decimal:%d% &echo Binary :%b%
pause
复制代码