[文件操作] 【已解决】求助：批处理文件夹名添加后缀

lj670

bat批处理当前文件夹下根据88.txt文本内容，每行随机乱序给子文件夹名添加后缀（没有孙文件夹），每行文本只添加一个子文件夹不重复添加（文本内容可能有空行），如8行文本就只添加8个子文件夹后缀，子文件夹名例如：20 (1)，20 (6)，22 (2)等等，文件夹名有空格。
文本内容例如：春天的风，夏天的小鱼，秋天的果实，等等。添加后子文件夹名为：20 (1)夏天的小鱼，20 (6)春天的风，22 (2)秋天的果实。。等等   求助各位大佬，谢谢！

lj670

回复 3# aloha20200628


    脚本运行正常，达到预期效果，谢谢！

lj670

回复 2# qixiaobin0715

脚本运行正常，非常好，谢谢！

aloha20200628

回复 1# lj670

逐行读取 88.txt 实值数据 xxx，随机且不重复抽取当前目录下的某个子目录，对其更名为 ‘子目录名xxx’，管控实值xxx数量溢出子目录数量的实况...

@echo off &setlocal enabledelayedexpansion
dir /b/ad|findstr /n ".*">"_._" &for /f %%n in ('find /c /v ""^<"_._" ') do (set "n=%%n")
for /f "delims=" %%x in (88.txt) do set/a "k+=1" & if !k! gtr !n! (goto :end) else (
   set/a "r=1+!random!%%!n!" &(call :xxx)
   for /f "tokens=1* delims=:" %%a in ('findstr /bc:"!r!:" "_._" ') do (ren "%%b" "%%~nb%%x%%~xb")
)
:end
del /q "_._" &pause&exit/b
:xxx
   if defined _!r! (set/a "r=1+!random!%%!n!" &goto :xxx)
   set "_!r!=1" &exit/b
复制代码

qixiaobin0715

88.txt的行数要小于等于子文件夹数：

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /ad') do set _!random!=%%i
set _>temp
(for /f "delims=" %%i in (88.txt) do (
    set /p str=
    for /f "tokens=1* delims==" %%a in ("!str!") do ren "%%b" "%%b%%i"
))<temp
del temp
pause
复制代码

代码未经测试，请备份好源文件。