【练习-061】小学生加减法算式批处理生成器

batman

出题目的：
　　综合考查对set 命令以及if判断语句的运用
加分原则：
　　优秀代码予以技术＋1的鼓励
解题要求：
　　1、请版主、技术组成员先将机会留给新人
　　2、代码简洁、高效、无临时文件
题目如下：
　　编写代码随机生成指定运算范围内的整数加减法算式，其中指定范围是由使用者输入，在这其中要注意加法运算
的和不能超过指定范围（上限），减法运算结果不能为负数（减数不能大于被减数），然后接收输入的答案并做出判
断，如果结果正确则显示正确，不正确显示不正确并给出正确结果，接收回车指令后给出下一个随机算式，这时不要
求再接收运算范围的输入。运行过程如下所示：
[attach]2980[/attach]

sds

压缩后代码，去掉了菜单和注释，简化代码

@echo off

:lianxi
set times=0
cls
set /p sx=请输入数字上限:
set /p sc=要计算的是加法还是减法(A,B)?

:clc
set /a m=%random%%%%sx%
set /a n=%random%%%%sx%
if %sc%==A set ss=%m%+%n%
if %sc%==B set ss=%m%-%n%
set /a results=%ss%

:loop
cls
echo        第[%times%]道题
echo    请计算:%ss%
set /p ans=请输入结果：
set /a times=%times%+1
if %ans% gtr %results% set d=大&goto error
if %ans% lss %results% set d=小&goto error
if %ans% equ %results% goto right

:error
cls
echo 你计算的结果%d%了！
pause>nul
goto clc

:right
cls
echo Bingo 你算对了 
echo 按任意键继续答题
pause>nul
goto clc
复制代码

sds

发现一个bug：因为每次算完都会跳到clc，导致变量%times%不断清零，无法正常计数

下面是修复后的代码

@echo off
color 1F
setlocal enableDelayedExpansion
title 小学生加减法练习器v1.1

:menu
cls
echo      ┌───────────────────┐
echo         小学生加减法练习器v１．０
echo      └───────────────────┘ 
echo               ┌──┐
echo               │１│     开始练习
echo               └──┘
echo.
echo               ┌──┐
echo               │２│     退出
echo               └──┘
set /p choose=请输入:
if %choose%==1 goto lianxi
if %choose%==2 exit
echo 输入有误! 请重新输入
pause>nul
goto menu

:lianxi
set times=0
cls
set /p sx=请输入数字上限:
set /p sc=要计算的是加法还是减法(A,B)?


:clc


::处理加数(或减数)
set /a m=%random%%%%sx%
set /a n=%random%%%%sx%

::处理算式
if %sc%==A set ss=%m%+%n%
if %sc%==B set ss=%m%-%n%

::生成答案
set /a results=%ss%

:loop
cls

echo        第[%times%]道题
echo    请计算:%ss%
set /p ans=请输入结果：
set /a times=%times%+1

::结果与标准答案进行对比
if %ans% gtr %results% set d=大&goto error
if %ans% lss %results% set d=小&goto error
if %ans% equ %results% goto right

:error
cls
echo 你计算的结果%d%了！
pause>nul
goto clc

:right
cls
echo Bingo 你算对了 
echo 按任意键继续答题
pause>nul
goto clc
复制代码

sds

我也做了一个,个人感觉还行，就是减法出现负数的情况不可避免（以我现在的水平来看）

@echo off
color 1F
setlocal enableDelayedExpansion
title 小学生加减法练习器v1.0

:menu
cls
echo      ┌───────────────────┐
echo         小学生加减法练习器v１．０       
echo      └───────────────────┘ 
echo               ┌──┐
echo               │１│     开始练习
echo               └──┘
echo.
echo               ┌──┐
echo               │２│     退出
echo               └──┘
set /p choose=请输入:
if %choose%==1 goto lianxi
if %choose%==2 exit
echo 输入有误! 请重新输入
pause>nul
goto menu

:lianxi
cls
set /p sx=请输入数字上限:
set /p sc=要计算的是加法还是减法(A,B)?


:clc


::处理加数(或减数)
set /a m=%random%%%%sx%
set /a n=%random%%%%sx%

::处理算式
if %sc%==A set ss=%m%+%n%
if %sc%==B set ss=%m%-%n%

::生成答案
set /a results=%ss%

:loop
cls
set times=0
echo        第[%times%]道题
echo    请计算:%ss%
set /p ans=请输入结果：
set /a time=%time%+1

::结果与标准答案进行对比
if %ans% gtr %results% set d=大&goto error
if %ans% lss %results% set d=小&goto error
if %ans% equ %results% goto right

:error
cls
echo 你计算的结果%d%了！
pause>nul
goto clc

:right
cls
echo Bingo 你算对了 
echo 按任意键继续答题
pause>nul
goto clc
复制代码

ljfnh403

@echo off&setlocal EnableDelayedExpansion&set f=+-
set "制表符=        "&rem 请在这里放入制表符
set "退格符="&rem 请在这里放入12个退格符
set 退格=%制表符%%退格符%&mode con cols=80 lines=25
set/p max=输入最大数值：&set/a max+=1
for /l %%a in () do (set/a a1=!random!%%max,a2=!random!%%max,r=!random!%%2
for %%b in (!r!) do (set/p ans=→!a1!!f:~%%b,1!!a2!=
set/a ans=a1!f:~%%b,1!a2-ans+0
echo.%退格%
if !ans!==0 (echo.√) else echo.×))

ljfnh403

@echo off&setlocal EnableDelayedExpansion&set f=+-&set "制表符=        "&rem 请在这里放入制表符
set 退格=%制表符%-&mode con cols=80 lines=25
set/p max=输入最大数值：&set/a max+=1
for /l %%a in () do (set/a a1=!random!%%max,a2=!random!%%max,r=!random!%%2
for %%b in (!r!) do (set/p ans=→!a1!!f:~%%b,1!!a2!=
set/a ans=a1!f:~%%b,1!a2-ans+0
echo.%退格%
if !ans!==0 (echo.√) else echo.×))

brim

菜鸟一个，请多指教。

@echo off
color 9F
:aa
Set /a "sum1=%random%%%1000"
Set /a "sum2=%random%%%1000"
If %sum1% gtr %sum2% (Set /a sum3=%sum1%-%sum2% &echo %sum1%-%sum2%) else (Set /a sum3=%sum2%-%sum1%&echo %sum2%-%sum1%)
Set /p sum4= 请输入您的答案：
if %sum3%==%sum4% (echo  正确答案是%sum3%&echo  你的答案是%sum4%恭喜你答对了！继续努力，不要骄傲喔) else echo  正确答案是%sum3%&echo  你的答案是%sum4%，太可惜了，你答错了！不要气馁喔，继续努力，加油！
Goto aa
复制代码

raymai97

回复 35# smith203


    没错，批处理天生不能算小数点~

smith203

批处理是不是不能算小数？

明明结果是1.8， 显示的却是1，

asd821089612

@echo off
set /p a=请输入是多少以内的加减法
color 9f
:start
set /a pan=%random%%%2
if %pan%==1 goto jia
if %pan%==0 goto jian
:jia
set /a b=%random%%%(%a%+1)
set /a d=%a%-%b%+1
set /a c=%random%%%%d%
set /a he=%b%+%c%
echo %b%+%c%=?
set /p an=请输入答案：
if %an%==%he% echo 恭喜你，答对了
if %an% neq %he% echo 错误，正确答案是%he%
pause>nul
goto start


:jian
set /a b=%random%%%(%a%+1)
set /a c=%random%%%(%a%+1)
if %b% gtr %c% goto 1
goto 2
:1
echo %b%-%c%=?
set /p an=请输入答案：
set /a cha=%b%-%c%
if %an%==%cha% echo 恭喜你，答对了
if %an% neq %cha% echo 错误，正确答案是%he%
pause>nul
goto start
:2
echo %c%-%b%=?
set /p an=请输入答案：
set /a cha=%c%-%b%
if %an%==%cha% echo 恭喜你，答对了
if %an% neq %cha% echo 错误，正确答案是%he%
pause>nul
goto start
复制代码

Batcher

32# jixun66


DZ论坛程序会自己转换的，木有办法。

jixun66

代码很简单。


压缩前代码：

@echo off
setlocal enabledelayedexpansion
set /p max=请输入算数的和的上限：
if %max% LEQ 1 echo 最大值错误&%0

:loop
set /a p=%random% %% 2
set /a p1=%random% %% %max%
if !p!==1 (
	rem 加法
	set /a p2=%random% %% (^%max%-!p1!^)
	set s=+
) else (
	rem 减法
	set /a p2=%random% %% !p1!
	set s=-
)
echo.
echo %p1%%s%%p2%=?
echo.
set ans=
set /p ans=请输入答案：
set /a r=%p1%%s%%p2%
if "%r%"=="%ans%" (echo 答案正确！) else (echo 答案错误！&echo 正确答案是：%r%)
echo.
pause
goto loop
复制代码

压缩后代码：

@echo off&setlocal enabledelayedexpansion&set /p max=请输入算数的和的上限：
if %max% LEQ 1 echo 最大值错误&%0
:loop
set /a p=%random% %% 2
set /a p1=%random% %% %max%
if !p!==1 (
 set /a p2=%random% %% (^%max%-!p1!^)
 set s=+
) else (
 set /a p2=%random% %% !p1!
 set s=-
)
echo.&echo %p1%%s%%p2%=?&echo.&set ans=
set /p ans=请输入答案：
set /a r=%p1%%s%%p2%
if "%r%"=="%ans%" (echo 答案正确！) else (echo 答案错误！&echo 正确答案是：%r%)
echo.&pause&goto loop
复制代码

压缩后的代码的开头的空格怎么消失了..虽然下方的复制代码能复制进去。
还有一点，复制代码的时候我这里的TAB缩进符总是显示为『? ? ? ? 』，请问有没有解决办法？

applba

@echo off &setlocal enabledelayedexpansion &color 17
:limit
set /p n1=请输入最大计算范围：
set /a n=!n1!  && if  !n! lss 2 (echo 您输入的数字有误！&goto limit)
:gen
set /a "a=(!random!%%!n!+1),b=(!random!%%!n!+1)"
if !a! gtr !b! (
	set /a r0=!a!-!b!
	set /p "r1=!a!-!b!=?_"
) else (
		set /a r0=!a!+!b!
		if !r0! GTR !n! goto gen
		set /p "r1=!a!+!b!=?_"
	)
if !r0! neq !r1! (echo "你答错了！正确答案是：!r0!" ) else (echo 您答对了！请再接再厉吧~)
pause>nul&cls&goto gen
复制代码

::我搞了半天没明白按“回车键”继续？

qzwqzw

贴一个没有循环和选择结构的顺序性解法
常规之外略作创新
没有刻意处理诸如0或者最大值的边界问题
在运算范围为1时可能会丢失某些可能
为0时则直接报错退出

@echo off
echo.
set /p num=请输入运算范围（如10以内输入10）：
set ops=+-
:loop
cls&echo.
rem 生成大数big，在减法中作被减数，在加法中作和数
set /a big=%random% %% %num%+1
rem 生成运算符op，并转换为字符opr，0为加法，1为减法
set /a op=%random% %% 2
call set opr=%%ops:~%op%,1%%
rem 生成运算数opd1，减法为大数big，加法时为小于big的随机数
set /a opd1=big*op + (%random% %% big)*(!op)
rem 生成运算数opd2，减法为小于big的随机数，加法时为big-opr1
set /a opd2=(%random% %% big)*op + (big-opd1)*(!op)
rem 生成结果值result
set /a result=opd1 %opr% opd2
echo %opd1% %opr% %opd2% = ?
echo.
set "answer="
set /p answer=请输入答案：
echo.
rem 根据结果与输入的异同显示提示信息
set _0=正确
set _1=错误，正确答案是%result%
rem 两次取反是想将相减后的差值转换为是否相等的逻辑值0或1
set /a judge=!(!(answer-result))
call echo %%_%judge%%%
pause>nul
goto loop
复制代码

gshccr

基本符合版主的要求，不过代码太长了，不知道哪里需要改进的地方，还请大家多多指教！

 
@echo off
setlocal enabledelayedexpansion
set /p a=请输入指定范围数：
set /a a1=%a%+1
:a
cls
set /a t1=%random%%% %a1%,t2=%random%%% %a1%
set /a y1=%a1%-%t1%-1,y2=%a1%-%t2%-1
if %y1% geq %y2% (
if %y2% geq 1 (set /a the=%y1%+%y2%
if !the! gtr %a% (
set /a daan=%y1%-%y2%&echo %y1%-%y2%=?&goto b)))
set /a r=%random%%% 2+1
if %r%==1 (set n=2) else (set n=1)
set /a wet=!y%r%!+!y%n%!
if %wet% gtr %a% (set /a daan=%y2%-%y1%&echo %y2%-%y1%=?) else (
set /a daan=!y%r%!+!y%n%!&echo !y%r%!+!y%n%!=?)
:b
set /p g=请输入正确答案：
if "%g%"=="%daan%" (echo 正确) else (echo 错误,正确答案为%daan%)
pause
goto a
复制代码

[ 本帖最后由 gshccr 于 2010-10-13 11:11 编辑 ]